Ip Scanner Problem

war10ck

Ich wollte mir gerade einen IP scanner bauen, allerdings eralte ic entwerde kein ergebnis oder der IP scan funktioniert nicht.

Hat vllt jemand ne Idee warum???

Also, hier das Script:

Spoiler anzeigen

[autoit]

#include <inet.au3>
#include <array.au3>
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>

[/autoit] [autoit][/autoit] [autoit]

guicreate("Network Scanner",200,130)
guictrlcreatelabel("IP-Bereich:",10,10,100,30)
$1=guictrlcreateinput("192", 105,10,30,30)
$2=guictrlcreateinput("168",140,10,30,30)
$3=guictrlcreateinput("0",175,10,30,30)
$scan=guictrlcreatebutton("Scannen", 50,50,100,40)
$progress=guictrlcreateprogress(10,100,180,20)

[/autoit] [autoit][/autoit] [autoit]

guisetstate()

[/autoit] [autoit][/autoit] [autoit]

dim $array[257][2]
$array[0][0]="IP"
$array[0][1]="Name"
$i=0
tcpstartup()

[/autoit] [autoit][/autoit] [autoit]

while 1
$msg=guigetmsg()
if $msg= $scan Then
_scan()
_show()
elseif $msg= $GUI_EVENT_CLOSE then
exit
EndIf
sleep(100)
WEnd

[/autoit] [autoit][/autoit] [autoit]

func _scan()
$i=0
for $i=0 to $i= 256
$ip= guictrlread($1) & "." & guictrlread($2) & "." & guictrlread($3) & "." & $i
$array[$i+1][0]=$ip
$array[$i+1][0]=_tcpiptoname($ip,0,"ws2_32.dll")
$i+=1
guictrlsetdata($progress, (100/256)*($i))
next
EndFunc

[/autoit] [autoit][/autoit] [autoit]

func _show()
_arraydisplay($array, "IP´s / Names")
endfunc

[/autoit] [autoit][/autoit] [autoit][/autoit]

**Sprenger120**

habe das mal gebaut (vor einiger zeit)
könnte vlt nicht funzen

Spoiler anzeigen

[autoit]

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#include <GuiIPAddress.au3>

[/autoit] [autoit][/autoit] [autoit]

$_1 = GUICreate("IP-Scanner", 558, 262, 192, 124)
$List = GUICtrlCreateListView("IP|Zeit", 8, 40, 537, 169)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 50)
$Start = GUICtrlCreateButton("Start", 8, 216, 537, 41, $WS_GROUP)
GUICtrlCreateGroup("IP", 8, 0, 537, 33)
$show_ip = GUICtrlCreateLabel("", 176, 8, 115, 17)
$IPAddress1 = _GUICtrlIpAddress_Create($_1, 32, 8, 130, 21)
GUISetState(@SW_SHOW)

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $Start
$ip = _GUICtrlIpAddress_Get ($IPAddress1)
$xip = StringSplit($ip, ".")
_ArrayDelete ($xip, 0)
;_ArrayDisplay ($xip, "")
Do
$xip[3] = $xip[3] + 1
If $xip[3] > 233 Then
$xip[2] = $xip[2] + 1
$xip[3] = 0
EndIf
If $xip[2] > 233 Then $xip[1] = $xip[1] + 1
If $xip [1] > 233 Then $xip[0] = $xip[0] + 1
$sip = _ArrayToString ($xip, ".")
$ping = Ping ($sip)
if $ping <> 0 Then GUICtrlCreateListViewItem ($sip & "|" & $ping, $List)
GUICtrlSetData ($show_ip, $sip)
Until GUIGetMsg() = -3
EndSwitch
WEnd

[/autoit] [autoit][/autoit] [autoit][/autoit]

SEuBo

