Funktion/Controlclick vor/bei/nach PC-Sperrung

#include<EditConstants.au3>
#include<WindowsConstants.au3>
#include<GUIConstantsEx.au3>
Global Const $NOTIFY_FOR_THIS_SESSION = 0
Global Const $NOTIFY_FOR_ALL_SESSIONS = 1
Global Const $WM_WTSSESSION_CHANGE = 0x02B1
Global Enum $WTS_CONSOLE_CONNECT = 0x1, $WTS_CONSOLE_DISCONNECT, _
$WTS_REMOTE_CONNECT, $WTS_REMOTE_DISCONNECT, _
$WTS_SESSION_LOGON, $WTS_SESSION_LOGOFF, _
$WTS_SESSION_LOCK, $WTS_SESSION_UNLOCK, _
$WTS_SESSION_REMOTE_CONTROL
Global Const $aWTS_EVENTS[10][3] = [ [""], _ ; Codes fangen bei 1 an, also ist array[0] leer
[ "WTS_CONSOLE_CONNECT", "0x1", "A session was connected to the console terminal." ], _
[ "WTS_CONSOLE_DISCONNECT", "0x2", "A session was disconnected from the console terminal." ], _
[ "WTS_REMOTE_CONNECT", "0x3", "A session was connected to the remote terminal." ], _
[ "WTS_REMOTE_DISCONNECT", "0x4", "A session was disconnected from the remote terminal." ], _
[ "WTS_SESSION_LOGON", "0x5", "A user has logged on to the session." ], _
[ "WTS_SESSION_LOGOFF", "0x6", "A user has logged off the session." ], _
[ "WTS_SESSION_LOCK", "0x7", "A session has been locked." ], _
[ "WTS_SESSION_UNLOCK", "0x8", "A session has been unlocked." ], _
[ "WTS_SESSION_REMOTE_CONTROL", "0x9", "A session has changed its remote controlled status. To determine the status, call GetSystemMetrics and check the SM_REMOTECONTROL metric." ] _
]

$hWndGUI = GUICreate("WM_WTSSESSION_CHANGE", 400, 400)
$Button_Register = GUICtrlCreateButton("Register Msg", 10, 10, 185, 30)
$Button_UnRegister = GUICtrlCreateButton("UnRegister Msg", 205, 10, 185, 30)
GUICtrlSetState($Button_UnRegister, $GUI_DISABLE)
$LogWin = GUICtrlCreateEdit("", 10, 50, 380, 315, BitOR($GUI_SS_DEFAULT_EDIT, $ES_READONLY))
GUICtrlCreateLabel("WM_WTSSESSION_CHANGE-Demo: ©2009 by Prog@ndy", 10, 375, 380, 20)
GUIRegisterMsg($WM_WTSSESSION_CHANGE, "MY_WM_WTSSESSION_CHANGE")
GUISetState()

While 1
Switch GUIGetMsg()
Case $Button_Register
Local $aResult = DllCall("wtsapi32.dll", "int", "WTSRegisterSessionNotification", "hwnd", $hWndGUI, "dword", $NOTIFY_FOR_THIS_SESSION)
If Not @error And $aResult[0]<>0 Then
GUICtrlSetState($Button_Register, $GUI_DISABLE)
GUICtrlSetState($Button_UnRegister, $GUI_ENABLE)
EndIf
Case $Button_UnRegister
Local $aResult = DllCall("wtsapi32.dll", "int", "WTSUnRegisterSessionNotification", "hwnd", $hWndGUI)
If Not @error And $aResult[0]<>0 Then
GUICtrlSetState($Button_UnRegister, $GUI_DISABLE)
GUICtrlSetState($Button_Register, $GUI_ENABLE)
EndIf
Case $GUI_EVENT_CLOSE
Exit
DllCall("wtsapi32.dll", "int", "WTSUnRegisterSessionNotification", "hwnd", $hWndGUI)
EndSwitch
WEnd

Func MY_WM_WTSSESSION_CHANGE($hWnd, $uMsg, $wParam, $lParam)
ConsoleWrite($wParam & @CRLF)
If $wParam < 1 Or $wParam > 9 Then Return 0
Local $iLength = GUICtrlSendMsg($LogWin, $WM_GETTEXTLENGTH, 0, 0)
GUICtrlSendMsg($LogWin, $EM_SETSEL, $iLength, $iLength)
GUICtrlSetData($LogWin, _
"WM_WTSSESSION_CHANGE :: " & $aWTS_EVENTS[$wParam][0] & @CRLF & _
@TAB & "Code: " & $aWTS_EVENTS[$wParam][1] & @CRLF & _
@TAB & "Desc.: " & $aWTS_EVENTS[$wParam][2] & @CRLF, 1 _
)
Return 0
EndFunc