Button: 1. -ändern der Farbe- und 2. -Name des Button per Tastatur (Hotkey) erreichen-.

bazii

Hallo BugFix,

jetzt funktioniert es ganz klasse mit den Pfeiltasten. Vielen Dank.

Ein Problem ist noch, dass meine Buttons nun per Mausklick, keine Funktionen mehr ausführen.

HotKeySet("!b", "_uac") funktioniert noch. Ich habe sicher den Code an die falsche Stelle eingebaut, oder?

EDIT:

hab's geschafft. Jetzt funktioniert fast alles wie es soll.

**BugFix**

Zitat von bazii

Ein Problem ist noch, dass meine Buttons nun per Mausklick, keine Funktionen mehr ausführen.

Anhand meines Bsp-Codes kann ich das nicht nachvollziehen. Deshalb weiß ich nicht, wo da bei dir der Fehler entsteht.

bazii

Entschuldige bitte BugFix,

ich hatte eben noch meinen vorherigen Code editiert. Es funktioniert nun bestens mit den Pfeiltasten. Ich musste nur den Code

Code

Case -3
;~ 			Exit
;~ 		Case $Dummy_Up
;~ 			_SetFocus(0,-1)
;~ 		Case $Dummy_Down
;~ 			_SetFocus(0,1)
;~ 		Case $Dummy_Left
;~ 			_SetFocus(-1,0)
;~ 		Case $Dummy_Right
;~ 			_SetFocus(1,0)
;~ 		Case $taskschd, $uac, $CMD, $compmgmt, $diskmgmt, $dfrgui, $cleanmgr, $control, $blind
;~ 			ConsoleWrite('Clicked: ' & ControlGetText($gui1, '', $nMsg) & @CRLF)

Alles anzeigen

an meine eigentliche "While" ans Ende anfügen. Ich hatte das zuvor am Anfang eingebaut. Ich kann bisher die Auswirkungen nicht richtig einschätzen.

Gleich entstand aber die die nächste und vorest "hoffentlich" letzte Frage.
Für die Menschen mit Sehbehinderungen, welche nur die Tastatur benutzen, wäre es sicher noch sehr sinnvoll. den zuvor mit den Pfeiltasten ausgewählten Button (der per NVDA vorgelesen wird), schlussendlich mit der Entertaste auszuführen. Ich hatte zu Anfangs nicht daran gedacht. Ist das denn noch umsetzbar?

**BugFix**

Zitat von bazii

schlussendlich mit der Entertaste auszuführen. Ich hatte zu Anfangs nicht daran gedacht. Ist das denn noch umsetzbar?

Kein Problem, einfach einen ENTER-Dummy hinzufügen zum Auslösen des Buttons der aktuell den Fokus hat:

Spoiler anzeigen

AutoIt

$hGui = GUICreate('Test')
$Button_1 = GUICtrlCreateButton('1', 10, 10, 30, 20)
$Button_2 = GUICtrlCreateButton('2', 50, 10, 30, 20)
$Button_3 = GUICtrlCreateButton('3', 90, 10, 30, 20)
$Button_4 = GUICtrlCreateButton('4', 130, 10, 30, 20)
$Button_5 = GUICtrlCreateButton('5', 170, 10, 30, 20)
$Button_6 = GUICtrlCreateButton('6', 210, 10, 30, 20)
$Button_7 = GUICtrlCreateButton('7', 10, 50, 30, 20)
$Button_8 = GUICtrlCreateButton('8', 50, 50, 30, 20)
$Button_9 = GUICtrlCreateButton('9', 90, 50, 30, 20)
$Dummy_Up = GUICtrlCreateDummy()
$Dummy_Down = GUICtrlCreateDummy()
$Dummy_Left = GUICtrlCreateDummy()
$Dummy_Right = GUICtrlCreateDummy()
$DummyEnter = GUICtrlCreateDummy()


