Compilierte exe als Dienst/Service laufen lassen.

platte

Hallo Leute bin neu im Forum und hab wie alle Newbeeeeees gleich mal ne Frage,
ich habe mir ein Skript ähnlich wie der Scheduler aus der SkripteDB gebaut mit dem ich eine INI - Datei auslese und zur ausgelesen Zeit ein Befehl starte, das Skript bzw. die compilierte exe funktioniert wunderbar, jetzt die Frage ich möchte diese Datei als Dienst unter Windows laufen lassen, im WindowsressourcenKit gibt es das Tool INSTSRV mit dem man ein exe zum Dienst macht bzw. es werden die RegEinträge dafür gemacht um eine exe als Dienst laufen zu lassen. Leider lässt sich das mit der compilierten exe nicht machen, der Dienst wird installiert lässt sich aber nicht starten. Hat jemand schonmal sowas gemacht oder eine Idee vielleicht muss aus dem Skript nochwas übergeben werden??!!!

Ciao und danke Jens.

**Xenobiologist**

Hi,

hilft das?

PHP

Func _SrvAny($service, $fullpath, $hidden = 0)
; Adds a program, as a windows service.
; Requires $instsrv and $srvany to be assigned, full paths.
; e.g. _SrvAny ( 'ServiceName', 'FullPath_to_the_program' )
    Local $instsrv = @WindowsDir & '\System32\Instsrv.exe'
    Local $srvany = @WindowsDir & '\System32\SrvAny.exe'
    If FileExists($instsrv) And FileExists($srvany) Then
        RunWait($instsrv & ' ' & $service & ' "' & $srvany & '"', '', @SW_HIDE)
        Local $key = 'HKLM\SYSTEM\CurrentControlSet\Services\' & $service
        If RegRead($key, 'DisplayName') Then
            If $hidden Then RegWrite($key & '\Parameters', 'AppParameters', 'Reg_sz', '/hidden')
            Return RegWrite($key & '\Parameters', 'Application', 'Reg_sz', $fullpath)
        EndIf
    EndIf
EndFunc

Alles anzeigen

So long,

Mega

platte

@th.meger danke aber das hilft mir nicht weiter, das was die Function macht, macht ja instsrv.exe, ich möchte ja eine compilierte exe als Dienst laufen lassen. Mit instsrv bekomme ich ja auch den Dienst installiert nur läuft dieser nicht, er lässt sich nicht starten. Ich denke da muss noch was in das Script rein damit das läuft. ODER??

Ciao Jens

trallala

hi,

ich habe mal ein wenig gestöbert, evtl. hilft dir das weiter

http://www.autoitscript.com/forum/index.php?showtopic=17581

mfg
trallala

**peethebee**

Hallo!

@platte: Muss das wirklich sein?

peethebee

**Gun-Food**

Es kommt darauf an, wie du deinen "Dienst" programmiert hast. Mal eben nen Dienst ist nicht so einfach. Er muss nen bestimmten Status zurück geben. Was sagt den dein Eventlog, wenn du versuchst den Dienst zu starten?

**Xenobiologist**

Hi,

also bei mir funktioniert das. Ich habe zwar kein Skript, dass ich als Dienst laufen lassen möchte, aber rein technisch funktioniert es.

So long,

Mega

platte

@ peethebee: ja ich weiß es ist nicht schön in zwei Foren zu posten aber das Thema brennt mir unter den Nägeln... sorry!!

admin : Ja genau das mit dem Status zurückgeben, das muss doch definiert werden. Bloss wie und wo ist die Frage hast du mehr Informationen darüber?? were schön... Eine compilierte exe oder eine andere exe mit INSTSRV und ANYSRV als Dienst in die Reg einzutragen ist nicht das Problem. Meine compilierte exe läuft mit normalen Aufruf(Doppelklick ) wunderbar nur wenn ich sie mit INSTSRV und ANYSRV als Dienst installiere startet der Dienst und stoppt sofort wieder.

