Auflistung von Excel-Makros

Mike32

Bei der Excel.au3 gibt es ja die Funktion _ExcelSheetList($oExcel)

Ich suche nun eine Funktion, wir man bei einer geöffneten Excel.Datei, die z.B. in Modul 1 bestehenden Makros/Prozeduren auflisten kann. Hintergund ist der, dass der Anwender per Listbox ein entsprechendes Makros sich aussuchen soll, dass dann per Autoit gestartet wird.

Unter Excel gibt es den Befehl:
ThisWorkbook.VBProject.VBComponents("Modul1").CodeModule

Aber leider funktioniert eine entsprechende Anpassung der obigen Excel-Funktion von Autoit3 nicht.

Wie kann man bestehende Makros abfragen?

Grüße

Mike32

m-obi

Schonmal so versucht?

[autoit]

$oBook.VBProject.VBComponents("Modul1").CodeModule

[/autoit]

Mike32

Ja, habe ich. Klappt leider nicht.

[autoit]

$ExcelVar = ObjGet("Excel.Application")
$ExcelVar = _ExcelBookOpen("C:\Test.xls", 1)
$temp=$ExcelVar.VBE.ActiveVBProject.Name
$temp=$ExcelVar.VBProject.VBComponents("Modul1").VBModul.CodeModul
$temp=$ExcelVar.VBE.ActiveVBProject.VBComponents.VBModul.CodeModul

[/autoit][autoit][/autoit][autoit][/autoit]

Die erste Zeile "$temp=$ExcelVar.VBE.ActiveVBProject.Name" funktioniert einwandfrei. Die beiden anderen Zeilen sowie div. Versionen davon leider nicht.
Leider komme ich mit der Zeile, die funktioniert, nicht weiter, da sie mir nur den VBProjectnamen verrät, aber nicht die Module bzw. Prozeduren darin.

Grüße

Mike32

m-obi

Und so?

[autoit]

$ExcelVar = _ExcelBookOpen("C:\Test.xls", 1)
$Makros = $ExcelVar.VBE.ActiveVBProject.VBComponents.Item("Modul1").CodeModule
For $Makro In $Makros
MsgBox(0, "", $Makro)
Next

[/autoit]

Ich weiß jetzt nicht wie er die Makros zurückgibt.

Mike32

Vielen Dank,

funktioniert leider auch nicht.
Er bleibt wieder andiesem Befehl hängen und bricht ab.
Irgendwie kann Autoit nicht auf das Modul bzw. auf die Prozeduren zugreifen. Funktioniert bei dir der Befehl (bei einer Exceltestdatei)?

Grüße

Mike32

**BugFix**

Es ist etwas aufwändiger.
Ich habe mal das Excel-Object-Model auf MSDN durchforstet und bin zu dieser Lösung gekommen:

[autoit]

Const $vbext_ct_ClassModule = 2
Const $vbext_ct_Document = 100
Const $vbext_ct_StdModule = 1
Const $vbext_pk_Proc = 0

[/autoit][autoit][/autoit][autoit]

Local $sPath = 'Deine_Excel.xls'
Local $oExcel, $oBook, $oProj, $oComp, $Makro, $aMakro[1] = ['']

[/autoit][autoit][/autoit][autoit]

$oExcel = ObjCreate('Excel.Application')
$oExcel.Visible = 1
$oBook = $oExcel.Workbooks.Open($sPath)
$oProj = $oBook.VBProject
$oComp = $oProj.VBComponents

[/autoit][autoit][/autoit][autoit]

For $Komponente In $oComp
If $Komponente.Type = $vbext_ct_ClassModule Or $Komponente.Type = $vbext_ct_Document Or _
$Komponente.Type = $vbext_ct_StdModule Then
With $Komponente.CodeModule
For $i = 1 To .CountOfLines
If .ProcOfLine($i, $vbext_pk_Proc) > "" Then
$Makro = .ProcOfLine($i, $vbext_pk_Proc)
If $Makro <> $aMakro[UBound($aMakro)-1] Then
If $aMakro[UBound($aMakro)-1] <> '' Then ReDim $aMakro[UBound($aMakro)+1]
$aMakro[UBound($aMakro)-1] = $Makro
EndIf
EndIf
Next
EndWith
EndIf
Next
For $i = 0 To UBound($aMakro)-1
ConsoleWrite($aMakro[$i] & @CRLF)
Next

[/autoit]