Global $iFocusCurrent = $Button_1
ControlFocus($hGui, '', $Button_1)
Global $aAccelerators[5][2] = [['{UP}',$Dummy_Up],['{DOWN}',$Dummy_Down],['{LEFT}',$Dummy_Left],['{RIGHT}',$Dummy_Right],['{ENTER}',$DummyEnter]]
GUISetAccelerators($aAccelerators, $hGui)


GUISetState()


While True
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case -3
			Exit
		Case $Dummy_Up
			_SetFocus(0,-1)
		Case $Dummy_Down
			_SetFocus(0,1)
		Case $Dummy_Left
			_SetFocus(-1,0)
		Case $Dummy_Right
			_SetFocus(1,0)
		Case $DummyEnter
			ControlClick($hGui, '', ControlGetFocus($hGui))
		Case $Button_1,$Button_2,$Button_3,$Button_4,$Button_5,$Button_6,$Button_7,$Button_8,$Button_9
			ConsoleWrite('Clicked: ' & ControlGetText($hGui, '', $nMsg) & @CRLF)
	EndSwitch
WEnd


Func _SetFocus($Spalte, $Zeile)
	Local Static $aButton[2][6] = [[$Button_1,$Button_2,$Button_3,$Button_4,$Button_5,$Button_6],[$Button_7,$Button_8,$Button_9]]
	Local Static $iCurrentLine = 0, $iCurrentRow = 0
	$iCurrentLine += $Zeile
	$iCurrentLine = $iCurrentLine > 2 ? 2 : ($iCurrentLine < 0 ? 0 : $iCurrentLine)
	$iCurrentRow += $Spalte
	If $iCurrentLine = 0 Then
		$iCurrentRow = $iCurrentRow > 5 ? 5 : ($iCurrentRow < 0 ? 0 : $iCurrentRow)
	ElseIf $iCurrentLine = 1 Then
		$iCurrentRow = $iCurrentRow > 2 ? 2 : ($iCurrentRow < 0 ? 0 : $iCurrentRow)
	EndIf
	ControlFocus($hGui, '', $aButton[$iCurrentLine][$iCurrentRow])
EndFunc

Alles anzeigen

bazii

Hallo BugFix,

Was soll ich Dir sagen außer, 100% klasse Hilfestellung. Das hat richtig gut funktioniert. Jetzt muss ich mal wieder an dem erlernten weiterarbeiten und schauen, dass ich kapiere was da vor sich geht. Gut dass es in Autoit die F1-Taste gibt. Wenn ich es nur kapieren würde was da alles steht.

Was ich zum Beispiel nicht verstehe ist die Funktion:

Code

Func _SetFocus($Spalte, $Zeile)
	Local Static $aButton[10][6] = [[$taskschd,$uac,$CMD,$compmgmt,$diskmgmt,$dfrgui],[$cleanmgr,$control,$blind]]
	Local Static $iCurrentLine = 0, $iCurrentRow = 0
	$iCurrentLine += $Zeile
	$iCurrentLine = $iCurrentLine > 2 ? 2 : ($iCurrentLine < 0 ? 0 : $iCurrentLine)
	$iCurrentRow += $Spalte
	If $iCurrentLine = 0 Then
		$iCurrentRow = $iCurrentRow > 5 ? 5 : ($iCurrentRow < 0 ? 0 : $iCurrentRow)
	ElseIf $iCurrentLine = 1 Then
		$iCurrentRow = $iCurrentRow > 2 ? 2 : ($iCurrentRow < 0 ? 0 : $iCurrentRow)
	EndIf
	ControlFocus($gui1, '', $aButton[$iCurrentLine][$iCurrentRow])
EndFunc

Alles anzeigen

@Bufix: Dafür hätte ich (wenn ich es überhaupt geschafft hätte) Wochen benötigt.