1. For $i = 0 To 255, nicht For $i = 0 To $i = 255
2. In einer for-next schleife brauchst du kein $i += 1
3. _TCPIpToName braucht einen DLL handle! Also gefälligst ein DLLOpen() am anfang des skriptes
4. Nimm das If $msg = ... aus deiner Hauptschleife! Das macht alles nur noch langsamer als es eh schon ist. Switch / select ist die richtige wahl. Switch > Select > If.
5. IP's gehen von 0 bis 255, nicht 256
6. Ich würde 255 mal Ping.exe aufrufen (parrallel). Damit erfährst du am schnellsten, welche IP's erreichbar sind. Und nur diese musst du dann nochmal mit _TCPIPToName abfragen.

Spoiler anzeigen

[autoit]

#include <inet.au3>
#include <array.au3>
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>

[/autoit] [autoit][/autoit] [autoit]

GUICreate("Network Scanner", 200, 130)
GUICtrlCreateLabel("IP-Bereich:", 10, 10, 100, 30)
$1 = GUICtrlCreateInput("192", 105, 10, 30, 30)
$2 = GUICtrlCreateInput("168", 140, 10, 30, 30)
$3 = GUICtrlCreateInput("0", 175, 10, 30, 30)
$scan = GUICtrlCreateButton("Scannen", 50, 50, 100, 40)
$progress = GUICtrlCreateProgress(10, 100, 180, 20)
$dll = DllOpen("ws2_32.dll")
GUISetState()

[/autoit] [autoit][/autoit] [autoit]

Dim $array[257][2]
$array[0][0] = "IP"
$array[0][1] = "Name"
$i = 0
TCPStartup()

[/autoit] [autoit][/autoit] [autoit]

While 1
$msg = GUIGetMsg()
If $msg = $scan Then
_scan()
_show()
ElseIf $msg = $GUI_EVENT_CLOSE Then
Exit
EndIf
Sleep(100)
WEnd

[/autoit] [autoit][/autoit] [autoit]

Func _scan()
$i = 0
For $i = 0 To 255
$ip = GUICtrlRead($1) & "." & GUICtrlRead($2) & "." & GUICtrlRead($3) & "." & $i
ConsoleWrite($ip&@CRLF)
$array[$i + 1][0] = $ip
$array[$i + 1][0] = _TCPIpToName($ip, 0, $dll )
GUICtrlSetData($progress, (100 / 255) * ($i))
Next
EndFunc ;==>_scan

[/autoit] [autoit][/autoit] [autoit]

Func _show()
_ArrayDisplay($array, "IP´s / Names")
EndFunc ;==>_show

[/autoit] [autoit][/autoit] [autoit]

DllClose($dll)

[/autoit]

m-obi

Also:
1. Das Array $array muss lauten [256][2] nicht [257][2]
2. Die For_schleife muss heißen for $i=0 to 255 nicht for $i=0 to $i=256 -> die max. IP-Zahl ist 255
3. $array[$i+1][1]=_tcpiptoname($ip,0,"ws2_32.dll") nicht $array[$i+1][0]=_tcpiptoname($ip,0,"ws2_32.dll")
4. Wenn du dies schreibst

[autoit]

$i+=1
guictrlsetdata($progress, (100/256)*($i))

[/autoit]

dann lässt er jede zweite Zahl aus, also in der Reihenfolge 0, 2, 4, 6, 8 ...

Versuch mal den:

Spoiler anzeigen

[autoit]

#include <inet.au3>
#include <array.au3>
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>

[/autoit] [autoit][/autoit] [autoit]

guicreate("Network Scanner",200,130)
guictrlcreatelabel("IP-Bereich:",10,10,100,30)
$1=guictrlcreateinput("192", 105,10,30,30)
$2=guictrlcreateinput("168",140,10,30,30)
$3=guictrlcreateinput("0",175,10,30,30)
$scan=guictrlcreatebutton("Scannen", 50,50,100,40)
$progress=guictrlcreateprogress(10,100,180,20)

[/autoit] [autoit][/autoit] [autoit]

guisetstate()

[/autoit] [autoit][/autoit] [autoit]

dim $array[256][2]
$array[0][0]="IP"
$array[0][1]="Name"
$i=0
tcpstartup()

