rechte maustaste emulieren

  • Guten Abend

    bin neu bei dem AutoIT also bitte n bissl rücksicht hab noch gar kein Plan von dem Programm
    naja nun zu meinem Problem

    und zwar bräuchte ma hilfe nem script
    und zwar soll es folgendes können
    es soll mir die rechte maustaste emulieren auf nem hotkey da meine rechte maustaste kaputt is. ich habs schonmal versucht nur iwie klappt das net so wie ich es will

    HotKeySet("middle")
    MouseDown("right")
    Sleep(100)
    MouseUp("right")

    was mach ich falsch?

    wäre super wenn mir jeamdn helfen könnte da das Scripten ja doch ziemlich komplex ist

  • Habs mal auf die Strg. Taste gemacht.

    [autoit]

    #include <Misc.au3>

    [/autoit][autoit][/autoit][autoit]

    While 1
    If _IsPressed("11") Then ; 11 bedeutet Strg bzw. Ctrl
    MouseDown("right")
    Sleep(50)
    MouseUp("right")
    EndIf
    WEnd

    [/autoit]

    Meine Projekte:
    ClipBoard Manager (beendet)
    Gutes ClipBoard Verwaltungs Programm mit nützlichen Funktionen.

    HTML Creator (beendet)
    Nützliches Tool um schnell ein eigenes HTML Dokument zu erstellen.

  • ok schon und gut funktioniert auch einwandfrei

    was müsste ich eingeben damit das strg also die 11 da oben drin zur mittleren maustaste wird "middle" da hinzumachen funktioniert leider nicht es ist einzig und allein wegen der handhabung

    • Offizieller Beitrag
    [autoit]

    #include <Misc.au3>

    [/autoit][autoit][/autoit][autoit]

    While 1
    If _IsPressed("04") Then ; 04 bedeutet: Middle mouse button (three-button mouse)
    MouseDown("right")
    Sleep(50)
    MouseUp("right")
    EndIf
    WEnd

    [/autoit][autoit][/autoit][autoit][/autoit][autoit][/autoit]
  • ich würde es noch etwas abändern (falls du die mittlere taste länger als 50ms drückst)

    [autoit]

    #include <Misc.au3>

    [/autoit][autoit][/autoit][autoit]

    While 1
    If _IsPressed("04") Then ; 04 bedeutet: Middle mouse button (three-button mouse)
    MouseDown("right")
    Sleep(50)
    MouseUp("right")
    While _isPressed("04")
    sleep(10)
    Wend
    EndIf
    WEnd

    [/autoit]


    (ungetestet, sollte dennoch funktionieren) :rolleyes:

    Wer immer nur das tut, was er bereits kann - wird auch immer nur das bleiben, was er bereits ist!

    • Offizieller Beitrag

    Wenn schon mit Abfrage, wie lange die mittlere Maustaste gedrückt wurde, dann so:

    [autoit]

    #include <Misc.au3>

    [/autoit][autoit][/autoit][autoit]

    While 1
    If _IsPressed("04") Then ; 04 bedeutet: Middle mouse button (three-button mouse)
    MouseDown("right")
    While _IsPressed("04")
    Sleep(10)
    WEnd
    MouseUp("right")
    EndIf
    WEnd

    [/autoit]
    • Offizieller Beitrag

    Besser (bzw. gründlicher, Down und Up werden separat behandelt) als _IsPressed ist es, den Middle-Mausklick abzufangen und dem System einen Right-Klick zu senden.
    Das läßt sich mittels Hook realisieren.
    - Empfange Middle-Down, verwerfe diese Message und sende Right-Down an das System
    - Empfange Middle-Up, verwerfe diese Message und sende Right-Up an das System

    So sieht das dann aus:

    Spoiler anzeigen
    [autoit]

    #include <Constants.au3>
    #include <WinAPI.au3>
    #include <WindowsConstants.au3>
    Global Const $HC_ACTION = 0
    Global $hStub_MouseProc = DllCallbackRegister("_MouseProc", "long", "int;wparam;lparam")
    Global $hmod = _WinAPI_GetModuleHandle(0)
    Global $hHook = _WinAPI_SetWindowsHookEx($WH_MOUSE_LL, DllCallbackGetPtr($hStub_MouseProc), $hmod)

    [/autoit] [autoit][/autoit] [autoit]

    HotKeySet('^+!e', '_ende') ; STRG+SHIFT+ALT+e zum Beenden
    OnAutoItExitRegister('ExitFunc')

    [/autoit] [autoit][/autoit] [autoit]

    While 1
    Sleep(100)
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func _ende()
    Exit
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func _MouseProc($nCode, $wParam, $lParam)
    If $nCode < 0 Then
    Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
    EndIf
    If $nCode = $HC_ACTION Then
    Switch $wParam
    Case $WM_MBUTTONDOWN
    Return _mouse_event($MOUSEEVENTF_RIGHTDOWN) ; sendet -1 zurück, Original-Mausklick wird ignoriert
    Case $WM_MBUTTONUP
    Return _mouse_event($MOUSEEVENTF_RIGHTUP) ; sendet -1 zurück, Original-Mausklick wird ignoriert
    EndSwitch
    EndIf
    Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func ExitFunc()
    _WinAPI_UnhookWindowsHookEx($hHook)
    DllCallbackFree($hStub_MouseProc)
    EndFunc ;==>OnAutoItExit

    [/autoit] [autoit][/autoit] [autoit]

    Func _mouse_event($dwFlags)
    DllCall("user32", 'long', 'mouse_event', 'long', $dwFlags, 'long', 0, 'long', 0, 'long', 0, 'long', 0)
    Return -1
    EndFunc

    [/autoit]