Ich kapiere nicht, warum und wofür zum Beispiel die Zahlen stehen. Was ist "2 ? 2", was ist "5 ? 5". Warum ist da ein "?". Warum wird nach der Zahl ein Teiler eingesetzt wie
": ($iCurrentLine < 0 ? 0 : $iCurrentLine)" Das schütteltst Du / Ihr einfach mal so aus dem Ärmel. Wie macht man das nur?

**bernd670**

Hallo,

das ist einfacher als es aussieht, aber wie das so oft ist, wenn man erst mal weiß wie es geht versteht man auch die Bedienungsanleitung!

In der Hilfe findest du es übrigens unter dem Begriff Ternary.

Es ist im Prinzip nicht mehr ein ein verkürzte If ... Then ... Else -Anweisung.

Vor dem Fragezeichen steht die Bedingung, hinter dem Fragezeichen das was zugewiesen werden soll wenn die Bedingung erfüllt ist und nach dem Doppelpunkt, dass was zugewiesen werden soll wenn die Bedingung nicht erfüllt ist.

[autoit]

$iCurrentLine = $iCurrentLine > 2 ? 2 : ($iCurrentLine < 0 ? 0 : $iCurrentLine)

[/autoit]

heisst nichts anderes als

AutoIt

If $iCurrentLine > 2 Then
	$iCurrentLine = 2
Else
	If $iCurrentLine < 0 Then
		$iCurrentLine = 0
	Else	                          ; nur der Vollständigkeitshalber, dieser Else-Zweig
		$iCurrentLine = $iCurrentLine ; kann in diesem Fall auch weggelassen werden
	EndIf
EndIf

bazii

Hallo bernd670

Ahhhh, verstehe. So wird der Code quasi abgekürtzt wenn man das Know how hat, wie das geht. Vielen Dank der Erklärung. Mit If > Then > Else konnte ich jetzt verstehen was gemeint war. So wie BugFix den Code geschrieben hatte, war er natürllich für mich viel einfacher einzubauen. Vielen Dank dafür.

Jetzt aber wirklich noch eine aller letzte Frage, auch wenn es schon peinlich für mich ist. Es kommt halt eines zum anderen ohne es vorher zu sehen.
Es ist diese typische Hand abreisen, obwohl ich nur einen kleinen Finger zu Beginn haben wollte.

Die Frage:
Wenn ich mit der Tab-Taste von Button zu Button springe, färben sich die Buttons am Randbereich blau ein. Somit ist sofort erkennbar (für gut sehende natürlich), wo man sich befindet. Ist diese Einfärung auch für das springen von Button zu Button mit den Pfeiltasten machbar? Wäre naürlich nur noch eine rein optische Verbesserung.

**bernd670**

Das sollte eigentlich schon gehen da ja der Focus mit ControlFocus jedesmal neu gesetzt wird.

bazii

ControlFocus kommt bei mir 2 mal im Code vor:

Das erste Mal bei:

Code

ControlFocus($gui1, '', $taskschd)
Global $aAccelerators[5][2] = [['{UP}',$Dummy_Up],['{DOWN}',$Dummy_Down],['{LEFT}',$Dummy_Left],['{RIGHT}',$Dummy_Right],['{ENTER}',$Dummy_Enter]]
GUISetAccelerators($aAccelerators, $gui1)

Diese Zeilen habe ich nach den While Zeilen eingefügt, also nach WEnd. Und das zweite Mal kommt es vor bei der Funktion in Zeile 12:

Code

Func _SetFocus($Spalte, $Zeile)
	Local Static $aButton[10][6] = [[$taskschd,$uac,$CMD,$compmgmt,$diskmgmt,$dfrgui],[$cleanmgr,$control,$blind]]
	Local Static $iCurrentLine = 0, $iCurrentRow = 0
	$iCurrentLine += $Zeile
	$iCurrentLine = $iCurrentLine > 2 ? 2 : ($iCurrentLine < 0 ? 0 : $iCurrentLine)
	$iCurrentRow += $Spalte
	If $iCurrentLine = 0 Then
		$iCurrentRow = $iCurrentRow > 5 ? 5 : ($iCurrentRow < 0 ? 0 : $iCurrentRow)
	ElseIf $iCurrentLine = 1 Then
		$iCurrentRow = $iCurrentRow > 2 ? 2 : ($iCurrentRow < 0 ? 0 : $iCurrentRow)
	EndIf
	ControlFocus($gui1, '', $aButton[$iCurrentLine][$iCurrentRow])