Edit: Kannst die Makros ja z.B. in einer ComboBox anzeigen und das vom User gewählte Makro so starten:

[autoit]

$oExcel.Application.Run('Makro_Name')

[/autoit]

Mike32

BugFix

Vielen Dank für deine umfangreiche Antwort.

Bei "$oComp = $oProj.VBComponents" will Auoit nicht mehr. Könnte es sein, dass hier noch irgendein Parameter fehlt oder funktioniert bei dir ggf. der Code?

Grüße

Mike32

**BugFix**

Funktioniert bei mir tadellos. Laut MSDN dürfte die Excel-Version keine Rolle spielen. OS ist bei mir XPHome SP3.

Mike32

Hei BugFix,

so ich habe mal das Problem eingegrenzt. Bei Excel 2007 (Tabelle .xlsm) läuft es tadellos.

Die gleiche Datei als Excel 97-2003 (.xls) abgespeichert und ich habe das beschriebene Problem. Kann es sein, dass die VBA-Struktur dann anders ist? - Und wenn ja, wie?

Grüße

Mike32

**BugFix**

Zitat von Mike32

Die gleiche Datei als Excel 97-2003 (.xls) abgespeichert und ich habe das beschriebene Problem. Kann es sein, dass die VBA-Struktur dann anders ist? - Und wenn ja, wie?

Das übersteigt mein Wissen in dem Bereich.
Aber falls es dir reicht, den normalen Makro-Dialog anzuzeigen - das geht so:

[autoit]

Const $xlDialogRun = 17
Local $oExcel, $sPath = 'Deine_Excel.xls'

[/autoit][autoit][/autoit][autoit]

$oExcel = ObjCreate('Excel.Application')
$oExcel.Visible = 1
$oExcel.Workbooks.Open($sPath)
$oExcel.Application.Dialogs($xlDialogRun).Show

[/autoit]

Mike32

@ BugFix

Super, dass du immer so prompt eine Antwort hast. Ich bin der Sache mal weitergegenagen und habe festgestellt, dass mir ein Fehler unterlaufen ist. Dein Code funktioniert bei allen Excel-Versionen. Ich habe nur vergessen beim VBProjekt das Passwort rauszunehmen.
So konnte Autoit bei deinem Code gar nicht darauf zugreifen. - Sorry!!!!

Könntest du mir noch netterweise kurz mitteilen, wie ich per Autoit beim Projekt das Passwort eingebe bzw. den Schutz temporär aufhebe und nachher wieder einschalte?

Vielen Dank!

Grüße

Mike32

**BugFix**

Zitat von Mike32

Könntest du mir noch netterweise kurz mitteilen, wie ich per Autoit beim Projekt das Passwort eingebe bzw. den Schutz temporär aufhebe und nachher wieder einschalte?

Also für das Workbook geht das (wenn ich mich recht erinnere) mit:

[autoit]

$oExcel.Workbooks.Open($sPath)
$oExcel.Workbooks.Unprotect('Passwort')

[/autoit]

Aber wenn das Project PW-geschützt ist.. ich glaube, die Protection.Property ist ReadOnly.
Mal suchen, ob es da eine Lösungsmöglichkeit gibt.

Mike32

BugFix

Danke, wäre echt toll von dir!

Grüße

Mike32

**BugFix**

Also, Protection.Property ist ReadOnly!
Es gibt wohl keinen direkten Weg per Skript das PW zu setzen. Vorstellbar wäre eine Variante mit Send/Controlsend/ControlClick. Mußt halt mal probieren, was da geht.

Mike32

@ BugFix

schade.

Kann man irgendwie mit $oExcel.Application.Dialogs($xlDialogRun) die Auflistung auslesen?

Grüße

Mike32

**BugFix**

Leider nicht möglich. Mit Run wird nur der Dialog gestartet. Die Liste des Dialogs ist aber kein Standard-Control und kann nicht per Control-ID oder Class angesprochen werden.

Mike32

@ BUgFix

Schade!

Vielen Dank für deine starke Hilfe!

Grüße

Mike32

Mike32

@ Bugfix,

ich muss leider ein altes Thema/Problem ausgraben.

Ich dachte, dass der Code vom Beitrag Nr. 6 laufen würde. War mein Fehler. - Beim heutigen Testen kam folgende Fehlermeldung in Autoit
: ==> Error in expression.:
If .ProcOfLine($i, $vbext_pk_Proc) > "" Then
If .ProcOfLine($i, $vbext_pk_Proc) ^ ERROR

