Hi,
nach der Auswahl von GUICtrlCreateMenuItem soll das Fenster "geleert" werden.
Gibt es dafür einen pauschalen Befehl?
Wenn man zuvor Menüitem A ausgewählt und danach Menüitem B auswählt, dann sieht man immer noch die Labels, die bei A angezeigt wurden.
Grüße und Danke
Guido
ich kann mir zwar jetz wenig vorstellen was genau du machen willst, aber um die label zu entfernen kann man GUICtrlDelete() verwenden
Ich habe eine Menübar mit GUICtrlCreateMenu gemacht.
Angenommen ich wähle im Menü "Benutzer anzeigen" aus, wird in dem Fenster alles zum angemeldeten Benutzer angzeigt.
Wähle ich in der Menüleiste nun "Drucker anzeigen" aus, sollen natürlich alle Einträge zu installieren Druckern angezeigt werden.
Nun ist es aber so, dass die Informationen zu "Benutzer anzeigen" ebenfalls noch angezeigt werden.
Mit GUICtrlDelete müsste ich jedes Label, Input-Feld, Button, etc. sepparat entfernen.
Schöner wäre es, wenn die Fensterfläche mit einem Befehl wieder frei ist und man nur noch die Menüleiste sieht.
Hallo ThinkCross,
poste doch einfach dein bisheriges Skript,
mfg (Auto)Bert
In der Funktion "_events" werden die Funktionen aufgerufen, die im Menü ausgewählt wurden.
Wurde z. B. "DC's" ausgewählt, werden u. a. alle Domänen-Controller angezeigt.
Wurde z. B. "Mitgliedschaft" ausgewählt, erscheint ein Input-Feld mit einem Button zum Abschicken.
Hat man nun zuerst DC's ausgewählt und wählt anschließend Mitgliedschaft aus, stehen die Einträge von der letzten Auswahl noch im Fenster.
Ich kann natürlich eine Funktion bauen, die nach dem Aufruf eines Menüpunktes sämtliche Ctrl's löscht, komfortabel ist das aber nicht.
;Fenster erstellen
GUICreate("AD-Funktionen",600,580)
GUISetBkColor("0xFFFFCA")
GUISetFont(9,400,0,"Arial")
;Menübar anzeigen
$menu_dc = GUICtrlCreateMenu("DC", -1, 1)
$item_dc_dcs = GUICtrlCreateMenuItem("DC´s", $menu_dc)
$menu_help = GUICtrlCreateMenu("?", -1, 1)
$item_help_auto = GUICtrlCreateMenuItem("Autor", $menu_help)
$item_help_exit = GUICtrlCreateMenuItem("Beenden", $menu_help)
$menu_group = GUICtrlCreateMenu("Gruppen", -1, 1)
$item_group_search = GUICtrlCreateMenuItem("Mitgliedschaft", $menu_group)
_events()
;Fenster aufrufen
Func _events()
GUISetState(@SW_SHOW )
While 1
$msg = GUIGetMsg()
Select
case $msg = $GUI_EVENT_CLOSE or $msg = $item_help_exit
GUIDelete()
Exit
case $msg = $item_dc_dcs
_DCTab()
case $msg = $item_group_search
_GruppenTab()
EndSelect
WEnd
EndFunc
;Wenn im Menü DCs ausgewählt wurde...
func _DCTab()
Local $DCs, $DC
GuiCtrlCreateLabel("Domäne:", 10, 40)
GuiCtrlCreateLabel($strDomaine, 100, 40)
GuiCtrlCreateLabel("Logon-Server:", 10, 70)
GuiCtrlCreateLabel($strLogonServer, 100, 70)
$DCS = _ADDCList()
for $i = 1 to UBound($DCs,1)-1
$DC = $DC & $DCs[$i] & @CRLF
Next
GUICtrlCreateLabel("Domänen-Controller",10,140,140,20)
GUICtrlSetFont(-1,10,800)
GUICtrlCreateLabel($DC,10,170,270,380)
GUICtrlSetBkColor(-1,0xffffff)
EndFunc
;Wenn im Menü Gruppen ausgewählt wurden
Func _GruppenTab()
GUICtrlCreateLabel("Gruppe:",10,40)
$input_searchgroup = GuiCtrlCreateInput("", 100, 40, 140, 20)
$btn_searchgroup = GUICtrlCreateButton("Suchen", 270, 40, 60, 20)
EndFuncHallo ThinkCross,
warum löst du das ganze nicht mit einem Tab-Control z.B:
#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
;Fenster erstellen
[/autoit] [autoit][/autoit] [autoit]Global $strDomaine = "TestDomäne", $strLogonServer = "TestServer", $DCS = "Test-DC"
[/autoit] [autoit][/autoit] [autoit]Global $DCS, $DC
[/autoit] [autoit][/autoit] [autoit]GUICreate("AD-Funktionen", 600, 580)
GUISetBkColor("0xFFFFCA")
GUISetFont(9, 400, 0, "Arial")
;Menübar anzeigen
$menu_dc = GUICtrlCreateMenu("DC", -1, 1)
$item_dc_dcs = GUICtrlCreateMenuItem("DC´s", $menu_dc)
$menu_help = GUICtrlCreateMenu("?", -1, 1)
$item_help_auto = GUICtrlCreateMenuItem("Autor", $menu_help)
$item_help_exit = GUICtrlCreateMenuItem("Beenden", $menu_help)
$menu_group = GUICtrlCreateMenu("Gruppen", -1, 1)
$item_group_search = GUICtrlCreateMenuItem("Mitgliedschaft", $menu_group)
$hmainTab = GUICtrlCreateTab(0, 0, 600, 550)
$htabDC = GUICtrlCreateTabItem("DC's")
GUICtrlCreateLabel("Domäne:", 10, 40)
GUICtrlCreateLabel($strDomaine, 100, 40)
GUICtrlCreateLabel("Logon-Server:", 10, 70)
GUICtrlCreateLabel($strLogonServer, 100, 70)
;$DCS = _ADDCList()
For $i = 1 To UBound($DCS, 1) - 1
$DC = $DC & $DCS[$i] & @CRLF
Next
GUICtrlCreateLabel("Domänen-Controller", 10, 140, 140, 20)
GUICtrlSetFont(-1, 10, 800)
GUICtrlCreateLabel($DC, 10, 170, 270, 380)
GUICtrlSetBkColor(-1, 0xffffff)
$htabGroups = GUICtrlCreateTabItem("Gruppen")
GUICtrlCreateLabel("Gruppe:", 10, 40)
$input_searchgroup = GUICtrlCreateInput("", 100, 40, 140, 20)
$btn_searchgroup = GUICtrlCreateButton("Suchen", 270, 40, 60, 20)
GUICtrlCreateTabItem("") ; Beendet die Tab Definition
GUISetState(@SW_SHOW)
While 1
$msg = GUIGetMsg()
Select
Case $msg = $GUI_EVENT_CLOSE Or $msg = $item_help_exit
GUIDelete()
Exit
Case $msg = $item_dc_dcs
_GUICtrlTab_SetCurFocus($hmainTab, 0)
Case $msg = $item_group_search
_GUICtrlTab_SetCurFocus($hmainTab, 1)
EndSelect
WEnd
mfg (Auto)Bert
Hi,
Tabs hatte ich zuerst gehabt, finde ich aber nicht so ansprechend.
Schöner wäre es mit einer Menüleiste zu arbeiten und der untere Bereich wäre dann für das jeweilige Menü komplett separat gestaltbar.
Grüße
Guido
Hallo ThinkCross,
dann hätte ich noch eine Lösung mit Child-Guis anzubieten:
#include <GUIConstantsEx.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
;Fenster erstellen
[/autoit] [autoit][/autoit] [autoit]Global $strDomaine = "TestDomäne", $strLogonServer = "TestServer", $DCS = "Test-DC"
[/autoit] [autoit][/autoit] [autoit]Global $hmainGui, $hguiDC, $hguiGroup, $DCS, $DC
[/autoit] [autoit][/autoit] [autoit]$hmainGui = GUICreate("AD-Funktionen", 600, 580)
GUISetBkColor("0xFFFFCA")
GUISetFont(9, 400, 0, "Arial")
;Menübar anzeigen
$menu_dc = GUICtrlCreateMenu("&DC", -1, 1)
$item_dc_dcs = GUICtrlCreateMenuItem("DC´s", $menu_dc)
$menu_help = GUICtrlCreateMenu("?", -1, 1)
$item_help_auto = GUICtrlCreateMenuItem("Autor", $menu_help)
$item_help_exit = GUICtrlCreateMenuItem("Beenden", $menu_help)
$menu_group = GUICtrlCreateMenu("&Gruppen", -1, 1)
$item_group_search = GUICtrlCreateMenuItem("Mitgliedschaft", $menu_group)
GUISetState()
;Hilfsgui für DC's
$hguiDC = GUICreate("", 600, 556, 0, 0, BitOR($WS_CHILD, $WS_TABSTOP), -1, $hmainGui)
GUISetBkColor("0xFFFFCA")
GUICtrlCreateLabel("Domäne:", 10, 40)
GUICtrlCreateLabel($strDomaine, 100, 40)
GUICtrlCreateLabel("Logon-Server:", 10, 70)
GUICtrlCreateLabel($strLogonServer, 100, 70)
;$DCS = _ADDCList()
For $i = 1 To UBound($DCS, 1) - 1
$DC = $DC & $DCS[$i] & @CRLF
Next
GUICtrlCreateLabel("Domänen-Controller", 10, 140, 140, 20)
GUICtrlSetFont(-1, 10, 800)
GUICtrlCreateLabel($DC, 10, 170, 270, 380)
GUICtrlSetBkColor(-1, 0xffffff)
GUISetState()
;Hilfsgui für Gruppen
$hguiGroup = GUICreate("", 600, 556, 0, 0, BitOR($WS_CHILD, $WS_TABSTOP), -1, $hmainGui)
GUISetBkColor("0xFFFFCA")
GUICtrlCreateLabel("Gruppe:", 10, 40)
$input_searchgroup = GUICtrlCreateInput("", 100, 40, 140, 20)
$btn_searchgroup = GUICtrlCreateButton("Suchen", 270, 40, 60, 20)
GUISetState(@SW_HIDE)
While 1
$msg = GUIGetMsg()
Select
Case $msg = $GUI_EVENT_CLOSE Or $msg = $item_help_exit
GUIDelete()
Exit
Case $msg = $item_dc_dcs
GUISetState(@SW_SHOW, $hguiDC)
GUISetState(@SW_HIDE, $hguiGroup)
Case $msg = $item_group_search
GUISetState(@SW_SHOW, $hguiGroup)
GUISetState(@SW_HIDE, $hguiDC)
EndSelect
WEnd
mfg (Auto)Bert
Super, das ist genial, das ist genau das, was ich brauche. 
Danke
Grüße
Guido
Du hättest auch einfach
[autoit]@GUI_CtrlId
[/autoit]benutzen können 
Hallo @eF_Hacks,
das Beispiel ist im MsgLoop-Modus wie auch der Ursprung von ThinkCross. @GUI_CtrlId ist jedoch ausschliesslich im OnEvent-Modus verfügbar.
mfg (Auto)Bert
Hallo @eF_Hacks,
das Beispiel ist im MsgLoop-Modus wie auch der Ursprung von ThinkCross. @GUI_CtrlId ist jedoch ausschliesslich im OnEvent-Modus verfügbar.
mfg (Auto)Bert
Ups stimmt, du hast recht. Sorry 
Ich brauche noch eine Kleinigkeit
Der Wechsel der Hilfsfenster klappt ja super, wenn ich allerdings zum vorherigen Hilfsfenster zurück gehe, sehe ich noch den alten Inhalt, da dieser noch in den Variablen steht.
Gibt es einen Befehl um pauschal den Inhalt alle Variablen beim Aufruf eines neuen Hilfs-Fensters zu löschen?
Danke.
Grüße
Guido
