Problem SendEmail( )

**BugFix**

Hi,
Da ich für meinen GMX-Account _INetSmtpMailCom( ) nicht verwenden kann, habe ich mal SendEmail( ) probiert.

Spoiler anzeigen

[autoit]

Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
Func SendEmail($e_Sender, $e_Recipient, $e_Subject, $e_Text,$e_File)
$objMessage = ObjCreate ("CDO.Message")
With $objMessage
.Subject = $e_Subject
.Sender = $e_Sender
.From = $e_Sender
.To = $e_Recipient
.TextBody = $e_Text
;.HtmlBody = $e_Text ; uncomment to send a HTML mail and comment line above
;~ .AddAttachment = $e_File
EndWith
With $objMessage.Configuration.Fields
.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "mail.gmx.net";$smtpserver
.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = "max.mustermann@gmx.de";$smtpuser
.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "XXX";$smtppass
.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
.Item ("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
.Update
EndWith
$objMessage.Send
Return
EndFunc
Func MyErrFunc()
$HexNumber=hex($oMyError.number,8) ; for displaying purposes
Msgbox(0,"AutoItCOM Test","We intercepted a COM Error !" & @CRLF & @CRLF & _
"err.description is: " & @TAB & $oMyError.description & @CRLF & _
"err.number is: " & @TAB & $HexNumber & @CRLF & _
"err.scriptline is: " & @TAB & $oMyError.scriptline & @CRLF _
)
SetError(1) ; to check for after this function returns
Endfunc

[/autoit]

Dabei taucht aber ein seltsames Phänomen auf:

Übergebe ich die Daten für die eMail im Klartext

[autoit]

SendEmail("max.mustermann@gmx.de", "empfaenger@web.de", "Betreff = TEST", "Body = Das ist ein Test")

[/autoit]

dann funktioniert das tadellos.
Rufe ich die Funktion aber mit Variablen, die ich mit Daten aus einer INI befüllt habe auf:

[autoit]

SendEmail($arIniRead[1][1], $arIniRead[2][1], $Betr, $Text)

[/autoit]

erhalte ich: "==> The requested action with this object has failed.:
$objMessage.Send
$objMessage.Send^ ERROR"
Wenn ich den Fehler auswerte: "...Server hat die Absender adresse zurückgewiesen ...unknown user"
Und die Daten in der INI sind identisch mit denen, die ich im ersten Bsp. von Hand eintrage. :irre:

Hat jemand 'ne Idee?

*Die Funktion verwendet im Original noch "Attachment". Das hab ich aber auskommentiert, da ich es nicht brauche. Deshalb Aufruf nur mit 4 Argumenten.

JanSchmidt

Moin,

blöde Frage, aber haast du dir die Variabeln mal in ner MsgBox anzeigen lassen?

**BugFix**

Habe ich, alles paletti. Habe auch zusätzlich mit "IsString( )" geprüft. Alles OK.
Ist mir absolut unverständlich.

**Xenobiologist**

Hi,

hast du mal die Funktion probiert?

Spoiler anzeigen

[autoit]

#include <INet.au3>

$s_SmtpServer = "mail.gmx.net"
$s_FromName = "Mega"
$s_FromAddress = "XXX"
$s_ToAddress = "XXX"
$s_Subject = "My Test UDF"
$s_UName = "XXX"
$s_PWD = "XXX"
Dim $as_Body[2]
$as_Body[0] = "Testing the new email udf"
$as_Body[1] = "Second Line"
$Response = _INetSmtpMailAuth ($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_UName, $s_PWD, $s_Subject, $as_Body)
;~ $Response = _INetSmtpMail ($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject, $as_Body)
$err = @error
If $Response = 1 Then
MsgBox(0, "Success!", "Mail sent")
Else
MsgBox(0, "Error!", "Mail failed with error code " & $err)
EndIf

;===============================================================================
;
; Function Name: _INetSmtpMailAuth()
; Description: Sends an email using SMTP over TCP IP.
; Parameter(s): $s_SmtpServer - SMTP server to be used for sending email
; $s_FromName - Name of sender
; $s_FromAddress - eMail address of sender
; $s_ToAddress - Address that email is to be sent to
; $s_Username - Username for Authentication (bernd670)
; $s_Passwd - Password for Authentication (bernd670)
; $s_Subject - Subject of eMail
; $as_Body - Single dimension array containing the body of eMail as strings
; $s_helo - Helo identifier (default @COMPUTERNAME) sometime needed by smtp server
; $s_first - send before Helo identifier (default @CRLF) sometime needed by smtp server
; $b_trace - trace on a splash window (default 0 = no trace)
; Requirement(s): None
; Return Value(s): On Success - Returns 1
; On Failure - 0 and sets
; @ERROR = 1 - Invalid Parameters
; @ERROR = 2 - Unable to start TCP
; @ERROR = 3 - Unable to resolve IP
; @ERROR = 4 - Unable to create socket
; @ERROR = 5x - Cannot open SMTP session
; @ERROR = 50x - Cannot send body
; @ERROR = 5000 - Cannot close SMTP session
; Authors: Original function to send email via TCP - Asimzameer
; Conversion to UDF - Walkabout
; Correction Helo, timeout, trace - Jpm
; Correction send before Helo - Jpm
; Include Authentication - bernd670
;
;===============================================================================
Func _INetSmtpMailAuth($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Username, $s_Passwd, $s_Subject = "", $as_Body = "", $s_helo = "", $s_first="-1", $b_trace = 0)

Local $v_Socket
Local $s_IPAddress
Local $i_Count
Local $s_Send[9]
Local $s_ReplyCode[9];Return code from SMTP server indicating success

If $s_SmtpServer = "" Or $s_FromAddress = "" Or $s_ToAddress = "" Or $s_Username = "" Or $s_Passwd = "" Or $s_FromName = "" Or StringLen($s_FromName) > 256 Then
SetError(1)
Return 0
EndIf
If $s_helo = "" Then $s_helo = @ComputerName
If TCPStartup() = 0 Then
SetError(2)
Return 0
EndIf
StringRegExp($s_SmtpServer, "(25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\.(25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\.(25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\.(25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)")
If @extended Then
$s_IPAddress = $s_SmtpServer
Else
$s_IPAddress = TCPNameToIP($s_SmtpServer)
EndIf
If $s_IPAddress = "" Then
TCPShutdown()
SetError(3)
Return 0
EndIf
$v_Socket = TCPConnect($s_IPAddress, 25)
If $v_Socket = -1 Then
TCPShutdown()
SetError(4)
Return (0)
EndIf

$s_Send[0] = "EHLO " & $s_helo & @CRLF
;~ If StringLeft($s_helo,5) <> "EHLO " Then $s_Send[0] = "EHLO " & $s_helo & @CRLF
$s_ReplyCode[0] = "250"

$s_Send[1] = "AUTH LOGIN" & @CRLF
$s_ReplyCode[1] = "334"
$s_Send[2] = _Base64Encoding($s_Username) & @CRLF
$s_ReplyCode[2] = "334"
$s_Send[3] = _Base64Encoding($s_Passwd) & @CRLF
$s_ReplyCode[3] = "235"
$s_Send[4] = "MAIL FROM: <" & $s_FromAddress & ">" & @CRLF
$s_ReplyCode[4] = "250"
$s_Send[5] = "RCPT TO: <" & $s_ToAddress & ">" & @CRLF
$s_ReplyCode[5] = "250"
$s_Send[6] = "DATA" & @CRLF
$s_ReplyCode[6] = "354"

$s_Send[7] = "From: " & $s_FromName & " <" & $s_FromAddress & ">" & @CRLF & _
"To: " & "<" & $s_ToAddress & ">" & @CRLF & _
"Subject: " & $s_Subject & @CRLF & _
"Mime-Version: 1.0" & @CRLF & _
"Content-Type: text/plain; charset=US-ASCII" & @CRLF & _
@CRLF
$s_ReplyCode[7] = ""

$s_Send[8] = @CRLF & "." & @CRLF
$s_ReplyCode[8] = "250"

; open stmp session
If _SmtpSend($v_Socket, $s_Send[0], $s_ReplyCode[0], $b_trace, "220", $s_first) Then
SetError(50)
Return 0
EndIf

; send header
For $i_Count = 0 To UBound($s_Send) - 2
If _SmtpSend($v_Socket, $s_Send[$i_Count], $s_ReplyCode[$i_Count], $b_trace) Then
SetError(50 + $i_Count)
Return 0
EndIf
Next

; send body records (a record can be multiline : take care of a subline beginning with a dot should be ..)
For $i_Count = 0 To UBound($as_Body) - 1
; correct line beginning with a dot
If StringLeft($as_Body[$i_Count], 1) = "." Then $as_Body[$i_Count] = "." & $as_Body[$i_Count]

If _SmtpSend($v_Socket, $as_Body[$i_Count] & @CRLF, "", $b_trace) Then
SetError(500 + $i_Count)
Return 0
EndIf
Next

; close the smtp session
$i_Count = UBound($s_Send) - 1
If _SmtpSend($v_Socket, $s_Send[$i_Count], $s_ReplyCode[$i_Count], $b_trace) Then
SetError(5000)
Return 0
EndIf

TCPCloseSocket($v_Socket)
TCPShutdown()
Return 1
EndFunc ;==>_INetSmtpMailAuth

;===============================================================================
;
; Function Name: _Base64Encoding()
; Description: Kodiert eine Zeichenfolge mit dem Base64-Verfahren
; (http://de.wikipedia.org/wiki/Base64)
; Parameter(s): $String - Zeichenfolge die kodiert werden soll
; Requirement(s): None
; Return Value(s): Kodierte Zeichenfolge
; Authors: bernd670
;
;===============================================================================
Func _Base64Encoding ($String)

$strUmsetzung = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/"
$strRetValue = ""

For $i = 1 To StringLen($String) Step 3
$strTok = StringMid($String,$i,3)
Switch StringLen($strTok)
Case 3
$iTokVal = (Asc(StringMid($strTok,1,1)) * 256 + _
Asc(StringMid($strTok,2,1))) * 256 + _
Asc(StringMid($strTok,3,1))
$strTokCryt = StringMid($strUmsetzung,(BitAND($iTokVal,63)) + 1,1)
$iTokVal = BitShift($iTokVal,6)
$strTokCryt = StringMid($strUmsetzung,(BitAND($iTokVal,63)) + 1,1) & $strTokCryt
$iTokVal = BitShift($iTokVal,6)
$strTokCryt = StringMid($strUmsetzung,(BitAND($iTokVal,63)) + 1,1) & $strTokCryt
$iTokVal = BitShift($iTokVal,6)
$strTokCryt = StringMid($strUmsetzung,(BitAND($iTokVal,63)) + 1,1) & $strTokCryt
$strRetValue &= $strTokCryt

Case 2
$iTokVal = (Asc(StringMid($strTok,1,1)) * 256 + _
Asc(StringMid($strTok,2,1))) * 256
$iTokVal = BitShift($iTokVal,6)
$strTokCryt = StringMid($strUmsetzung,(BitAND($iTokVal,63)) + 1,1)
$iTokVal = BitShift($iTokVal,6)
$strTokCryt = StringMid($strUmsetzung,(BitAND($iTokVal,63)) + 1,1) & $strTokCryt
$iTokVal = BitShift($iTokVal,6)
$strTokCryt = StringMid($strUmsetzung,(BitAND($iTokVal,63)) + 1,1) & $strTokCryt
$strRetValue &= $strTokCryt & "="

Case 1
$iTokVal = Asc(StringMid($strTok,1,1)) * 65536
$iTokVal = BitShift($iTokVal,12)
$strTokCryt = StringMid($strUmsetzung,(BitAND($iTokVal,63)) + 1,1)
$iTokVal = BitShift($iTokVal,6)
$strTokCryt = StringMid($strUmsetzung,(BitAND($iTokVal,63)) + 1,1) & $strTokCryt
$strRetValue &= $strTokCryt & "=="

EndSwitch
Next

Return $strRetValue
EndFunc

[/autoit]

So long,

Mega

**BugFix**

Zitat

hast du mal die Funktion probiert?

Noch nicht, aber gleich

Edit

Dasselbe Problem. Von Hand eingetragen - super. Aus INI eingelesen - fail.

Hier mal die INI:

Code

[mail]
SMTPserver=mail.gmx.net
fromName=Max Mustermann
fromAdress=max.mustermann@gmx.net
toAdress=bugfix@autoit.de
Betreff=autom.: Wochenplan & KW
UserName=xxxxxxx
UserPasswort=xxxxxxxx

So lese ich aus:

[autoit]

$arIniRead = IniReadSection($iniPath, "mail")
$server = $arIniRead[1][1]
$fromName = $arIniRead[2][1]
$from = $arIniRead[3][1]
$to = $arIniRead[4][1]
$betr = $arIniRead[5][1]
$Uname = $arIniRead[6][1]
$Upass = $arIniRead[7][1]

[/autoit][autoit][/autoit][autoit]

; Aufruf
$Response = _INetSmtpMailAuth ($server, $fromName, $from, $to, $Uname, $Upass, $betr, $arbody)

[/autoit]

**Xenobiologist**

Hi,

funktioniert einwandfrei:

Spoiler anzeigen

[autoit]

#include <INet.au3>
#cs
$s_SmtpServer = "mail.gmx.net"
$s_FromName = "Mega"
$s_FromAddress = "vibroei@gmx.de"
$s_ToAddress = "XXX"
$s_Subject = "My Test UDF"
$s_UName = "vibroei@gmx.de"
$s_PWD = "XXX"
#ce
$arIniRead = IniReadSection(@ScriptDir & '\mails.ini', "mail")
$s_SmtpServer = $arIniRead[1][1]
$s_FromName = $arIniRead[2][1]
$s_FromAddress = $arIniRead[3][1]
$s_ToAddress= $arIniRead[4][1]
$s_Subject = $arIniRead[5][1]
$s_UName = $arIniRead[6][1]
$s_PWD = $arIniRead[7][1]