ich danke!!

Ciao Jens

**Xenobiologist**

Hi,

hast du ptrex Skript benutzt? Wie gesagt, funktioniert ganz gut.

So long,

Mega

platte

@ th.menger: ja habe ich aber wie schon in meinem vorherigem post, der dienst startet und stop sofort wieder.

ciao jens

**Xenobiologist**

HI,

was für ein Skript willst du denn als Dienst laufen lassen? Vielleicht kannst du den Source ja posten, dann kompiliere ich den und teste mal ob ich die exe als Service einbinden kann.

So long,

Mega

platte

Ich werde dies so schnell wie möglich tun...
Habe das zwar schon probiert aber 4 Augen sehen mehr wie 2..

Ciao Jens

**Xenobiologist**

HI,

alles klar. Ich denke, da wird sich eine Lösung finden lassen.

So long,

Mega

platte

So hier mein Script:

C

; ========================================================
; Includes
; ========================================================
#Include <Date.au3>
#include <array.au3>
#Include <process.au3>
#NoTrayIcon
; ========================================================
; Constanten, Array und Variablen anlegen
; ========================================================
Global Const $JobInI = @ScriptDir & "\Service_Jobs.ini"
Global $JobsMax
Global $arrayJobTime[1]
Global $arrayJobNumbers[1]
; ========================================================
; Functionen
; ========================================================
Func _JobNumbersReadInI()
	$JobNumbersInI = IniReadSectionNames(@ScriptDir & "\Service_Jobs.ini")
	If @error Then 
		MsgBox(4096, "", "Kann InI nicht finden oder lesen")
	Else
		$JobsMax = $JobNumbersInI[0]
		$arrayJobNumbers[0] = $JobsMax
		$i=1
		While $i <= $JobsMax
			_ArrayAdd($arrayJobNumbers, $JobNumbersInI[$i])
			$i = $i + 1
		WEnd
		;_ArrayDisplay($arrayJobNumbers, "Test")
	EndIf
EndFunc


Func _JobTimeReadInI()
	$i = 1
	While $i <= $JobsMax
		$z = IniRead($JobInI, 'Job_' & $i, 'Tag_' & @WDAY, "error")
		_ArrayAdd($arrayJobTime, $z)
		$i =  $i + 1
	WEnd
	;_ArrayDisplay($arrayJobTime, "Test")
EndFunc
;
Func _JobStartNow()
	$TimeNow =  @HOUR & ':' & @MIN
	$i = 1
	While $i <= $JobsMax
		If $arrayJobTime[$i] = $TimeNow Then
			$RunTaskPath = IniRead($JobInI, 'Job_' & $i, "Pfad", "error")
			$RunTaskFile = IniRead($JobInI, 'Job_' & $i, "Dateiname", "error")
			$RunTaskPara = IniRead($JobInI, 'Job_' & $i, "Parameter", "error")
			If Not ProcessExists($RunTaskFile) Then
				If Not $RunTaskFile = "error" And Not $RunTaskPath = "error" Then
				;$rc = RunWait(@ComSpec & ' /c ' & '"' & $RunTask & '"')
				$rc = _RunDOS($RunTaskPath & $RunTaskFile & ' ' & $RunTaskPara)
				EndIf
			EndIf
		EndIf
		$i = $i + 1
	WEnd
EndFunc
; =========================================================
_JobNumbersReadInI()
_JobTimeReadInI()
;_JobStartNow()
While 1
AdlibEnable("_JobStartNow")
Sleep(2000)
WEnd

Alles anzeigen

und die dazu gehörige InIDatei

Code

[Job_1]
Tag_1 = 0
Tag_2 = 05:45
Tag_3 = 05:45
Tag_4 = 05:45
Tag_5 = 05:45
Tag_6 = 05:45
Tag_7 = 0
Pfad = d:\Bin\PfW\Bin\
Dateiname = DabMain.exe
Parameter = q