[/autoit] [autoit][/autoit] [autoit]

while 1
$msg=guigetmsg()
if $msg= $scan Then
_scan()
_show()
elseif $msg= $GUI_EVENT_CLOSE then
exit
EndIf
WEnd

[/autoit] [autoit][/autoit] [autoit]

func _scan()
$i=0
for $i=0 to 255
ConsoleWrite($i & ";")
$ip= guictrlread($1) & "." & guictrlread($2) & "." & guictrlread($3) & "." & $i
$array[$i+1][0]=$ip
$array[$i+1][1]=_tcpiptoname($ip,0,"ws2_32.dll")
guictrlsetdata($progress, (100/256)*($i+1))
next
EndFunc

[/autoit] [autoit][/autoit] [autoit]

func _show()
_arraydisplay($array, "IP´s / Names")
endfunc

[/autoit]

Edit: Minimal zu spät

war10ck

OK thx erstmal.

Ich werd das mit den paralellen ping.exe´s mal einbauen, das is mir so echt zu langsam^^

Mfg

m-obi

Am besten so:

[autoit]

func _scan()
$dll = DllOpen("ws2_32.dll")
$i=0
for $i=0 to 255
ConsoleWrite($i & ";")
$ip= guictrlread($1) & "." & guictrlread($2) & "." & guictrlread($3) & "." & $i
guictrlsetdata($progress, Round((100/256)*($i+1), 0))
If Ping($ip, 200) Then
$array[$i+1][0]=$ip
$array[$i+1][1]=_tcpiptoname($ip,0,$dll)
Else
$array[$i+1][0]=$ip
$array[$i+1][1]="N/A"
EndIf
next
DllClose($dll)
EndFunc

[/autoit]

Bau lieber noch einen Abbrechen-Button rein :D.

SEuBo

Nein, m-obi. das ist noch zu langsam. am besten so:

Spoiler anzeigen

[autoit]

#include <inet.au3>
#include <array.au3>
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>

[/autoit] [autoit][/autoit] [autoit]

GUICreate("Network Scanner", 200, 130)
GUICtrlCreateLabel("IP-Bereich:", 10, 10, 100, 30)
$1 = GUICtrlCreateInput("192", 105, 10, 30, 30)
$2 = GUICtrlCreateInput("168", 140, 10, 30, 30)
$3 = GUICtrlCreateInput("0", 175, 10, 30, 30)
$scan = GUICtrlCreateButton("Scannen", 50, 50, 100, 40)
$progress = GUICtrlCreateProgress(10, 100, 180, 20)
$dll = DllOpen("ws2_32.dll")
GUISetState()

[/autoit] [autoit][/autoit] [autoit]

Dim $array[257][2]
$array[0][0] = "IP"
$array[0][1] = "Name"
$i = 0
TCPStartup()

[/autoit] [autoit][/autoit] [autoit]

While 1 * Sleep(10)
$msg = GUIGetMsg()
Switch $msg
Case $scan
_scan()
_show()
Case -3
Exit
EndSwitch
WEnd

[/autoit] [autoit][/autoit] [autoit]

Func _scan()
FileDelete("ping.ini")
For $i = 0 To 255
$ip = GUICtrlRead($1) & "." & GUICtrlRead($2) & "." & GUICtrlRead($3) & "." & $i
Run("ping.exe "& $ip)
ConsoleWrite($ip&@CRLF)
Next
GUICtrlSetData($progress, 50)
Do
Sleep(100)
Until Not ProcessExists("ping.exe")
$pings = IniReadSection("ping.ini","pings")
For $i = 1 to UBound($pings)-1
$subIP = StringReplace($pings[$i][0],GUICtrlRead($1)&"."&GUICtrlRead($2)&"."&GUICtrlRead($3)&".","")
ConsoleWrite($subIP&@CRLF)
$array[$subIP+1][0] = $pings[$i][0]
If Number($pings[$i][1]) <> 0 Then
$array[$subIP+1][1] = _TCPIpToName($pings[$i][0], 0, $dll)
If $array[$subIP+1][1] = "" Then
$array[$subIP+1][1] = "Unnamed Host"
EndIf
Else
$array[$subIP+1][1] = "Error: ("&$pings[$i][1]&")"
EndIf
GUICtrlSetData($progress, 50+(100/255*$i)/2)
Next
FileDelete("ping.ini")
EndFunc ;==>_scan

