Festplatte durchsuchen

EpicWorld

Guten Tag,

ich wollte fragen wie ich es machen kann das AutoIt nach bestimmen Schlüsselwörtern auf der Festplatte such.

Ich hab bis jetzt nur die lösung gefunden:

[autoit]

$File = FileFindFirstFile("test.exe")

[/autoit][autoit][/autoit][autoit]

FileWrite("Funde.txt","Testexe gefunden: " & $File)

[/autoit]

Jedoch ist hier das Problem das es nur im Scriptverzeichnis sucht, nicht nach schlüsselwörter sondern nur nach dem 100% einstimmigen datei und das es in die txt datei bei fund nur 1 bei gefunden oder -1 beim nicht gefunden schreibt (standart halt)

**Raupi**

Schau dir mal die Funktion von BugFix an: Rekursive Dateisuche per Objekt
Oder: Dateisuche in Ordner und allen Unterordnern - eine weitere Variante

EpicWorld

Sucht aber auch nur nach exakt angegebenen datein z.b. autoit.ex nicht nach schlüsselwörtern gibts da nicht sowas wo nach schlüsselwörtern suchen kann.
Z.b. man gibt autoit ein und alles was autoit im wort hat wird gefunden

**Oscar**

Mit meiner Funktion kannst Du ein RegExp-Pattern benutzen:

Spoiler anzeigen

[autoit]