[Job_2]
Tag_1 = 0
Tag_2 = 09:45
Tag_3 = 0
Tag_4 = 09:45
Tag_5 = 0
Tag_6 = 09:45
Tag_7 = 0
Pfad = d:\orainstall\ora8i\
Dateiname = chk_DBV
Parameter = MAIL

Alles anzeigen

Natürlich kann jeder belibige Eintrag in der Ini stehen.

Danke Jens!

muh_kuh

http://autoit.aufwaerts.de/jgs_db.php?action=show&eintrags_id=14&katid=12&sid=

platte

@ muh_kuh: das hilft nicht weiter so weit waren wir schon im Thread...
trotzdem danke!!

Ciao Jens

platte

Ich habe noch etwas interessantes gefunden in der DLL (advapi32.dll) gibt es die Function (ControlService) kann mir jemand da weiter helfen bin leider im CallDll nicht so fit. Die DLL mit Ihren Functionen sind gut unter:
http://www.pinvoke.net/default.aspx/advapi32.ControlService beschrieben.

Oder kann man da mit ner DLL garnichts machen.

Ciao Jens

**bernd670**

Hallo,

den Aufruf

Code

AdlibEnable("_JobStartNow")

solltest du vor die While-Schleife schreiben und den Paramter für Zeit auf ca. 15sek. stellen

Code

AdlibEnable("_JobStartNow",15000)
While 1
    Sleep(200) ; Prozessorlast verringern
WEnd

Das bewirkt das alle 15 sek. die Funktion _JobStartNow() aufgerufen wird.
Ohne Zeitangabe wird die Funktion alle 250ms aufgerufen.

platte

Danke bernd670 das ist gut fürs finetuning aber leider löst das nicht mein Problem...!!

Ciao Jens

**bernd670**

Ich kann das Programm als Dienst einrichten und laufen lassen!

Ich habe noch ein paar Änderungen an der Run-Zeile vorgenommen, so wie du es geschrieben hast ist es bei mir nicht gelaufen!

Spoiler anzeigen

C

; ========================================================
; Includes
; ========================================================
#Include <Date.au3>
#include <array.au3>
#Include <process.au3>
#NoTrayIcon
; ========================================================
; Constanten, Array und Variablen anlegen
; ========================================================
Global Const $JobInI = @ScriptDir & "\Service_Jobs.ini"
Global $JobsMax
Global $arrayJobTime[1]
Global $arrayJobNumbers[1]
; ========================================================
; Functionen
; ========================================================
Func _JobNumbersReadInI()
	$JobNumbersInI = IniReadSectionNames(@ScriptDir & "\Service_Jobs.ini")
	If @error Then 
		MsgBox(4096, "", "Kann InI nicht finden oder lesen")
	Else
		$JobsMax = $JobNumbersInI[0]
		$arrayJobNumbers[0] = $JobsMax
		$i=1
		While $i <= $JobsMax
			_ArrayAdd($arrayJobNumbers, $JobNumbersInI[$i])
			$i = $i + 1
		WEnd
		;_ArrayDisplay($arrayJobNumbers, "Test")
	EndIf
EndFunc


Func _JobTimeReadInI()
	$i = 1
	While $i <= $JobsMax
		$z = IniRead($JobInI, 'Job_' & $i, 'Tag_' & @WDAY, "error")
		_ArrayAdd($arrayJobTime, $z)
		$i =  $i + 1
	WEnd
	;_ArrayDisplay($arrayJobTime, "Test")
EndFunc
;
Func _JobStartNow()
	$TimeNow =  @HOUR & ':' & @MIN
	$i = 1
	While $i <= $JobsMax
		If $arrayJobTime[$i] = $TimeNow Then
			$RunTaskPath = IniRead($JobInI, 'Job_' & $i, "Pfad", "error")
			$RunTaskFile = IniRead($JobInI, 'Job_' & $i, "Dateiname", "error")
			$RunTaskPara = IniRead($JobInI, 'Job_' & $i, "Parameter", "error")
            MsgBox(0,"", $RunTaskPath & @CRLF & $RunTaskFile & @CRLF & $RunTaskPara)
			If Not ProcessExists($RunTaskFile) Then
				If $RunTaskFile <> "error" And $RunTaskPath <> "error" Then
				;$rc = RunWait(@ComSpec & ' /c ' & '"' & $RunTask & '"')