EndFunc

Alles anzeigen

Diese Func habe ich vor den Button Funktionen stehen.

Die Buttons werden zwar leicht gestrichelt umrandet angezeigt, wenn ich von Button zu Button hüpfe, aber nicht blau umrandet wie bei der Tab-Taste.

**bernd670**

Hallo,

die Funktion _SetFocus hat einen kleinen Fehler, sie bekommt nämlich nicht mit wenn zwischendurch mal mit der Tab-taste weitergesprungen wird. Ich habe mal in das Beispiel von @BugFix ein paar kleine Änderungen eingebaut. Zusätzlich habe ich auch dem aktuellen Button nicht nur den Focus gegeben, sondern ihn auch den Status DefButton gegeben. Jetzt sollte der Blaue Rahmen auch mit springen. Dadurch ist auch gleich gewährleistet das der aktuelle Button mit Enter aktiviert werden kann.

AutoIt

#include <array.au3>


$hGui = GUICreate('Test')
$Button_A = GUICtrlCreateButton('A', 10, 10, 30, 20)
$Button_B = GUICtrlCreateButton('B', 50, 10, 30, 20)
$Button_C = GUICtrlCreateButton('C', 90, 10, 30, 20)
$Button_D = GUICtrlCreateButton('D', 10, 50, 30, 20)
$Button_E = GUICtrlCreateButton('E', 50, 50, 30, 20)
$Button_F = GUICtrlCreateButton('F', 90, 50, 30, 20)
$Button_G = GUICtrlCreateButton('G', 10, 90, 30, 20)
$Button_H = GUICtrlCreateButton('H', 50, 90, 30, 20)
$Button_I = GUICtrlCreateButton('I', 90, 90, 30, 20)
$Dummy_Up = GUICtrlCreateDummy()
$Dummy_Down = GUICtrlCreateDummy()
$Dummy_Left = GUICtrlCreateDummy()
$Dummy_Right = GUICtrlCreateDummy()


GUICtrlSetState($Button_A, 768) ; Focus + Defbutton
;~ ControlFocus($hGui, '', $Button_A)
Global $aAccelerators[4][2] = [['{UP}',$Dummy_Up],['{DOWN}',$Dummy_Down],['{LEFT}',$Dummy_Left],['{RIGHT}',$Dummy_Right]]
GUISetAccelerators($aAccelerators, $hGui)


GUISetState()


While True
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case -3
			Exit
		Case $Dummy_Up
			_SetFocus(0,-1)
		Case $Dummy_Down
			_SetFocus(0,1)
		Case $Dummy_Left
			_SetFocus(-1,0)
		Case $Dummy_Right
			_SetFocus(1,0)
		Case $Button_A, $Button_B, $Button_C, $Button_D, $Button_E, $Button_F, $Button_G, $Button_H, $Button_I
			ConsoleWrite('Clicked: ' & ControlGetText($hGui, '', $nMsg) & @CRLF)
	EndSwitch
WEnd


Func _SetFocus($Spalte, $Zeile)
	Local Static $aButton[3][3] = [[$Button_A,$Button_B,$Button_C],[$Button_D,$Button_E,$Button_F],[$Button_G,$Button_H,$Button_I]]
	Local $iCurrentLine, $iCurrentRow


	; Button mit Focus ermitteln, falls mal Tab gedrückt wurde
	for $iLine = 0 To UBound($aButton, 1) - 1
		for $iRow = 0 To UBound($aButton, 2) - 1
			If ControlGetHandle($hGui, "", $aButton[$iLine][$iRow]) = ControlGetHandle($hGui, "", ControlGetFocus($hGui)) Then
				$iCurrentLine = $iLine
				$iCurrentRow = $iRow
				ExitLoop 2
			EndIf
		Next
	Next


	$iCurrentLine += $Zeile
	$iCurrentLine = $iCurrentLine > 2 ? 2 : ($iCurrentLine < 0 ? 0 : $iCurrentLine)
	$iCurrentRow += $Spalte
	$iCurrentRow = $iCurrentRow > 2 ? 2 : ($iCurrentRow < 0 ? 0 : $iCurrentRow)