[/autoit] [autoit][/autoit] [autoit]

Func _show()
_ArrayDisplay($array, "IP´s / Names")
EndFunc ;==>_show

[/autoit] [autoit][/autoit] [autoit]

DllClose($dll)

[/autoit]

ping.exe:

Spoiler anzeigen

[autoit]

#NoTrayIcon
;Diese Datei muss als "Ping.exe" compiliert werden
If $cmdline[0] = 1 Then
$ping = Ping($cmdline[1])
If @error Then
Switch @error
Case 1
IniWrite("ping.ini","pings",$cmdline[1],"Host is offline")
Case 2
IniWrite("ping.ini","pings",$cmdline[1],"Host is unreachable")
Case 3
IniWrite("ping.ini","pings",$cmdline[1],"Bad destination")
Case 4
IniWrite("ping.ini","pings",$cmdline[1],"Other errors")
EndSwitch
Else
IniWrite("ping.ini","pings",$cmdline[1],$ping)
EndIf
EndIf

[/autoit]

Edit: inidelete() sollte FileDelete() heißen. habs jetzt ausgebessert

war10ck

Danke m-obi funkt super!

Nur muss ich das noch iwie schneller machen, ich bastle gerade an der Version mit 256 mal ping.exe paralell asuführen, und nur die nochmal scannen die vorhanden sind, allerdings bekomm ich das mit den Rückgabewerten iwie nciht hin, bzw ich bekomme immer nur 0 od die PID zurück.

Kann sein das ich ein bisschen auf der Leitung stehe heute xD

mfg

/edit: danke seubo, werd ich gleich mal testen

war10ck

Seubo ich bin echt beeindruck, vielen Dank, ich werd noch versuchen das mit TCpiptoname iwie extern zu beschleunigen, mal gucken was ich so finde xD

Mfg

/edit: in zeile 58 gehört stat dem Inidelete filedelete(@scriptir & "ping.ini") rein

SEuBo

Dafür bin ich doch da
Mach am besten ncoh einmal FileDelete in Zeile 32. Damit, falls die ini doch noch existieren sollte (beenden des prozesses, rechnerabsturz usw.), die ini auf jeden fall neu geschrieben wird.

Viel glück noch mit deinem script.

war10ck

OK bau ich gleich ein

THX

Ich werd mal gucken ob ichs noch beschleunigen kann (wie auch immer, mal gucken xd) und vllt noch ein paar funktionen einbauen

Mfg

**Oscar**

Wenn man eine nicht existierende IP-Adresse anpingt, dauert es immer relativ lange, bis der Ping-Befehl "reagiert".
Beim DOS-Ping kann man die Wartezeit einstellen. Allerdings nur bis ca. 100ms runter.
Hier mal eine Funktion dafür:

Spoiler anzeigen

[autoit]

#include <Array.au3>
#include <Constants.au3>
#include <Inet.au3>
$iTimer = TimerInit()
$aRange = _ScanIPRange('192.168.1.')
ConsoleWrite(Round(TimerDiff($iTimer) / 1000, 3) & ' sek.' & @CR)
_ArrayDisplay($aRange)

[/autoit] [autoit][/autoit] [autoit]