;~ 				$rc = _RunDOS($RunTaskPath & $RunTaskFile & ' ' & $RunTaskPara)
                $rc = Run(StringStripWS($RunTaskPath & $RunTaskFile & ' ' & $RunTaskPara,3),$RunTaskPath, @SW_HIDE)
				EndIf
			EndIf
		EndIf
		$i = $i + 1
	WEnd
EndFunc
; =========================================================
_JobNumbersReadInI()
_JobTimeReadInI()
;_JobStartNow()
AdlibEnable("_JobStartNow",60000)
While 1
    Sleep(200)
WEnd

Alles anzeigen

Mit diesem Script habe ich den Dienst eingerichtet:

Spoiler anzeigen

C

;-------------------------------------
;
; Run AutoIT Scripts as a service
; PTREX 03/11/2005
;
;-------------------------------------
#include <GUIConstants.au3>
#include <Process.au3>


#NoTrayIcon


;Declare Vars
Global $objWMIService
Global $strComputer = "."


Const $OWN_PROCESS = 16;16 is own process
Const $INTERACTIVE = true;True changes the $Own_Process to 272 is interact with desktop
Const $NORMAL_ERROR_CONTROL = 1
Dim $Script, $SrvAny, $info, $Help, $ServiceName = "Service_Jobs"


;Main Gui
;Generated with Form Designer preview, great Job !!
GUICreate("CreateService",500,160)
GUICtrlCreateLabel("SRVANY.EXE", 30,32)
$IB_SrvAny = GUICtrlCreateInput($SrvAny,150,30,250)
$But_SrvAny = GUICtrlCreateButton("...",410,30,20,20)
GUICtrlCreateLabel("Service_Jobs.exe", 30,57)
$IB_Script = GUICtrlCreateInput($Script,150,55,250)
$But_Script = GUICtrlCreateButton("...",410,55,20,20)
$But_InstallService = GUICtrlCreateButton("Install Service",30,90,120)
$But_StartService = GUICtrlCreateButton("Start Service",170,90,120)
$But_DeleteService = GUICtrlCreateButton("Delete Service",30,120,120)
$But_StopService = GUICtrlCreateButton("Start Service",170,120,120)


GUISetState(@SW_SHOW)


While 1
    $msg = GuiGetMsg()
    Select
    Case $msg = $GUI_EVENT_CLOSE
        ExitLoop
    Case $msg = $But_SrvAny
        _File_Open()
    Case $msg = $But_Script
        _Select_Script()
    Case $msg = $But_InstallService
        _Install_Service()
    Case $msg = $But_DeleteService
        _Delete_Service()
    Case $msg = $But_StartService
        _Start_Service()
    case $msg = $But_StopService
        _Stop_Service()
    EndSelect
WEnd
Exit


;Functions
Func _File_Open()
    $FileOD = FileOpenDialog("Select SrvAny.exe File", @SystemDir, "EXE (*.exe)", 3)
    $File = FileOpen($FileOD, 0)
    If $File = -1 Then
        MsgBox(0, "Error", "Unable to open file, or no file selected !!")
    Else
        GUICtrlSetData($IB_SrvAny,Chr(34) & $FileOD  & chr(34))
        $SrvAny = (Chr(34) & $FileOD  & chr(34) )
    EndIf
    FileClose($File)
EndFunc