;~ 	ControlFocus($hGui, '', $aButton[$iCurrentLine][$iCurrentRow])
	GUICtrlSetState($aButton[$iCurrentLine][$iCurrentRow], 768) ; Focus + Defbutton




EndFunc

Alles anzeigen

bazii

Hallo bernd670,

Klasse dass Du eine Lösung dafür gefunden hast.

Ich bin heute den ganzen Tag unterwegs und kann das leider erst heute Abend testen. Ich melde mich dann nochmal.

Vielen Dank vorab.

**Kanashius**

Hier steht auch, wie du AutoIt-Code posten kannst. Ist im allgemeinen schöner zu lesen, als wenn alles grau ist
Dann wird alles schön bunt, ansonsten: Lob, Vorblidliches Posten von Fragen Endlich hat mal jemand die "Frage richtig stellen" threads verstanden

bazii

Hallo,

@bernd670:
Dein Code funktioniert ganz hervorragend. Herzlichen Dank. Jetzt muss ich als nächstes ransetzen und die ganzen Befehle verinnerichen, um den gesamten Code bis zum Finale fertigzustellen.

@Kanashius:
Vielen Dank für den Hinweis mit dem Code-Button, der extra für Autoit-Skripte zur Verfügung steht. Ich werde das selbstverständlich das nächste Mal, wenn ich einen Code zu posten habe, beherzigen.

@all:
Wenn ich alles fertig habe wie ich es mir vorstelle, wird allein durch Eure Hilfe und Autoit ein kleiner Traum für mich wahr. Vielleicht setze ich mich dann an meinen zweiten kleinen Traum, ein Textersetzer, der alle editierbaren Textformate sowie .ZIP, .7z entpacken, packen und Officedokumente bearbeiten kann. Den Status des Themas kann ich jetzt beruhigt auf gelöst setzen. Vielen Dank Euch allen für die hervorragende Hilfe und natürlich auch den Forenadministratoren "peethebee" und "Gun-Food" für das schöne neue Forum, bei dem jetzt schon, nach der Umstellung vieles wieder funktioniert, was gar nicht soooo selbstverständlich ist, wenn man sich mal mit Burning Board Forensoftware auseinandergesetzt hat. Die alten Hasen, die in der Marterie mal gute Konverter zum Umstieg "alter" oder anderer Forensoftware geschrieben haben sterben aus oder sind noch nicht geboren. Dasselbe aber auch bei VBulletin und phpBB. Bei phpBB kam auch nur wieder Schwung in die neue Software, da sich ein kleines Team über menschliche Grenzen hinaus an .php und an die besonderheiten eines Forum gemacht haben. Der Hauptmann der Jungs (Nickvergessen) durfte ich mit wenigen anderen phpBB-Spezialisten bei einem phpBB-Treff mit Bier und Hamburger in Stuttgart kenenlernen. Man muss mit neuer Forensoftware ein wenig mit Abstrichen leben aber gleichsam nach vorne schauen. Wichtig ist, dass die "alten" Hasen die Lust nicht verlieren oder sich wegen Ego-Spielereien anblöken. Genauso wichtig sind die Admins sind die Moderatoren und die Mitglieder. Geht einer der alten Hasen aus dem Stall, folgen die jungen Hasen nach und ziehen um. Darum: Macht weiter so, bleibt bei Autoit. .... Klasse Leute, klasse Forum.