Excel - String in allen Zellen ersetzen

CoWa

Hallo,

ich möchte in Excel einen String in allen Zellen durch einen neuen String ersetzen.

Ideen wie ich das machen könnte?
Den weg über Tastencodes senden (Strg+h, Text eingeben, Strg+a, etc) möchte ich nicht gehen.

Ich habe u.a. aus ExcelCom_udf.au3 folgendes versucht:

Code

_ExcelReplaceInRange($oExcel, $Endtext, " ", $sRangeOrRowStart)

Leider wird danach meine Text-Formatierung danach auf Zahl umgestellt, weswegen ich den gleichen Fehler wie hier habe.

Ideen wie ich das machen könnte?

Gruß Cornelius

**water**

Wenn sich die Formatierung ändert, dann liegt das vermutlich daran, dass die Formatierung auf "Standard" steht und der Inhalt nach dem Change nur noch aus Ziffern besteht.
Gib den Replacestring als String an. Also "'3" statt "3"

CoWa

Hey Water,

danke dir.

Habe das Apostroph zwar nur entfernen müssen, aber es funktioniert

Anbei mein Quellcode, vllt hilfts ja anderen.

Spoiler anzeigen

C

#include <Date.au3>
#include <Excel.au3>
#Include <File.au3>


;===============================================================================
;
; Description:  	Finds all instances of a string in a range and replace them with the replace string.
; Syntax:       	_ExcelReplaceInRange($oExcel, $sFindWhat, $sReplaceWith, $sRangeOrRowStart, $iColStart = 1, $iRowEnd = 1, $iColEnd = 1,  _
;										$iWholeOrPart = 2, $fMatchCase = False, $fMatchFormat = False, $fReplaceFormat = False)
; Parameter(s): 	$oExcel - An Excel object opened by a preceding call to _ExcelBookOpen() or _ExcelBookNew()
;					$sFindWhat - The string to search for
;					$sReplaceWith - The string to replace the search string with
;					$sRangeOrRowStart - Either an A1 range, or an integer row number to start from if using R1C1
;					$iColStart - The starting column for the number format(left) (default=1)
;					$iRowEnd - The ending row for the number format (bottom) (default=1)
;					$iColEnd - The ending column for the number format (right) (default=1)
;					$iWholeOrPart - Whole or part of cell must match search string (1=Whole, 2=Part) (default=2)
;					$fMatchCase - Specify whether case should match in search (True or False) (default=False)
;					$fMatchFormat - Specify whether cell formatting should match in search (True or False) (default=False)
;					$fReplaceFormat - Specify whether cell format will be reset (True Or False) (default=False)
; Requirement(s):   AutoIt Beta 3.2.1.12
; Return Value(s):  On Success - Returns 1
;               	On Failure - Returns 0 and sets @error on errors:
;						@error=1 - Specified object does not exist
;						@error=2 - Starting row or column invalid
;							@extended=0 - Starting row invalid
;							@extended=1 - Starting column invalid
;						@error=3 - Ending row or column invalid
;							@extended=0 - Ending row invalid
;							@extended=1 - Ending column invalid
;						@error=4 - Whole or part parameter invalid
; Author(s):    	SEO <locodarwin at yahoo dot com>, many thanks to DaLiMan
; Note(s):      	None
;
;===============================================================================
Func _ExcelReplaceInRange($oExcel, $sFindWhat, $sReplaceWith, $sRangeOrRowStart, $iColStart = 1, $iRowEnd = 1, $iColEnd = 1, $iWholeOrPart = 2, $fMatchCase = True, $fMatchFormat = "", $fReplaceFormat = True)
	If NOT IsObj($oExcel) Then Return SetError(1, 0, 0)
	If $iWholeOrPart < 1 Or $iWholeOrPart > 2 Then Return SetError(4, 0, 0)
	If NOT StringRegExp($sRangeOrRowStart, "[A-Z,a-z]", 0) Then
		If $sRangeOrRowStart < 1 Then Return SetError(2, 0, 0)
		If $iColStart < 1 Then Return SetError(2, 1, 0)
		If $iRowEnd < $sRangeOrRowStart Then Return SetError(3, 0, 0)
		If $iColEnd < $iColStart Then Return SetError(3, 1, 0)
		$oExcel.Range($oExcel.Cells($sRangeOrRowStart, $iColStart), $oExcel.Cells($iRowEnd, $iColEnd)).Select
	Else
		$oExcel.Range($sRangeOrRowStart).Select
	EndIf
	If $fMatchFormat = "" Then
		$oExcel.Selection.Replace($sFindWhat, $sReplaceWith, $iWholeOrPart, Default, $fMatchCase, Default, Default, $fReplaceFormat)
	Else
		$oExcel.Selection.Replace($sFindWhat, $sReplaceWith, $iWholeOrPart, Default, $fMatchCase, Default, $fMatchFormat, $fReplaceFormat)
	EndIf
	Return 1
EndFunc	;==>_ExcelReplaceInRange