Func _Select_Script()
    $FileOD = FileOpenDialog("Select Au3 Script File", "C:\", "EXE (*.exe)", 3)
    $File = FileOpen($FileOD, 0)
    If $File = -1 Then
        MsgBox(0, "Error", "Unable to open file, or no file selected !!")
    Else
        GUICtrlSetData($IB_Script,Chr(34) & $FileOD  & chr(34))
        $Script = (Chr(34) & $FileOD  & chr(34) )
    EndIf
    FileClose($File)
Endfunc


Func _Install_Service()
    If $SrvAny = "" Then
    MsgBox(0,"Warning ", "Select the SrvAny.exe using the File Open first")
    Else
    MsgBox(0,"Information","This has to be activated only ONCE !!")
    $objWMIService = ObjGet("winmgmts:" & "{impersonationLevel=impersonate}!\\" & $strComputer & "\root\cimv2")
    $objService = $objWMIService.Get("Win32_BaseService")
    $errReturn = $objService.Create($ServiceName ,$ServiceName , $SrvAny, $OWN_PROCESS, $NORMAL_ERROR_CONTROL, _
    "Manual", $INTERACTIVE, "LocalSystem", ""  )
    _Assign_Script()
    _Interact_Desktop()
    EndIf
EndFunc

Func _Delete_Service()
    $objWMIService = ObjGet("winmgmts:" & "{impersonationLevel=impersonate}!\\" & $strComputer & "\root\cimv2")
    $colListOfServices = $objWMIService.ExecQuery ("Select * from Win32_Service Where Name = '" & $ServiceName & "'")
        For $objService in $colListOfServices
            $objService.StopService()
            $objService.Delete()
    Next
EndFunc


Func _Start_Service()
    Local $var1 = RegRead("HKLM\SYSTEM\CurrentControlSet\Services\" & $ServiceName, "ImagePath")
    If @error = -1 or StringRight ($var1, 11) <> "SrvAny.exe"&chr(34) Then
        MsgBox(4096,"",  "RegKey SrvAny not yet created, or not correct"&$var1)
    Else
        Local $var2 = RegRead("HKLM\SYSTEM\CurrentControlSet\Services\" & $ServiceName & "\Parameters", "Application")
        If @error = 1 Then
        MsgBox(0,"Warning","No Script has been assigned yet to the Any service!!")
        EndIf
    _RunDos("Net start " & $ServiceName)
    EndIf
EndFunc


Func _Stop_Service()
    _RunDos("Net stop " & $ServiceName)
EndFunc


Func _Open_Services()
    _RunDos("services.msc")
EndFunc


Func _Interact_Desktop()
    Local $var1 = RegRead("HKLM\SYSTEM\CurrentControlSet\Services\" & $ServiceName, "ImagePath")
    if @error = -1 or StringRight ($var1, 11) <> "SrvAny.exe"&chr(34) Then
        MsgBox(4096,"",  "RegKey not yet created, or not correct")
        RegWrite("HKLM\SYSTEM\CurrentControlSet\Services\" & $ServiceName, "Type", "REG_DWORD", "272")
;~         RegWrite("HKLM\SYSTEM\CurrentControlSet\Services\" & $ServiceName, "Type", "REG_DWORD", "16")
    EndIf
EndFunc


Func _Assign_Script()
        Local $var1 = RegRead("HKLM\SYSTEM\CurrentControlSet\Services\" & $ServiceName, "ImagePath")
    if @error = -1 or StringRight ($var1, 11) <> "SrvAny.exe"&chr(34) Then
        MsgBox(4096,"",  "RegKey not yet created, or not correct")
    Else
        RegWrite("HKLM\SYSTEM\CurrentControlSet\Services\" & $ServiceName & "\Parameters", "AppDirectory", "REG_SZ", @WorkingDir)
        RegWrite("HKLM\SYSTEM\CurrentControlSet\Services\" & $ServiceName & "\Parameters", "Application", "REG_SZ", $Script)
    EndIf
EndFunc

Alles anzeigen

Ich habe das Scirpt etwas angepasst.

Noch ein kliener Tipp: Die Leerzeichen in der Ini-Datei (vor und nach "=") kann zu problemen führen! Am besten ohne Leerzeichen schreiben!