OutlookEX Mail Send->Recieve mit Timer

Kasper

Hallo zusammen,

Für Outlook Client Performance Messungen versuche ich in einem Outlook eine Testmail an das Postfach selber zu senden. Dazu soll die Inbox überwacht werden und beim Eintreffen der Testmail einen Timer ausgegeben werden.

Outlook Clients sind über verschiedene WAN Strecken angebunden, und so sollen Sync Zeiten für verschiedene Standorte ermittelt werden.

Routinen wie eine Mail zu versenden oder Mails mit speziellen Subject in der Inbox abzufragen ist recht einfach, ich bekomme aber keine Loop hin die nach dem Senden bis zum Eintreffen der Mail wartet.
Hat hier jemand eine Idee dazu?

Code

#include <OutlookEx.au3>
Local $begin = TimerInit()


$oOL = _OL_Open()
Global $sCurrentUser = $oOL.GetNameSpace("MAPI").CurrentUser.Name


_OL_Wrapper_SendMail($oOL, $sCurrentUser, "", "", "TestA123", "Hallo, dies ist eine Testmail.", "C:\Temp\Anhang.ppt", $olFormatHTML, $olImportanceHigh)


$aItems = _OL_ItemFind($oOl, "*\Inbox", $olMail, "", "Subject", "TestA123", "Subject,Body", "", 1)
If IsArray($aItems) Then
    _ArrayDisplay($aItems, "Outlook Test")
Else
    MsgBox(48, "Outlook Test", "Outbox empy. @error = " & @error & ", @extended: " & @extended)
EndIf


Local $dif = TimerDiff($begin)
MsgBox(0, "Time Difference", $dif)

Alles anzeigen

**water**

Hier würde ich mit Events arbeiten. Funktionen werden aufgerufen, wenn ein bestimmtes Ereignis eintrifft. Dazu gehört der NewMail Event.
Schau Dir mal im engl. Forum das entsprechende Beispiel an.

Kasper

Nunja, das _OL_ExampleNewMail_Event script funktioniert auf wundersame Weise, ich weiss aber nicht wie.
Nach der Initialisierung läuft es in einer endlos While Schleife die nur Sleep beinhaltet.
Die Funktion _oOApp_NewMailEx wird garnicht aufgerufen, zumindest nicht direkt?

Sorry, Programiertechnisch denke ich irgendwie linear und in Autoit bin ich noch neu.
Gut, RTFM,... Autoit kennt einen "On Event Mode"...
Die Initialisierung gemäß Tuturial mit Opt("GUIOnEventMode", 1) gibts aber nicht im Script
Seltsam

**water**

[autoit]

ObjEvent($oOApp, "oOApp_")

[/autoit]

vollbringt das Wunder. Für die Applikation $oOApp soll für jedes Event (jedes hat einen anderen Namen) eine Funktion aufgerufne werden die mit "oOApp_" beginnnt und den Namen des Events angehängt hat.
Beim Event "NewMailEx" wird also die Funktion "oOApp_NewMailEx" aufgerufen - voila!

Kasper

OK, verstehe, danke für die Erläuterung.
Die Routine funktioniert jetzt auch mit der coolen Event-Steuerung

C

#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#AutoIt3Wrapper_Au3Check_Stop_OnWarning=Y
#include <OutlookEX.au3>


; *****************************************************************************
; Handle Outlook NewmailEX event when a new mail arrives.
; This script send a mail to the current user and show after mail arrival the transfer time in seconds.
; Mail delivery end the script, otherwise it loops until Shift-Alt-E is pressed.
; *****************************************************************************
HotKeySet("+!e", "_Exit") ;Shift-Alt-E to Exit the script
MsgBox(64, "Autoit Script", "Click OK to send a testmail. If no mail is received you can interrupt the script with Hotkey: 'Shift-Alt-E'!")


$oOL = _OL_Open()
Global $oOApp = ObjCreate("Outlook.Application")
Global $test = ObjEvent($oOApp, "oOApp_")
Global $sCurrentUser = $oOL.GetNameSpace("MAPI").CurrentUser.Name


Local $begin = TimerInit()


_OL_Wrapper_SendMail($oOL, $sCurrentUser, "", "", "TestA123", "Hallo, dies ist eine Testmail.", "C:\Temp\Anhang.ppt", $olFormatHTML, $olImportanceHigh)


While 1
 Sleep(10)
WEnd


Func oOApp_NewMailEx($sOL_EntryId)
 Local $oOL_Item = $oOApp.Session.GetItemFromID($sOL_EntryId, Default)
 Local $dif = TimerDiff($begin)/1000
    MsgBox(0, "Mail Send to Receive in sec", $dif)
    Exit
EndFunc   ;==>oOApp_NewMailEx


Func _Exit()
 Exit
EndFunc   ;==>_Exit

Alles anzeigen

**water**

Schön, dass es funzt