Andockbare GUI

DeepRed92

Hallo,

weiß jemand wie man eine GUI so machen kann, dass es sich automatisch am Bildschirmrand andockt?
Also das es sozusagen, wenn es 5 Pixel vom Bildschirmrand entfernt ist "angezogen" wird.

**BugFix**

Guck das mal an: DockIt

DeepRed92

Das hab ich schon gesehen, aber das ist nicht das, was ich suche. Also mein GUI soll sich nur am Bildschirmrad (oben + unten + rechts + links + Tray) andockbar sein. Jetzt weiß ich nun nicht genau wie man sowas bewerkstelligen soll. :-/

**BugFix**

Hab ich verstanden und dieses Skript zeigt doch den Weg. Nur dass du als Andockkriterium die Desktopränder benötigst.
Versuch mal dein Glück und melde dich, wenn es nicht swird.

DeepRed92

Sry hab ich dann falsch verstanden :wacko: . Dein Script ist mir leider viel zu kompliziert (soviele Arrays usw...) .
Deswegen hab ich es so versucht:

Spoiler anzeigen

[autoit]

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

$Width = 200
$Hight = 200
$Toleranz = 100

[/autoit] [autoit][/autoit] [autoit]

$hwnd = GUICreate("Dock mich an :D", $Width, $Hight)
GUISetState()

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

While 1
If GUIGetMsg() = -3 Then Exit

[/autoit] [autoit][/autoit] [autoit]

$Pos = WinGetPos($hwnd)

[/autoit] [autoit][/autoit] [autoit]

If $Pos[0] < $Toleranz Then WinMove($hwnd, "", 0, $Pos[1])
If $Pos[1] < $Toleranz Then WinMove($hwnd, "", $Pos[0], 0)

[/autoit] [autoit][/autoit] [autoit]

Sleep(1)
WEnd

[/autoit]

Dies klappt gut soweit, aber ich möchte meinen Gui auch rechts und unten andocken. Weiß jetzt nicht wie ich es machen soll. Ich habs mit @DesktopWidth ausprobiert, aber da ist nichts gescheites herausgekommen.

**BugFix**

Hier mal eine Komplettlösung:

Spoiler anzeigen

[autoit]

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>

[/autoit] [autoit][/autoit] [autoit]

Global $CatchWidth = 70 ; Pixelbereich indem das Fenster gefangen wird
Global $BorderDiff = 5 ; Pixelabstand zum Rand

[/autoit] [autoit][/autoit] [autoit]

Global $gui = GUICreate("Dock on Border", 300, 300)
GUISetState(@SW_SHOW, $gui)

[/autoit] [autoit][/autoit] [autoit]

; WM_MOVE registrieren:
GUIRegisterMsg($WM_MOVE, "WM_MOVE")

[/autoit] [autoit][/autoit] [autoit]

While True
$msg = GUIGetMsg()
Switch $msg
Case -3
Exit
EndSwitch
WEnd

[/autoit] [autoit][/autoit] [autoit]

Func WM_MOVE($hWndGUI)
If Not(WinGetHandle($gui) = $hWndGUI) Then Return $GUI_RUNDEFMSG
Local $aPos = WinGetPos($gui)
Local $Catch_Left = $CatchWidth, $Catch_Right = @DesktopWidth - $CatchWidth
Local $Catch_Top = $CatchWidth, $Catch_Bottom = @DesktopHeight - $CatchWidth
Select
Case $aPos[0] <= $Catch_Left
If $aPos[1] <= $Catch_Top Then
WinMove($gui, '', $BorderDiff, $BorderDiff)
ElseIf $aPos[1] + $aPos[3] >= $Catch_Bottom Then
WinMove($gui, '', $BorderDiff, @DesktopHeight - $BorderDiff - $aPos[3])
Else
WinMove($gui, '', $BorderDiff, $aPos[1])
EndIf
Case $aPos[0] + $aPos[2] >= $Catch_Right
If $aPos[1] <= $Catch_Top Then
WinMove($gui, '', @DesktopWidth - $BorderDiff - $aPos[2], $BorderDiff)
ElseIf $aPos[1] + $aPos[3] >= $Catch_Bottom Then
WinMove($gui, '', @DesktopWidth - $BorderDiff - $aPos[2], @DesktopHeight - $BorderDiff - $aPos[3])
Else
WinMove($gui, '', @DesktopWidth - $BorderDiff - $aPos[2], $aPos[1])
EndIf
Case $aPos[1] <= $Catch_Top
If $aPos[0] <= $Catch_Left Then
WinMove($gui, '', $BorderDiff, $BorderDiff)
ElseIf $aPos[0] + $aPos[2] >= $Catch_Right Then
WinMove($gui, '', @DesktopWidth - $BorderDiff - $aPos[2], $BorderDiff)
Else
WinMove($gui, '', $aPos[0], $BorderDiff)
EndIf
Case $aPos[1] + $aPos[3] >= $Catch_Bottom
If $aPos[0] <= $Catch_Left Then
WinMove($gui, '', $BorderDiff, @DesktopHeight - $BorderDiff - $aPos[3])
ElseIf $aPos[0] + $aPos[2] >= $Catch_Right Then
WinMove($gui, '', @DesktopWidth - $BorderDiff - $aPos[2], @DesktopHeight - $BorderDiff - $aPos[3])
Else
WinMove($gui, '', $aPos[0], @DesktopHeight - $BorderDiff - $aPos[3])
EndIf
EndSelect
Return $GUI_RUNDEFMSG
EndFunc ;==>WM_MOVE

[/autoit]

Edit: Hatte nen kleine Bug bei Top drin - gefixt.