Local $sRangeOrRowStart = 1, $iColStart = 1, $iRowEnd = 10, $iColEnd = 10, $sHorizAlign = "left"
Local $aquelle
$iniFile = @ScriptDir & "\barcodes_auslesen.ini"
$quelle = @ScriptDir & "\" & IniRead($inifile,"Konfiguration","quelle", "output.txt")
$_quelle = @ScriptDir & "\" & IniRead($inifile,"Konfiguration","_quelle", "_output.txt")
$ziel = IniRead($inifile,"Konfiguration","ziel", @DesktopDir & "\foobaa\")
$tCur = _Date_Time_GetLocalTime()
$spalte1_ausrichtung = IniRead($inifile,"Konfiguration","spalte1_ausrichtung", "left")
$spalte2_ausrichtung = IniRead($inifile,"Konfiguration","spalte2_ausrichtung", "right")
$aktuelles_datum = stringreplace(StringReplace(StringReplace(_Date_Time_SystemTimeToDateTimeStr($tcur, 1),"/","."), " ", "_"),":",".")
$debug = number(IniRead($inifile,"Konfiguration","debug", "0"))
$excel_oeffen = number(IniRead($inifile,"Konfiguration","excel_oeffen", "1"))
$verschieben = number(IniRead($inifile,"Konfiguration","verschieben", "1"))
$csvdatei = number(IniRead($inifile,"Konfiguration", "csv_datei", "0"))
$Endtext = "!###4log_Endtext###!"


if $debug = 1 Then
	MsgBox(0,@ScriptDir, $ziel & $aktuelles_datum & ".csv")
	if FileExists($iniFile) then MsgBox(0,@ScriptDir, "Inidatei vorhanden: " & $iniFile)
EndIf


if FileExists($quelle) Then


	; Hilfstext $Endtext einfügen - Verhindert Bug das aus Codes wie "0104045119066437375194103058035440" folgender kaputter Code "1,40451E+17" wird.
	_FileReadToArray($quelle, $aquelle)
	For $i = 1 To $aquelle[0]
		$aquelle[$i] = StringReplace($aquelle[$i] & $Endtext,";",";'")
	Next
	_FileWriteFromArray($_quelle, $aquelle, 1)




	if $verschieben = 0 Then
		if FileExists($_quelle) Then
			FileMove($_quelle, $ziel & $aktuelles_datum & ".csv", 8)
		else
			FileCopy($quelle, $ziel & $aktuelles_datum & ".csv", 8)
		EndIf
	elseif $verschieben = 1 Then
		if FileExists($_quelle) Then
			FileMove($_quelle, $ziel & $aktuelles_datum & ".csv", 8)
			FileDelete($quelle)
		else
			FileMove($quelle, $ziel & $aktuelles_datum & ".csv", 8)
		EndIf


	EndIf


	if (FileExists($ziel & $aktuelles_datum & ".csv")) & ($excel_oeffen = 1) Then
		Local $oExcel = _ExcelBookOpen($ziel & $aktuelles_datum & ".csv")


		$oExcel.Columns("A:A" ).ColumnWidth = 20 ; Zeitstempel
		$oExcel.Columns("B:B" ).ColumnWidth = 35 ; Barcode


		_ExcelHorizontalAlignSet($oExcel, "A:A", $iColStart, $iRowEnd, $iColEnd, $spalte1_ausrichtung) ; Zeitstempel
		_ExcelHorizontalAlignSet($oExcel, "B:B", $iColStart, $iRowEnd, $iColEnd, $spalte2_ausrichtung); Barcode


		_ExcelNumberFormat($oExcel, "@", "B:B") ; Zellen als Text formatieren


		;; Endtext wieder entfernen
		_ExcelReplaceInRange($oExcel, $Endtext, "", $sRangeOrRowStart)
		_ExcelReplaceInRange($oExcel, "'", "", $sRangeOrRowStart)








		_ExcelBookSaveAs($oExcel, $ziel & $aktuelles_datum & ".xls", "xls")


		if $debug = 1 Then
			If Not @error Then MsgBox(0, "Success", "File was Saved!", 3)
		EndIf
		if FileExists($iniFile) then MsgBox(0,@ScriptDir, "Inidatei vorhanden: " & $iniFile)
		if (FileExists($ziel & $aktuelles_datum & ".xls") & ($csvdatei = 0)) Then FileDelete($ziel & $aktuelles_datum & ".csv")


	EndIf
EndIf

Alles anzeigen

Quelldatei Output.txt

Spoiler anzeigen

Code

1999-08-03 11:20:32;10813950
1999-08-03 11:20:34;10813950
1999-08-03 11:20:39;0005634663
1999-08-03 11:20:40;001914930285
1999-08-03 11:20:41;001210410207
1999-08-03 11:20:42;Fuga1234log
1999-08-03 11:20:43;8888888888
1999-08-03 11:20:45;BDP1049186
1999-08-03 11:20:46;70000849
1999-08-03 11:20:48;00673724000802
1999-08-03 11:20:49;70000849
1999-08-03 11:20:28;1W113A017413
1999-08-03 11:20:29;1W113A017413
1999-08-03 11:23:27;1W113A017413
1999-08-03 11:23:28;1W113A017413
1999-08-03 11:23:29;1W113A017413
2012-08-29 12:44:24;0104045119066437375194103058035440
2012-08-29 12:44:31;00140451192320177692
2012-08-29 12:44:32;0104045119066437375194103058035440

Alles anzeigen

Gruß Cornelius