OutlookEX UDF - 2019-11-30: Neue Version 1.4.0.0. freigegeben

[autoit]

; #FUNCTION# ====================================================================================================================
; Name...........: _OL_Open
; Description ...: Opens a connection to Microsoft Outlook.
; Syntax.........: _OL_Open([$fOL_WarningClick = False[, $sOL_WarningProgram = ""[, $iOL_WinCheckTime = 1000[, $iOL_CtrlCheckTime = 1000]]])
; Parameters ....: $fOL_WarningClick - Optional: If set to True a function will click away the Outlook security warning messages (default = False)
; $sL_WarningProgram - Optional: Complete path to the WarningProgram, e.g.: "C:\OLext\_OL_Warnings.exe"
; + (default = @ScriptDir & "\_OL_Warnings.exe" which is part of this UDF)
; $iOL_WinCheckTime - Optional: Time in milliseconds to wait before a check for a warning window is performed (default = 1000 milliseconds = 1 second)
; $iOL_CtrlCheckTime - Optional: How long, in milliseconds, we will wait before we check that the controls we click are enabled (default = 1000)
; Return values .: Success - New object identifier
; Failure - Returns 0 and sets @error:
; |1 - Unable to Create Outlook Object. See @extended for details (@error returned by ObjCreate)
; |2 - Unable to create custom error handler. See @extended for details (@error returned by ObjEvent)
; |3 - $fOL_WarningClick is invalid. Has to be True or False
; |4 - $iOL_WinCheckTime is invalid. Has to be an integer
; |5 - File $sOL_WarningProgram does not exist. Has to be an executable that can be startet using the run command
; |6 - Run error when running $sOL_WarningProgram. Please check @extended for more information
; |7 - $iOL_CtrlCheckTime is invalid. Has to be an integer
; |8 - Unable to logon to the default profile. See @extended for details (@error returned by Logon)
; |9 - No profile has been configured or there is no default profile for Outlook
; Author ........: Wooltown
; Modified ......: water
; Remarks .......: Create your own $sOL_WarningProgram Exe if the window title or messages have changed or are displayed in another language
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _OL_Open($fOL_WarningClick = False, $sOL_WarningProgram = "", $iOL_WinCheckTime = 1000, $iOL_CtrlCheckTime = 1000)

[/autoit] [autoit][/autoit] [autoit]

Local Const $msoLanguageIDUI = 0x2 ; See http://msdn.microsoft.com/en-us/library/aa170976.aspx
If Not IsBool($fOL_WarningClick) Then Return SetError(3, 0, 0)
If Not IsInt($iOL_WinCheckTime) Then Return SetError(4, 0, 0)
If Not IsInt($iOL_CtrlCheckTime) Then Return SetError(7, 0, 0)
If ProcessExists("Outlook.exe") > 0 Then $fOL_AlreadyRunning = True
Local $oOL = ObjCreate("Outlook.Application")
If @error <> 0 Or Not IsObj($oOL) Then Return SetError(1, @error, 0)
If $fOL_WarningClick Then
If $sOL_WarningProgram = "" Then $sOL_WarningProgram = @ScriptDir & "\_OL_Warnings.exe"
If Not FileExists($sOL_WarningProgram) Then Return SetError(5, 0, 0)
Run($sOL_WarningProgram & " " & @AutoItPID & " " & $iOL_WinCheckTime & " " & $iOL_CtrlCheckTime & " " & $oOL.Version & " " & $oOL.LanguageSettings.LanguageID($msoLanguageIDUI), "", @SW_HIDE)
If @error <> 0 Then Return SetError(6, @error, 0)
EndIf
; A COM error handler will be initialised only if one does not exist
If ObjEvent("AutoIt.Error") = "" Then
$oOL_Error = ObjEvent("AutoIt.Error", "_OL_COMError") ; Creates a custom COM error handler
If @error <> 0 Then Return SetError(2, @error, 0)
EndIf
Local $aVersion = StringSplit($oOL.Version, '.')
; Logon to the default profile if Outlook wasn't already running (for Outlook 2007 and later)
If $fOL_AlreadyRunning = False And Int($aVersion[1]) >= 12 Then
If $oOL.DefaultProfileName = "" Then Return SetError(9, 0, 0)
Local $oOL_Namespace = $oOL.GetNamespace("MAPI")
$oOL_Namespace.Logon($oOL.DefaultProfileName, "", False, False)
If @error <> 0 Then Return SetError(8, @error, 0)
EndIf
Return $oOL

[/autoit] [autoit][/autoit] [autoit]

EndFunc ;==>_OL_Open

[/autoit]