Func _ScanIPRange($sIP_Range, $iWaitms = 100)
If Not StringRegExp($sIP_Range, '\d{1,3}\.\d{1,3}\.\d{1,3}\.') Then Return SetError(1, 0, 0)
Local $sPID, $sOut, $aOut[1][2]
TCPStartup()
For $i = 1 To 255
$sOut = ''
$sError = ''
ToolTip('Scanne IP: ' & $sIP_Range & $i)
$sPID = Run(@ComSpec & ' /c ping -w ' & $iWaitms & ' -4 -n 1 ' & $sIP_Range & $i, @SystemDir, @SW_HIDE, $STDOUT_CHILD)
Do
Sleep(10)
$sOut &= StdoutRead($sPID)
Until @error <> 0
If Not StringInStr($sOut, '100% Verlust') Then
$aOut[UBound($aOut) - 1][0] = $sIP_Range & $i
$aOut[UBound($aOut) - 1][1] = _TCPIpToName($sIP_Range & $i)
ReDim $aOut[UBound($aOut) + 1][2]
EndIf
Next
ReDim $aOut[UBound($aOut) - 1][2]
ToolTip('')
TCPShutdown()
Return $aOut
EndFunc ;==>_ScanIPRange

[/autoit]

war10ck

Danke Oscar, war grad selbst dabei sowas zu machen xD

Das gröst problem is aber nicht unbedingt die Zeit die fürs pingen draufgeht, sondern vielmehr die Zeit für _TCpIPtoName, das dauert jeweils ca. 3-5 sec und alle Pings zusammengefasst brauchen eig auch nciht länger

Hast irgendwer vllt ne Idee wie man das beschleunigen kann???

Mfg

**Oscar**

Also bei mir ist es der Ping-Befehl, der das Zeitlimit negativ beeinflusst.
Aber mir ist gerade aufgefallen, dass man ohne _TCPNameToIP() auskommen kann, weil der DOS-Ping auch eine Namensauflösung beinhaltet.

Spoiler anzeigen

[autoit]

#include <Array.au3>
#include <Constants.au3>
$iTimer = TimerInit()
$aRange = _ScanIPRange('192.168.1.')
ConsoleWrite(Round(TimerDiff($iTimer) / 1000, 3) & ' sek.' & @CR)
_ArrayDisplay($aRange)

[/autoit] [autoit][/autoit] [autoit]

Func _ScanIPRange($sIP_Range, $iWaitms = 100)
If Not StringRegExp($sIP_Range, '\d{1,3}\.\d{1,3}\.\d{1,3}\.') Then Return SetError(1, 0, 0)
Local $sPID, $sOut, $aOut[1][2], $sTmp
For $i = 1 To 255
$sOut = ''
ToolTip('Scanne IP: ' & $sIP_Range & $i)
$sPID = Run(@ComSpec & ' /c ping -a -w ' & $iWaitms & ' -4 -n 1 ' & $sIP_Range & $i, @SystemDir, @SW_HIDE, $STDOUT_CHILD)
Do
Sleep(10)
$sOut &= StdoutRead($sPID)
Until @error <> 0
If Not StringInStr($sOut, '100% Verlust') Then
$aOut[UBound($aOut) - 1][0] = $sIP_Range & $i
$sTmp = StringRegExpReplace($sOut, '(?s).+Ping (\H+?) .+', '$1')
If $sTmp = 'wird' Then $sTmp = 'Hostname nicht gefunden'
$aOut[UBound($aOut) - 1][1] = $sTmp
ReDim $aOut[UBound($aOut) + 1][2]
EndIf
Next
ReDim $aOut[UBound($aOut) - 1][2]
ToolTip('')
Return $aOut
EndFunc ;==>_ScanIPRange

[/autoit]

war10ck

Hmm Oscar das von dir is relativ lahm, da is die UAtoit Ping funktion um einiges schneller als die Windoof version

Ich werd mal gucken ob ich mit dem Windows teil die NAmen schneller bekomme als mit _TCPIptoName und wenn werd ich das dann für das Herausfinden von den namen verwenden

Mfg

m-obi

Also bei mir braucht am längsten der Ping, TCPIPToName läuft schnell ab. Das seltsame bei dem Ping ist, wenn ich z.B. ein Timeout angebe von 100ms macht der aber 500ms, bei 800ms macht er in Wirklichkeit 500ms, bei 1000ms macht er 1000ms. Das verstehe ich nicht.

