Hallo an Alle,
ich habe eine $List mit GuiCtrlSetData erstellt. Das hat super funtioniert :). Wie bekomme ich nun aber diese Infos wieder aus der List? Den Befehel GuiCtrlGetData gibt es ja nicht. Wie übergebe ich die Daten aus der List zeilenweise an eine Textdatei?
Es wäre toll, wenn Ihr mir helfen könntet.
Vielen Dank und viele Grüße (und allen schon einmal ein schönes Wochenende),
TOYY1
Hallo Toy,
du gehst in einer Schleife einfach alle Einträge (erhälst du mit
[autoit]_GUICtrlListBox_GetCount
[/autoit]durch) und liest Eintrag für Eintrag mit
[autoit]_GUICtrlListBox_GetText
[/autoit]aus. as ganze würde dann so aussehen:
[autoit]#include <GUIConstants.au3>
#Include <GuiListBox.au3>
#include <ListboxConstants.au3>
#include <File.au3>
Global $szDrive,$szDir,$szFName,$szExt, $aListe
[/autoit][autoit][/autoit][autoit]$hGUI = GUICreate("Flaggen", 300, 130)
$hListe = GUICtrlCreateList("", 10, 10, 180, 80,$LBS_NOTIFY)
$hNeu = GUICtrlCreateButton("...",200,10,30,25)
$hVorschau = GUICtrlCreatePic(@ScriptDir & "\Flaggen\NA.jpg", 210, 40, 36, 24)
$hTxtSave = GUICtrlCreateButton("&Speichern",10,100,80)
$hTxLoad = GUICtrlCreateButton("&Laden",210,100,80)
GUISetState()
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
case $hTxLoad
_FileReadToArray(@ScriptDir & "\flaggen.txt",$aListe)
for $i = 1 to $aListe[0]
_GUICtrlListBox_InsertString($hListe,$aListe[$i])
Next
case $hTxtSave
$hFile = FileOpen(@ScriptDir & "\flaggen.txt",2)
for $i = 0 to _GUICtrlListBox_GetCount($hListe) -1
FileWriteLine($hFile,_GUICtrlListBox_GetText($hListe,$i))
Next
FileClose($hFile)
case $hNeu
$sAlt = GUICtrlRead($hListe)
$sPlus = FileOpenDialog("Land auswählen:",@ScriptDir & "\Flaggen","Bilder (*.jpg)",3,"",$hGUI)
_PathSplit($sPlus,$szDrive,$szDir,$szFName,$szExt)
;ConsoleWrite($szFName & @CRLF)
_GUICtrlListBox_InsertString($hListe,$szFName,0)
Case $hListe
GUICtrlSetImage($hVorschau, @ScriptDir & "\Flaggen\" & GUICtrlRead($hListe) & ".jpg")
EndSwitch
WEnd
für obiges Beispiel benötigts du noch
mfg autoBert
Hallo und Guten Morgen. Vielen Dank AutoBert - das hat mir sehr geholfen. Ich hatte unter der Hilfe Get Text bei Suchen eingegeben. Leider findet die Hilfe dazu leider nichts.... 
Viele Grüße,
TOYY1
