Script mit Timer beendet sich nach ein paar Stunden von selbst

#NoTrayIcon
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_outfile=Fax.exe
#AutoIt3Wrapper_Icon=dummy2.ico
#AutoIt3Wrapper_Res_Icon_Add=dummy.ico
#AutoIt3Wrapper_Res_Icon_Add=dummy1.ico
#AutoIt3Wrapper_Res_Icon_Add=dummy3.ico
#AutoIt3Wrapper_Res_Icon_Add=dummy4.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****


#Include <Constants.au3>
#include <Timers.au3>


Opt("TrayMenuMode",1)    ; Default tray menu items (Script Paused/Exit) will not be shown.
Opt("MustDeclareVars", 1)


Global $iWait = 10000 ; Timerintervall
Global $faxitem, $aboutitem, $exititem,  $msg, $iTimerProgress
Global $FaxPath = "C:\Programme\my\Fax.exe", $first = 0
Global $counterNeu, $counterError, $text,$title, $counterSend


;Trayitems
$faxitem    = TrayCreateItem("Open MyFax")
TrayCreateItem("")
$aboutitem    = TrayCreateItem("About")
TrayCreateItem("")
$exititem    = TrayCreateItem("Exit")
TraySetState()
_settray()


If Not Winexists("MyFax") Then
	Run($FaxPath, "",@SW_MINIMIZE)
	Sleep (1000)
EndIf
If Winexists("MyFax") Then
	TrayTip ("Fax","Fax ist gestartet",1,1)
	TraySetToolTip ("Fax ist gestartet")
	Sleep (3000)
	TrayTip ("dummy","",0)
EndIf
$iTimerProgress = _Timer_SetTimer(0, $iWait, "_UpdateMyFax") ; create timer




While 1
	$msg = TrayGetMsg()
	Select
	    Case $msg = 0
	   	 ContinueLoop
	    Case $msg = $faxitem
	   	 If Not Winexists("MyFax") Then Run($FaxPath)
	   	 TraySetState(8)
	   	 WinSetState ("MyFax","",@SW_RESTORE)
	    Case $msg = $aboutitem
	   	 Msgbox(64, "MyFax watcher:", "© ID")
	    Case $msg = $exititem
	   	 ExitLoop
	EndSelect
WEnd
Exit






Func _UpdateMyFax($hWnd, $Msg, $iIDTimer, $dwTime)
	#forceref $hWnd, $Msg, $iIDTimer, $dwTime
	Local $strFaxActive, $iFaxActive, $strOldText
	If Winexists("MyFax") Then
	    If (not WinActive("MyFax"))  Then WinMenuSelectItem("MyFax", "", "&Journalanzeige", "Aktualisieren")
	    $strFaxActive = "MyFax ist gestartet."
	    $iFaxActive = 0
	Else
	    $strFaxActive = "MyFax nicht gestartet."
	    $iFaxActive = 2
	EndIf
	; Global $counterNeu, $counterError, $text,$title, $counterSend
	$strOldText = $text
	GetFax()
	If $text = "" then
	    TraySetState(8)
	    TrayTip ("MyFax:", "",1) ; löschen
	    _settray($iFaxActive)
	    TraySetToolTip ("Kein neues Fax" & @CRLF & $strFaxActive)
	Else
	    If $counterError <> 0 Then
	   	 _settray(3)
	    Else
	   	 _settray(1)
	    EndIf
	    TraySetToolTip($text & @CRLF & $strFaxActive)
	    If $text <> $strOldText  Then; Statusänderung
	   	 $strOldText = $text
	   	 TraySetState(4) ; blinkern
	   	 TrayTip($title,$text,1,1)
	   	 Sleep(3000)
	   	 TrayTip($title,"",1)
	    EndIf
	EndIf
EndFunc 








Func GetFax()
	Local $objconn =objCreate("ADODB.Connection")
	$objconn.ConnectionString="Provider=Microsoft.Jet.OLEDB.4.0;Data Source=T:\Fax;Extended Properties=dbase 5.0"
	Local $SQLstatement = "SELECT TOP 20 * FROM MyFax order by Datum desc"
	$objconn.Open ()
	Local $SQLexecute = $objConn.Execute($SQLstatement)
	Local $heute = @YEAR & @MON & @MDAY
	$counterNeu = 0
	$counterSend = 0
	$counterError = 0
	$text = ""
	$title = ""
	Local $stringError = "",  $Feldwert, $strSend
	With $SQLexecute
	 $Feldwert = ""
	 While Not .EOF
	  $Feldwert =   .Fields ("Datum").value 
	  if $Feldwert <> $heute then ExitLoop
	  $Feldwert =   .Fields ("Status").value
	  Switch $Feldwert
	    Case "a"
	   	 $counterNeu += 1
	    Case "b"
	    Case "2"
	    Case "1"
	   	 $counterSend += 1
	    Case Else
	   	 $stringError &= .Fields ("Error").value & "." & @CRLF
	   	 $counterError += 1 
	  EndSwitch
	 .MoveNext
	 WEnd
	EndWith
	$objconn.close()
	If $stringError <> "" Then $stringError = "Fehler: " & @CRLF & $stringError
	if $counterNeu > 1 Then 
	    $title = "Neue Faxe"
	    $text = "Es gibt " & $counterNeu & " neue Faxe."
	ElseIf $counterNeu > 0 Then
	    $title = "Neue Faxe"
	    $text = "Es gibt 1 neues Fax."
	EndIf
	if $counterSend > 0 Then 
	    if $title <> "" Then
	   	 $title &= "/Senden"
	    Else
	   	 $title = "Senden"
	    EndIf
	    $strSend = "1 Fax zu senden"
	    If $counterSend > 1 Then $strSend = $counterSend & " Faxe zu senden"
	    if $text <> "" Then
	   	 $text &= @CRLF & $strSend
	    Else
	   	 $text = $strSend
	    EndIf
	EndIf
	if $counterError > 0 Then 
	    if $title <> "" Then
	   	 $title &= "/Fehler"
	    Else
	   	 $title = "Fehler"
	    EndIf
	    if $text <> "" Then
	   	 $text &= @CRLF & @CRLF & $stringError
	    Else
	   	 $text = $stringError
	    EndIf
	EndIf
EndFunc


Func _settray($Farbe = 0)
if $Farbe = 0 then
	if @Compiled then
	    TraySetIcon(@AutoItExe,-5) 
	else
	    TraySetIcon("dummy.ico")
	EndIf
ElseIf $Farbe = 1 Then
	if @Compiled then
	    TraySetIcon(@AutoItExe,-6) 
	else
	    TraySetIcon("dummy1.ico")
	EndIf
ElseIf $Farbe = 2 Then
	if @Compiled then
	    TraySetIcon(@AutoItExe,-7) 
	else
	    TraySetIcon("dummy3.ico")
	EndIf
Else
	if @Compiled then
	    TraySetIcon(@AutoItExe,-8) 
	else
	    TraySetIcon("dummy4.ico")
	EndIf
EndIf
EndFunc