Ich habe ein einfache Excel-Testdatei mit drei Tabellen und einem VBA-Modul, welches drei kleine Makros enthält. Die Datei wird von Autoit geöffnet und dann kommt die obige Fehlermeldung bei Zeile 20 des Codes.
Woran könnte dies liegen?
Thx

Grüße

Mike

Mike32

So der Fehler wurde vermutlich eingegrenzt.
Es muss noch ein Verweis auf "Visual Basic for Applications Extensibility 5.3" gesetzt werden, damit .ProcofLine funktioniert.
Die COM-Datei heißt: Vbe6ext.olb und ist unter "c:\Programme\Gemeinsame Dateien\Microsoft Shared\VBA\VBA6" zu finden.

Weiß jemand, wie man einen Verweis setzen kann bzw. diese Datei irgendwie einbindet? Bei VB gibt es ja eine Möglichkeit dafür.

Thx

Grüße

Mike

Mike32

Für alle Interessierten hier die (behelfsmäßige) Lösung.

Ohne Verweis bei Autoit (ich habe hierfür keinerlei Möglichkeit gefunden, dass dies irgendwie geht), kommt man nur bis zur "Ebene" VBComponents. D.h. man kann nicht auf ProcofLine zugreifen. Um dies zu umgehen habe ich mit.Export die entsprechenden Module temporär exportiert und dann mit StringinString analysiert, da die .bas-Dateien einfache Textdateien sind. Dies klappt nun hervorragend.
Und hier der Code, der teilweise auf Bugfix's Code basiert (s.o.).

Code

Func VBAMacros_Neu()
	Const $vbext_ct_ClassModule = 2
	Const $vbext_ct_Document = 100
	Const $vbext_ct_StdModule = 1
	Const $vbext_pk_Proc = 0


	Local $oProj, $oComp, $Makro, $aMakro[1] = [''], $oKompName, $oBook
	$oBook = $ExcelVar.ActiveWorkbook
	$oProj = $oBook.VBProject
	$oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
	$oComp = $oProj.VBComponents ; Wenn hier ein Fehler kommt, dann sind die Module passswortgeschützt.
	$oMyError = "" ; On Error-Routine löschen
	$Makro = ""
	For $Komponente In $oComp
		;If $Komponente.Type = $vbext_ct_ClassModule Or $Komponente.Type = $vbext_ct_Document Or $Komponente.Type = $vbext_ct_StdModule Then
		If $Komponente.Type = $vbext_ct_StdModule Then ; Nur VBA-Makros
			$oKompName = $Komponente.Name
			$Komponente.Export(@WorkingDir & "\" & $oKompName & ".bas")
			; Datei öffnen
			$file = FileOpen(@WorkingDir & "\" & $oKompName & ".bas", 0)
			If $file = -1 Then
				MsgBox(262144 + 16, "Fehler", "Die VBA-Makros konnten nicht gelesen werden.")
			Else
				$line = FileRead($file)
			EndIf
			FileClose($file)
			FileDelete(@WorkingDir & "\" & $oKompName & ".bas")
			; Nun Subs auslesen
			While 1
				$result = StringInStr($line, "Sub ")
				$result1 = StringInStr($line, "()")
				If $result > 0 And $result1 > 0 Then
					$Makro = $Makro & "|" & StringMid($line, $result + 4, $result1 - $result - 4)
					$line=StringTrimLeft($line,$result1+1)
				Else
					ExitLoop
				EndIf
			WEnd
		EndIf
	Next
   Return($Makro)
EndFunc   ;==>VBAMacros_Neu


Func MyErrFunc() ; Fehler bei der Makroauflistung abfangen z.B., wenn PW vergeben wurde. ***
	$oMyError = ""
	While MsgBox(262144 + 16, "Achtung!", "Die VBA-Makros sind passwortgeschützt und können nicht aufgerufen werden!" & Chr(13) & "Bitte vorher den VBA-Schutz entfernen!") <> 1
	WEnd
	$temp = "-1"
EndFunc   ;==>MyErrFunc
$Liste=VBAMacros_Neu()
_ExcelBookClose($ExcelVar, 0)


Do
	$PID = ProcessExists("excel.exe")
	If $PID Then ProcessClose($PID)
Until $PID = 0

Alles anzeigen

Grüße

Mike