;===============================================================================
; Function Name: _RecursiveFileListToArray($sPath[, $sPattern][, $iFlag][, $iFormat][, $iRecursion][, $sDelim])
; Description:: gibt Verzeichnisse (rekursiv) und/oder Dateien zurück, die einem RegExp-Pattern entsprechen
; Parameter(s): $sPath = Startverzeichnis
; $sPattern = ein beliebiges RexExp-Pattern für die Auswahl
; $iFlag = Auswahl
; 0 = Dateien & Verzeichnisse
; 1 = nur Dateien
; 2 = nur Verzeichnisse
; $iFormat = Rückgabeformat
; 0 = String
; 1 = Array mit [0] = Anzahl
; 2 = Nullbasiertes Array
; $iRecursion = Verzeichnisse rekursiv durchsuchen
; 0 = Nein
; 1 = Ja
; $sDelim = Trennzeichen für die String-Rückgabe
; Requirement(s): AutoIt 3.3.0.0
; Return Value(s): Array/String mit den gefundenen Dateien/Verzeichnissen
; Author(s): Oscar (http://www.autoit.de)
; Anregungen von: bernd670 (http://www.autoit.de)
;===============================================================================
Func _RecursiveFileListToArray($sPath, $sPattern = '', $iFlag = 0, $iFormat = 1, $iRecursion = 1, $sDelim = @CRLF)
Local $hSearch, $sFile, $sReturn = ''
If StringRight($sPath, 1) <> '\' Then $sPath &= '\'
$hSearch = FileFindFirstFile($sPath & '*.*')
If @error Or $hSearch = -1 Then Return SetError(1, 0, $sReturn)
While True
$sFile = FileFindNextFile($hSearch)
If @error Then ExitLoop
If @extended Then
If StringRegExp($sPath & $sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 2) Then $sReturn &= $sPath & $sFile & '\' & $sDelim
If $iRecursion Then $sReturn &= _RecursiveFileListToArray($sPath & $sFile & '\', $sPattern, $iFlag, 0)
ContinueLoop
EndIf
If StringRegExp($sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 1) Then $sReturn &= $sPath & $sFile & $sDelim
WEnd
FileClose($hSearch)
If $iFormat And $sReturn = '' Then Return StringSplit($sReturn, '', $iFormat)
If $iFormat Then Return StringSplit(StringTrimRight($sReturn, StringLen($sDelim)), $sDelim, $iFormat)
Return $sReturn
EndFunc

[/autoit]

Für das Beispiel mit "autoit" erfolgt der Aufruf dann so:

[autoit]

$array = _RecursiveFileListToArray('c:\', '.*autoit.*', 1)

[/autoit]

findet alle Dateien auf "c:" (inkl. aller Unterverzeichnisse), die "autoit" im Dateinamen aufweisen.

EpicWorld

Wo muss ich dann

[autoit]

$array = _RecursiveFileListToArray('c:\', '.*autoit.*', 1)

[/autoit]

in dein script einfügen?

**Oscar**

Du weißt nicht, wie man eine Funktion aufruft?

So:

Spoiler anzeigen

[autoit]

#include <Array.au3>
$array = _RecursiveFileListToArray('c:\', '.*autoit.*', 1)
_ArrayDisplay($array)

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

;===============================================================================
; Function Name: _RecursiveFileListToArray($sPath[, $sPattern][, $iFlag][, $iFormat][, $iRecursion][, $sDelim])
; Description:: gibt Verzeichnisse (rekursiv) und/oder Dateien zurück, die einem RegExp-Pattern entsprechen
; Parameter(s): $sPath = Startverzeichnis
; $sPattern = ein beliebiges RexExp-Pattern für die Auswahl
; $iFlag = Auswahl
; 0 = Dateien & Verzeichnisse
; 1 = nur Dateien
; 2 = nur Verzeichnisse
; $iFormat = Rückgabeformat
; 0 = String
; 1 = Array mit [0] = Anzahl
; 2 = Nullbasiertes Array
; $iRecursion = Verzeichnisse rekursiv durchsuchen
; 0 = Nein
; 1 = Ja
; $sDelim = Trennzeichen für die String-Rückgabe
; Requirement(s): AutoIt 3.3.0.0
; Return Value(s): Array/String mit den gefundenen Dateien/Verzeichnissen
; Author(s): Oscar (http://www.autoit.de)
; Anregungen von: bernd670 (http://www.autoit.de)
;===============================================================================
Func _RecursiveFileListToArray($sPath, $sPattern = '', $iFlag = 0, $iFormat = 1, $iRecursion = 1, $sDelim = @CRLF)
Local $hSearch, $sFile, $sReturn = ''
If StringRight($sPath, 1) <> '\' Then $sPath &= '\'
$hSearch = FileFindFirstFile($sPath & '*.*')
If @error Or $hSearch = -1 Then Return SetError(1, 0, $sReturn)
While True
$sFile = FileFindNextFile($hSearch)
If @error Then ExitLoop
If @extended Then
If StringRegExp($sPath & $sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 2) Then $sReturn &= $sPath & $sFile & '\' & $sDelim
If $iRecursion Then $sReturn &= _RecursiveFileListToArray($sPath & $sFile & '\', $sPattern, $iFlag, 0)
ContinueLoop
EndIf
If StringRegExp($sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 1) Then $sReturn &= $sPath & $sFile & $sDelim
WEnd
FileClose($hSearch)
If $iFormat And $sReturn = '' Then Return StringSplit($sReturn, '', $iFormat)
If $iFormat Then Return StringSplit(StringTrimRight($sReturn, StringLen($sDelim)), $sDelim, $iFormat)
Return $sReturn
EndFunc

[/autoit]

EpicWorld

Sry hab mich gerade oben verlesen =X

EpicWorld

Und wenn ich jetzt mehrere habe, wie kann ich das machen das alle funde in eine textdatei mit FileWrite geschrieben wird

**Oscar**

So:

Spoiler anzeigen

[autoit]

#include <Array.au3>
$array = _RecursiveFileListToArray('c:\', '.*autoit.*', 1)
If IsArray($array) Then
$hFile = FileOpen(@ScriptDir & '\Ergebnis.txt', 2)
If $hFile <> -1 Then
For $i = 1 To $array[0]
FileWriteLine($hFile, $array[$i])
Next
FileClose($hFile)
EndIf
EndIf

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

;===============================================================================
; Function Name: _RecursiveFileListToArray($sPath[, $sPattern][, $iFlag][, $iFormat][, $iRecursion][, $sDelim])
; Description:: gibt Verzeichnisse (rekursiv) und/oder Dateien zurück, die einem RegExp-Pattern entsprechen
; Parameter(s): $sPath = Startverzeichnis
; $sPattern = ein beliebiges RexExp-Pattern für die Auswahl
; $iFlag = Auswahl
; 0 = Dateien & Verzeichnisse
; 1 = nur Dateien
; 2 = nur Verzeichnisse
; $iFormat = Rückgabeformat
; 0 = String
; 1 = Array mit [0] = Anzahl
; 2 = Nullbasiertes Array
; $iRecursion = Verzeichnisse rekursiv durchsuchen
; 0 = Nein
; 1 = Ja
; $sDelim = Trennzeichen für die String-Rückgabe
; Requirement(s): AutoIt 3.3.0.0
; Return Value(s): Array/String mit den gefundenen Dateien/Verzeichnissen
; Author(s): Oscar (http://www.autoit.de)
; Anregungen von: bernd670 (http://www.autoit.de)
;===============================================================================
Func _RecursiveFileListToArray($sPath, $sPattern = '', $iFlag = 0, $iFormat = 1, $iRecursion = 1, $sDelim = @CRLF)
Local $hSearch, $sFile, $sReturn = ''
If StringRight($sPath, 1) <> '\' Then $sPath &= '\'
$hSearch = FileFindFirstFile($sPath & '*.*')
If @error Or $hSearch = -1 Then Return SetError(1, 0, $sReturn)
While True
$sFile = FileFindNextFile($hSearch)
If @error Then ExitLoop
If @extended Then
If StringRegExp($sPath & $sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 2) Then $sReturn &= $sPath & $sFile & '\' & $sDelim
If $iRecursion Then $sReturn &= _RecursiveFileListToArray($sPath & $sFile & '\', $sPattern, $iFlag, 0)
ContinueLoop
EndIf
If StringRegExp($sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 1) Then $sReturn &= $sPath & $sFile & $sDelim
WEnd
FileClose($hSearch)
If $iFormat And $sReturn = '' Then Return StringSplit($sReturn, '', $iFormat)
If $iFormat Then Return StringSplit(StringTrimRight($sReturn, StringLen($sDelim)), $sDelim, $iFormat)
Return $sReturn
EndFunc

[/autoit]

EpicWorld

Und mehrere? mit array kenn ich mich ned so aus were nett wenn du mir ein tutorial davon gibst =)

**Oscar**

Wie "mehrere"?
Vielleicht versuchst Du mal das Problem genauer zu beschreiben. Mehr gibt meine Kristallkugel nicht her.

EpicWorld

mehrere suchbegriffe wie

$array = _RecursiveFileListToArray('c:\', '.*autoit.*', 1)

$array = _RecursiveFileListToArray('c:\', '.*script.*', 1)

das es nach mehreren suchbegriffen sucht und in der txt datei speichert.

Und ein tutorial wo array erklärt wird Danke =)

**Oscar**

Da meine Funktion ein RegExp-Pattern abfragt, kann man auch mehrere Begriffe kombinieren.
Dazu musst Du Dich mit den regulären Ausdrücken beschäftigen (Tut von SEuBo). Ein Tut zu Arrays gibt es von BugFix. Jeweils mal die Suche benutzen.

EpicWorld

50 seite fund bei array tut
und kannst du das kurz schreiben wir ich mehre suche und in das textdokument schreiben tu
Vielen dank und sorry für den aufwand =/

**Oscar**

Naja, ein bißchen mehr Eigeninitiative darfst Du schon zeigen.
Aber ich will mal nicht so sein (listet alle Dateien mit "autoit", "script" oder "help" auf):

Spoiler anzeigen

[autoit]

#include <Array.au3>
$array = _RecursiveFileListToArray('f:\autoit\', '.*(autoit|script|help).*', 1)
If IsArray($array) Then
$hFile = FileOpen(@ScriptDir & '\Ergebnis.txt', 2)
If $hFile <> -1 Then
For $i = 1 To $array[0]
FileWriteLine($hFile, $array[$i])
Next
FileClose($hFile)
EndIf
EndIf

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

;===============================================================================
; Function Name: _RecursiveFileListToArray($sPath[, $sPattern][, $iFlag][, $iFormat][, $iRecursion][, $sDelim])
; Description:: gibt Verzeichnisse (rekursiv) und/oder Dateien zurück, die einem RegExp-Pattern entsprechen
; Parameter(s): $sPath = Startverzeichnis
; $sPattern = ein beliebiges RexExp-Pattern für die Auswahl
; $iFlag = Auswahl
; 0 = Dateien & Verzeichnisse
; 1 = nur Dateien
; 2 = nur Verzeichnisse
; $iFormat = Rückgabeformat
; 0 = String
; 1 = Array mit [0] = Anzahl
; 2 = Nullbasiertes Array
; $iRecursion = Verzeichnisse rekursiv durchsuchen
; 0 = Nein
; 1 = Ja
; $sDelim = Trennzeichen für die String-Rückgabe
; Requirement(s): AutoIt 3.3.0.0
; Return Value(s): Array/String mit den gefundenen Dateien/Verzeichnissen
; Author(s): Oscar (http://www.autoit.de)
; Anregungen von: bernd670 (http://www.autoit.de)
;===============================================================================
Func _RecursiveFileListToArray($sPath, $sPattern = '', $iFlag = 0, $iFormat = 1, $iRecursion = 1, $sDelim = @CRLF)
Local $hSearch, $sFile, $sReturn = ''
If StringRight($sPath, 1) <> '\' Then $sPath &= '\'
$hSearch = FileFindFirstFile($sPath & '*.*')
If @error Or $hSearch = -1 Then Return SetError(1, 0, $sReturn)
While True
$sFile = FileFindNextFile($hSearch)
If @error Then ExitLoop
If @extended Then
If StringRegExp($sPath & $sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 2) Then $sReturn &= $sPath & $sFile & '\' & $sDelim
If $iRecursion Then $sReturn &= _RecursiveFileListToArray($sPath & $sFile & '\', $sPattern, $iFlag, 0)
ContinueLoop
EndIf
If StringRegExp($sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 1) Then $sReturn &= $sPath & $sFile & $sDelim
WEnd
FileClose($hSearch)
If $iFormat And $sReturn = '' Then Return StringSplit($sReturn, '', $iFormat)
If $iFormat Then Return StringSplit(StringTrimRight($sReturn, StringLen($sDelim)), $sDelim, $iFormat)
Return $sReturn
EndFunc

[/autoit]

EpicWorld

vielen dank ich such soweil ein array tut xD

PenGuin

Schau einfach in BugFix Signatur.