Mathe: Aus Textaufgabe 2 Gleichungen erstellen und ausrechnen

Erste Gleichung nach y umgestellt:

y = 180/x

Zweite Gleichung nach y umgestellt:

y = 1/2 * (365+x)/(x+5)

Beide Gleichungen gleichsetzen und folgende Umformungen durchführen:

(365+x)/(2x+10) = 180/x      | *x , *(2x+10)


x^2 + 365x = 360x + 1800     | -360x , -1800


x^2 + 5x - 1800 = 0

Quadratische Gleichung wie immer auflösen und man erhält als Ergebnis 40 und -45.
Welches von beiden das logische Ergebnis ist sollte klar sein.

Global Const $FLT_EPSILON = _GET_FLT_EPSILON() ; Rechengenauigkeit

; Definition der Funktionen
Global $sF1 = "180/x"
Global $sF2 = "(365+x)/(2*x+10)"

; Definition des Suchbereiches
Global $iStart = 1 ; x mindestens 1 da mindestens 1 Schüler mitfährt
Global $iEnd = 1000 ; wir gehen mal davon aus dass nicht mehr als 1000 Schüler in einen Bus passen...
Global $iStep = 1.1

#region Suche Bereich auf Schnittpunkte beider Funktionen ab und ermittle die Koordinaten der Schnittpunkte
; Größer/Kleiner Vergleichskriterium
Global $bSw = _Fx($sF1, $iStart) > _Fx($sF2, $iStart)

For $x = $iStart To $iEnd Step $iStep ; Gehe den Bereich grob ab
If $bSw <> (_Fx($sF1, $x) > _Fx($sF2, $x)) Then ; Wenn Wechsel der Größer/Kleiner Beziehung dann muss Schnittpunkt dazwischen liegen
$bSw = Not $bSw
$dX_Schnitt = Schnittsuche($sF1, $sF2, $x - $iStep, $x) ; Starte die feine Schnittpunktsuche im Intervall
$dY_Schnitt = (_Fx($sF1, $dX_Schnitt) + _Fx($sF2, $dX_Schnitt)) / 2 ;Y-Wert als Mittelwert beider Funktionswerte bestimmen
MsgBox(0, "Schnittpunkt der beiden Funktionen gefunden", "x = " & $dX_Schnitt & @CRLF & "y = " & $dY_Schnitt)
EndIf
Next
#endregion

; Berechnet eine Funktion als String formatiert
Func _Fx(Const $sF, Const $dW)
Return Number(Execute(StringReplace($sF, "x", "(" & $dW & ")")))
EndFunc ;==>_Fx

; Bestimmt die Schnittpunkte 2er Funktionen in einem Intervall iterativ mit dem Regula Falsi Algorithmus
; Hinweis: Sollte noch ungültige Ergebnisse liefern wenn einer der Grenzen = dem Schnittpunkt
Func Schnittsuche(Const $sF1, Const $sF2, $dA, $dB, $iMaxIt = 100)
;by AspirinJunkie
Local $xA = $dA, $xB = $dB
Local $Ya, $Yb, $x, $Yx
Local $xOld = $dB

For $n = 1 To $iMaxIt
$Ya = _Fx($sF1, $xA) - _Fx($sF2, $xA) ;Differenz der Funktionen da Regula Falsi nach Nullstellen sucht
$Yb = _Fx($sF1, $xB) - _Fx($sF2, $xB)
$x = $xA - ($Ya * ($xB - $xA)) / ($Yb - $Ya)
$Yx = _Fx($sF1, $x) - _Fx($sF2, $x)

If Abs($x - $xOld) < (4 * $FLT_EPSILON) Or Abs($Yx) < (5 * $FLT_EPSILON) Then ; Wenn Differenz der Durchgänge unter einer gewissen Genauigkeit liegt abbrechen
Return $x
Else ;Festlegung der neuen grenzen für den neuen Durchlauf
$xOld = $x
If $Ya > $Yx Then
$xA = $x
Else
$xB = $x
EndIf
EndIf

Next
Return SetError(1, $iMaxIt, $x)
EndFunc ;==>Schnittsuche

; #FUNCTION#=================================================================================
; Name...........: _GET_FLT_EPSILON
; Description ...: Berechnet den binären Rundungsfehler und damit die Rechengenauigkeit
; Syntax.........: _GET_FLT_EPSILON
; Return values .: Epsilon
; Author ........: AspirinJunkie
;============================================================================================
Func _GET_FLT_EPSILON()
Local $x = 1
Do
$x /= 2
Until 1 + $x <= 1
Return $x
EndFunc ;==>_GET_FLT_EPSILON