Patcher erstellen

#include<Crypt.au3>

; Funktion zum Erstellen der Dateiliste, die der Updater runterladen wird
; $sFile ist die Datei, in der die Hash-Strings gespeichert werden
; $sUpdateDir ist das Verzeichnis, dess Dateien gelistet werden sollen (rekursiv)
; $sDownloadDir ist die URL mit Verzeichnis, in dem die aktuellen Dateien liegen werden.
Func _CreateUpdatesList($sFile, $sUpdateDir, $sDownloadDir)
; Author: Prog@ndy
If StringRight($sUpdateDir,1)<>'\' Then $sUpdateDir &= '\'
If StringRight($sDownloadDir,1)<>'/' Then $sDownloadDir &= '/'
Local Const $iDirLen = StringLen($sUpdateDir)
Local $aFileList = _FileListToArrayRek($sUpdateDir)
If @error Then Return SetError(1,0,0)
Local $hFile = FileOpen($sFile, 258)
If @error Then Return SetError(2,0,0)
_Crypt_Startup()
For $i = 1 To $aFileList[0]
$sSubPath = StringTrimLeft($aFileList[$i], $iDirLen)
$sHash = _Crypt_HashFile($aFileList[$i], $CALG_MD5)
FileWrite($hFile, StringFormat("%s|%s|%s%s\r\n", $sSubPath, $sHash, $sDownloadDir, StringReplace($sSubPath, '\', '/', 0, 1)))
Next
_Crypt_Shutdown()
FileClose($hFile)
Return 1
EndFunc

Func _FileListToArrayRek($sPath)
; Author: Prog@ndy
Local Static $files, $depth=0
If StringRight($sPath,1)<>'\' Then $sPath &= '\'
Local $hFind = FileFindFirstFile($sPath & "\*.*"), $sFile
If @error=-1 Then Return SetError(1,0,0)
$depth += 1
While 1
$sFile = FileFindNextFile($hFind)
If @error Then ExitLoop
Switch @extended
Case 1
Sleep(10)
_FileListToArrayRek($sPath&$sFile)
Case Else
$files &= $sPath&$sFile&'|'
EndSwitch
WEnd
FileClose($hFind)
$depth -= 1
If $depth=0 Then
If $files='' Then Return SetError(1,0,0)
Return StringSplit(StringTrimRight($files,1), '|')
EndIf
EndFunc

; ------------------------------------------------------------------------------------------------------------------------
; BEISPIEL:
; ------------------------------------------------------------------------------------------------------------------------
_CreateUpdatesList(@ScriptDir&'\updates.txt', @ScriptDir&'\dateien', 'http://example.com/update')
; ------------------------------------------------------------------------------------------------------------------------
; ------------------------------------------------------------------------------------------------------------------------

#include<Crypt.au3>

; $sUpdateURL: Datei im Internet oder lokal, die die MD%-Hashes enthält
; $sUpdatePath: Das Verzeichnis, in dem die Dateien verglichen und werden
Func _CheckUpdates($sUpdateURL, $sUpdatePath)
; Author: Prog@ndy
;~ ; Beispielformat für die Textdatei (UTF-8 ohne BOM):
;~ Dateiname|MD5-Hash|Download-Adresse{@CRLF}
;~ test.txt|0x16f50d7f1078ae2116f3e9fa4ba25203|http:/download.com/a.txt
;~ temp.txt|0x0401DEFCF635DE4EAE161DC1F0F643DA|http:/download.com/b.txt
$sUpdatePath = StringReplace(StringReplace($sUpdatePath, '/', '\')&'\', '\\', '\')
Local $aUpdateFiles[1][4] = [[0]]
Switch StringInStr($sUpdateURL, "://")
Case 0
Local $hFile = FileOpen($sUpdateURL, 16)
If @error Then Return SetError(1,0,0)
Local $sSource = FileRead($hFile)
FileClose($sSource)
Case Else
Local $sSource = InetRead($sUpdateURL)
If @error Then Return SetError(1,0,0)
EndSwitch
;~ $sSource = StringToBinary("test.txt|0x16f50d7f1078ae2116f3e9fa4ba25203|http:/download.com/a.txt" & @CRLF & _
;~ "temp.txt|0x0401DEFCF635DE4EAE161DC1F0F643DA|http:/download.com/b.txt", 4)
$sSource = StringSplit(BinaryToString($sSource, 4), @CRLF, 1)
If StringLeft($sSource[1], 3) = Chr(0xEF)&Chr(0xBB)&Chr(0xBF) Then $sSource[1] = StringTrimLeft($sSource[1], 3)
Local $aFile, $sHash
Local $aUpdateFiles[$sSource[0]+1][4] = [[0]]
_Crypt_Startup()
For $i = 1 To $sSource[0]
$aFile = StringSplit($sSource[$i], '|', 2)
If UBound($aFile)<>3 Then ContinueLoop ; Name|MD5|URL
$sHash = _Crypt_HashFile($sUpdatePath & $aFile[0], $CALG_MD5)
If $aFile[1] <> $sHash Then
$aUpdateFiles[0][0] += 1
$aUpdateFiles[$aUpdateFiles[0][0]][0] = $aFile[0]
$aUpdateFiles[$aUpdateFiles[0][0]][1] = $aFile[1]
$aUpdateFiles[$aUpdateFiles[0][0]][2] = $aFile[2]
$aUpdateFiles[$aUpdateFiles[0][0]][3] = $sHash
EndIf
Next
ReDim $aUpdateFiles[$aUpdateFiles[0][0]+1][4]
_Crypt_Shutdown()
Return $aUpdateFiles
; Rückgabe:
;~ Dateiname|MD5-Hash|Download-Adresse|lokaler MD5{@CRLF}
EndFunc

; ------------------------------------------------------------------------------------------------------------------------
; BEISPIEL:
; ------------------------------------------------------------------------------------------------------------------------
#include<Array.au3>
$sZiel = @ScriptDir&'\dateien\'
$aUpdates = _CheckUpdates(@ScriptDir&'\updates.txt', $sZiel)
_ArrayDisplay($aUpdates)
For $i = 1 To $aUpdates[0][0]
MsgBox(0, '', "z.B. Download datei..."& @CRLF & $aUpdates[$i][0] & @CRLF & "Von: " & $aUpdates[$i][2] &@CRLF & "Nach: " & $sZiel)
Next
; ------------------------------------------------------------------------------------------------------------------------
; ------------------------------------------------------------------------------------------------------------------------