Wie finde ich heraus, welcher Menüeintrag gerade selektiert ist?

**Raupi**

Servus.

Habe folgendes Problem:
Ich möchte einen Hilftext in der Statusbar anzeigen, welcher Menüeintrag gerade selektiert ist. Hat jemand von euch einen Tipp für mich .
Habe schon versucht das ganze über WM_NOTIFY auszuwerten, leider ohne Erfolg. Welche Message wird beim highlighten eines Menüeintrages gesendet?

Edit ich meine welcher Menüeintrag in der Menüzeile selektiert ist, um Fragen vorzubeugen.

**autoBert**

Hallo raupi,

schau dir mal in der Hilfe _GUICtrlMenu_GetItemState und _GUICtrlMenu_GetItemHighlighted an. Hoffe dass hilft dir weiter

mfg (Auto)Bert

**Raupi**

autoBert.

Die Funktionen kenne ich, aber wenn man alle Menüeinträge stängig abfragt, wird das Script grottenlahm.
Zumal man das ganze dann mit AdlibEnable oder _Timer_SetTimer kombinieren muß und die Prozessorlast unerträglich wird.

**Oscar**

So groß ist die Prozessorlast doch gar nicht:

Spoiler anzeigen

[autoit]

#include <GuiMenu.au3>
#include <GuiStatusBar.au3>
#include <Timers.au3>
$hGui = GUICreate('Test', 400, 300)
Global $ahMenuItems[3]
$hMenu = GUICtrlCreateMenu('File')
$ahMenuItems[0] = GUICtrlCreateMenuItem('bla1', $hMenu)
$ahMenuItems[1] = GUICtrlCreateMenuItem('bla2', $hMenu)
$ahMenuItems[2] = GUICtrlCreateMenuItem('bla3', $hMenu)
$hStatus = _GUICtrlStatusBar_Create($hGui)
GUISetState()
$hTimer = _Timer_SetTimer($hGui, 100, '_Display')

[/autoit] [autoit][/autoit] [autoit]

Do
Until GUIGetMsg() = -3
_Timer_KillTimer($hGui, $hTimer)

[/autoit] [autoit][/autoit] [autoit]

Func _Display($hWnd, $Msg, $iIDTimer, $dwTime)
For $i = 0 To UBound($ahMenuItems) - 1
If _GUICtrlMenu_GetItemHighlighted(GUICtrlGetHandle($hMenu), $i) Then
_GUICtrlStatusBar_SetText($hStatus, GUICtrlRead($ahMenuItems[$i], 1))
Return
EndIf
Next
_GUICtrlStatusBar_SetText($hStatus, '')
EndFunc

[/autoit]

**Raupi**

Hm, stimmt so groß ist die Last nicht. Ich denke ich werde es erst mal so machen.

Danke euch beiden.

**Raupi**

Nach langen stöbern und probieren kann ich jetzt auch eine Lösung präsentieren.
Sie verwendet die Message WM_MENUSELECT. Ich hoffe es kann ausser mir noch jemand gebrauchen.

Spoiler anzeigen

[autoit]

#include <GuiMenu.au3>
#include <GuiStatusBar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

[/autoit] [autoit][/autoit] [autoit]

Const $MF_BYCOMMAND = 0x0
$hGui = GUICreate('Test', 400, 300)
Global $ahMenuItems[3]
$hMenu = GUICtrlCreateMenu('File')
$ahMenuItems[0] = GUICtrlCreateMenuItem('bla1', $hMenu)
$ahMenuItems[1] = GUICtrlCreateMenuItem('bla2', $hMenu)
$ahMenuItems[2] = GUICtrlCreateMenuItem('bla3', $hMenu)
$hStatus = _GUICtrlStatusBar_Create($hGui)
GUISetState()
GUIRegisterMsg($WM_MENUSELECT, "WM_MENUSELECT")

[/autoit] [autoit][/autoit] [autoit]

Do
Until GUIGetMsg() = -3

[/autoit] [autoit][/autoit] [autoit]

Func WM_MENUSELECT($hwnd, $iMsg, $iwParam, $ilParam)
Local $menuId, $aResult
$menuId = BitAND($iwParam, 0xFFFF)
$aResult = DllCall("User32.dll", "int", "GetMenuStringA", "hwnd", $ilParam, "int", $menuId, "str", 0, "int", 4096, "int", $MF_BYCOMMAND)
Switch $aResult[3]
Case "bla1"
_GUICtrlStatusBar_SetText($hStatus,"Menüeintrag bla1 wurde gewählt")
Case "bla2"
_GUICtrlStatusBar_SetText($hStatus,"Menüeintrag bla2 wurde gewählt")
Case "bla3"
_GUICtrlStatusBar_SetText($hStatus,"Menüeintrag bla3 wurde gewählt")
Case ""
_GUICtrlStatusBar_SetText($hStatus, '')
EndSwitch
Return $GUI_RUNDEFMSG
EndFunc ;==>WM_MENUSELECT

[/autoit]