Hallo Com
Ich hätte da eine Frage und zwar kann ich ein Programm schreiben das Keine GUI sondern eine GDI+ hat also das es dann so ausschaut
[Blockierte Grafik: http://www7.pic-upload.de/10.06.11/ru3x4oa6reaz.jpg]
Ich möchte nur das da kein Rand ist also kein
[Blockierte Grafik: http://www7.pic-upload.de/10.06.11/ughsd2eyl4ez.png]
Dann möchte ich noch ein Button drin haben wie mache ich das dann ?
Danke im voraus.
Guckst du hier:
;coded by UEZ 2011
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
Global Const $STM_SETIMAGE = 0x0172
_GDIPlus_Startup()
Global Const $hImage = _GDIPlus_ImageLoadFromFile(@ScriptDir & "\ru3x4oa6reaz.jpg")
Global Const $hHBITMAP = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
Global Const $iW = _GDIPlus_ImageGetWidth($hImage)
Global Const $iH = _GDIPlus_ImageGetHeight($hImage)
_GDIPlus_ImageDispose($hImage)
Global Const $hGUI = GUICreate("", $iW, $iH, -1 , -1, $WS_POPUP, $WS_EX_LAYERED)
Global Const $cPic = GUICtrlCreatePic("", 0, 0, $iW, $iH)
GUICtrlSetState(-1, $GUI_DISABLE)
Global Const $cButton = GUICtrlCreateButton("Exit", $iW - 40, $iH - 40, 30, 30)
Global Const $cLabel = GUICtrlCreateLabel("", 0, 0, $iW, $iH, -1, $GUI_WS_EX_PARENTDRAG)
GUICtrlSetBkColor(-1, -2)
_WinAPI_DeleteObject(GUICtrlSendMsg($cPic, $STM_SETIMAGE, 0, $hHBITMAP))
_WinAPI_DeleteObject($hHBITMAP)
_GDIPlus_ShutDown()
GUISetState(@SW_SHOW)
While 1
$msg = GUIGetMsg()
If $msg = $GUI_EVENT_CLOSE Or $msg = $cButton Then ExitLoop
WEnd
GUIDelete($hGUI)
Exit
Gruß,
UEZ
Guckst du hier:
DANKE !!! Hat mir suuuuuuuuper geholfen 