Spoiler anzeigen

[autoit]

#include <inet.au3>
#include <array.au3>
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>

[/autoit] [autoit][/autoit] [autoit]

guicreate("Network Scanner",200,130)
guictrlcreatelabel("IP-Bereich:",10,10,60,20)
$1=guictrlcreateinput("192", 65,10,30,20)
$2=guictrlcreateinput("168",100,10,30,20)
$3=guictrlcreateinput("178",135,10,30,20)
$scan=guictrlcreatebutton("Scannen", 10,50,80,30)
$abort=guictrlcreatebutton("Abbrechen", 100,50,80,30)
$progress=guictrlcreateprogress(10,100,180,20)

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

guisetstate()

[/autoit] [autoit][/autoit] [autoit]

dim $array[256][2]
$array[0][0]="IP"
$array[0][1]="Name"
$i=0
tcpstartup()

[/autoit] [autoit][/autoit] [autoit]

while 1
$msg=guigetmsg()
if $msg= $scan Then
_scan()
_show()
elseif $msg= $GUI_EVENT_CLOSE then
exit
EndIf
WEnd

[/autoit] [autoit][/autoit] [autoit]

func _scan()
$dll = DllOpen("ws2_32.dll")
$i=0

[/autoit] [autoit][/autoit] [autoit]

for $i=0 to 255
ConsoleWrite($i & ";")
$ip= guictrlread($1) & "." & guictrlread($2) & "." & guictrlread($3) & "." & $i
guictrlsetdata($progress, (100/256)*($i+1))
$begin = TimerInit()
$ping = Ping($ip, 800)
$time = TimerDiff($begin)
If $ping Then
$array[$i+1][0]=$ip & ":" & Round($time, 0) & "ms"
$array[$i+1][1]=_tcpiptoname($ip,0,$dll)
Else
$array[$i+1][0]=$ip & ":" & Round($time, 0) & "ms"
$array[$i+1][1]="N/A"
EndIf
If guigetmsg() = $abort Then ExitLoop
next
DllClose($dll)
EndFunc

[/autoit] [autoit][/autoit] [autoit]

func _show()
_arraydisplay($array, "IP´s / Names")
endfunc
TCPShutdown()

[/autoit]

war10ck

Probier mal das von seubo, da geht der Ping wirklich sehr schnell, nur der tcpiptoname braucht lange, und das is ncoh das Problem. Hab jetzt versucht das auch so zu machen wie er das mit dem Ping gelöst hat, dauert aber noch immer rect lange bis das was wird.

mfg

m-obi

Also zwischen SEuBo und meins liegen nur ein paar Sekunden, TCPIPToName dauert bei mir ca. 100ms. Aber ich bin grad dabei selbst einen IP Scanner zu basteln, mal sehen wies wird . Nur meiner scannt nicht z.B. 192.168.100.0 bis 192.168.100.255 sondern z.B. 192.168.100.25 bis 192.168.120.100., weiß vielleicht jemand ob die Zahlen Namen haben, also 1., 2., 3. und 4. Zahl?

war10ck

nur 100ms fürtcpiptoname?? bei mir dauert das Jeweils 1-2sec. Welches Betriebsystem hast du???

Ich wüsste nicht wofür man einen Scanner brauch der mehrere Adressbereiche Scannt. Höchstens du willst das Inet scannen, nur das daert sowiso ewig und dir wird dabei der Pc abkacken, jedenfalls wenn du autoit verwendest dafür.

Vllt hilft dir das weiter: http://de.wikipedia.org/wiki/IP-Adresse

Soweit ich weis gibt es nicht wirklich namen dafür. Allerdings Ist die 1. Zahl so eine Art Obergruppe, die Zweite dann eine Untergruppe usw. Die Letzte Zahl ist dann die Zahl die der Pc in diesem Ip-Adress bereich hat.

Mfg