Funktionreferenz


_SQLite_FastEncode

Beschreibung anzeigen in

Encodiert binär-Daten für den Gebrauch in SQLite-Statements (Querys)

#include <SQLite.au3>
_SQLite_FastEncode ( $vData )

Parameter

$vData Daten zum Encodieren (Nur Binär)

Rückgabewert

Erfolg: einen encodierten Binär-String
Fehler: einen Leer-String und setzt das @error Flag auf ungleich null
@error: 1 - Daten sind nicht vom Binär-Typ

Bemerkungen

Die SQLite-Dateien können von https://www.autoitscript.com/autoit3/pkgmgr/sqlite heruntergeladen werden. Abgespeichert können diese in @ScriptDir, @SystemDir, @WindowsDir oder @WorkingDir werden.

Der encodierte String ist bereits von einfachen Anführungszeichen (') umgeben.
Zum Beispiel Chr(0) & Chr(1) sieht wie folgt aus: X'0001'
Der encodierte String kann von SQLite decodiert und als Binärtyp in einem BLOB-Feld gespeichert werden.
Um Strings in einem TEXT-Feld zu speichern, benutzt man _SQLite_Escape().
Um numerische Werte als diese zu speichern, benutzt man einfache Verkettung.

Verwandte Funktionen

_SQLite_Escape

Beispiel

#include <MsgBoxConstants.au3>
#include <SQLite.au3>
#include <SQLite.dll.au3>

Local $hFile, $vData, $sFileName, $sData, $hQuery, $aRow, $sMsg

ConsoleWrite("_SQLite_Startup=" & _SQLite_Startup() & @CRLF)
ConsoleWrite("_SQLite_LibVersion=" & _SQLite_LibVersion() & @CRLF)

_SQLite_Open()
_SQLite_Exec(-1, "CREATE TABLE IF NOT EXISTS Test (Daten blob);")

$vData = Binary("Hallo" & Chr(0) & "Welt"); = 48616C6C6F0057656C74
$sData = _SQLite_FastEncode($vData)
_SQLite_Exec(-1, "INSERT INTO Test VALUES (" & $sData & ");")

$vData = Binary(Chr(0) & @CRLF); = 000D0A
$sData = _SQLite_FastEncode($vData)
_SQLite_Exec(-1, "INSERT INTO Test VALUES (" & $sData & ");")

$vData = Binary(Chr(0)); = 00
$sData = _SQLite_FastEncode($vData)

_SQLite_Exec(-1, "INSERT INTO Test VALUES ( " & $sData & " );")
_SQLite_Query(-1, "SELECT * FROM Test;", $hQuery)

While _SQLite_FetchData($hQuery, $aRow, 1) = $SQLITE_OK
    $sMsg &= Hex($aRow[0]) & @CRLF
WEnd

MsgBox($MB_SYSTEMMODAL, "Ergebnis", $sMsg)

_SQLite_Close()
_SQLite_Shutdown()