Kopieren von Dateien

Bass_tii

Hallo,
ich habe leider keine Funktion gefunden die für meine Aufgabe zugeschnitten ist.
Bevor ich mir einen Abwürge mit Filesearch usw wollte ich einfach fragen ob es auch einfacher geht.

Ich bin dabei ein kleines Programm zu schreiben das Dateien in ein Spielverzeichnis kopiert.
Dabei handelt es sich um Grafikdateien.
Die Dateien liegen zum Beispiel in
C/Games/WOWS/Res/content....

Meine Dateien die ich kopieren will habe ich die selbe Ordnerstruktur gegeben und kopiere einfach den Kompletten Ordner in das Root Verzeichnis Games // 20 MB
Funktioniert soweit auch super. Weil nur die Dateien die in meiner Ordnerstruktur enthalten sind überschrieben werden.

jetzt ist meine Frage aber, kann ich irgendwie die Dateien sichern bevor ich sie Überschreibe?
Wie mache ich das am einfachsten?
Ich Bräuchte dafür auch am besten die genaue Ordner Struktur
den kompletten \\RES Ordner Sichern geht leider nicht weil der Ordner über 700 MB hat

**bernd670**

Hallo und willkommen im Forum!

Du kannst z. B. einfach mit _FileListToArrayRec eine Liste von Quellordner erstellen.
Dann für jedes Element in der Liste mit FileExists prüfen ob die Datei im Zielordner existiert, wenn ja die Datei aus dem Zielordern sichern, zippen oder was auch immer, danach Datei mit FileCopy kopieren.

Beispiele findest du hier im Forum jede Menge, solltest du dennoch Probleme haben, kannst du deinen Quellcode hier posten.

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Wenn Du weißt welche Dateien kopiert werden sollen, ließ die Dateinamen aus - schreib diese in ein Array oder wenn es nach beendigung des Auoit Inhaltes noch gebraucht wird in eine TXT Datei. Also z.B. meine Dateien.TXT. Aus dieser Liste kannst Du dann auch die Dateien entnehmen die Du "sichern" willst. Unter DOS hat man das mal EXCLUDE / INCLUDE LIST genannt. Ist ein auch heute noch brauchbarer Ansatz.

Gruß

Peter

Bass_tii

Hallo danke schonmal für die Antworten.
Mein Quellcode ist nicht viel weil es bisher einfach nur ein Dircopy ist.
was ich wohl nicht so recht erwähnt habe ist, das die Dateien in unterschiedlichen Unterordnern liegen.
Z.B
C:\Users\Desktop\WoWs\res\content\gameplay\germany\ship\aircarrier\textures
C:\Users\Desktop\WoWs\res\content\gameplay\japan\ship\auxiliary\textures
Dort sind jeweils 2-3 Dateien
Die Ganze OrdnerStruktur besteht aus 50 Ordnern.

AutoIt

local $datapath = $installpath & "\res\content\gameplay"
$installpath = RegRead ( "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Uninstall\{1EAC1D02-C6AC-4FA6-9A44-96258C37C814eu}_is1", "InstallLocation" )
While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch
if $nMsg=$Button1  then
DirCopy(@ScriptDir  & "\res", $installpath  & "\res",1)
EndIf

Alles anzeigen

Also ich würde jetzt für mein Problem hingehen
1. Neue Dateien durchsuchen nach erster Datei
2. Pfad auslesen
3. Pfad Bearbeiten (aus ScriptDir Installpath machen)
4. Diese Datei dann von dort Kopieren und dann in einem entsprechender Backup Folder sichern.
Aber wie gesagt ich denke das geht einfacher

**bernd670**

Hallo,

gerade mal 20 zeilen Code! So wie oben schon mal beschrieben!

AutoIt

#include <File.au3>
#include <FileConstants.au3>


$szInstallPath = RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Uninstall\{1EAC1D02-C6AC-4FA6-9A44-96258C37C814eu}_is1", "InstallLocation" )
$szInstallPath &= "\res"
$szBackupPath = @ScriptDir & "\Backup_" & @YEAR & @MON & @MDAY & @HOUR & @MIN & @SEC
$szSource = @ScriptDir & "\res"


$aFL = _FileListToArrayRec($szSource, "*", $FLTAR_FILES, $FLTAR_RECUR)


If StringRight($szInstallPath, 1) <> "\" Then $szInstallPath &= "\"
If StringRight($szSource, 1) <> "\" Then $szSource &= "\"
If StringRight($szBackupPath, 1) <> "\" Then $szBackupPath &= "\"


For $iFL = 1 To $aFL[0]
	; Wenn Datei im Zielordner existiert nach BackupPath kopieren
	If FileExists($szInstallPath & $aFL[$iFL]) Then FileCopy($szInstallPath & $aFL[$iFL], $szBackupPath & $aFL[$iFL], $FC_CREATEPATH)
	; Datei kopieren
	FileCopy($szSource & $aFL[$iFL], $szInstallPath & $aFL[$iFL], $FC_OVERWRITE + $FC_CREATEPATH)
Next

Alles anzeigen

Bass_tii

Vielen Dank
ich werde mir das ganze morgen mal ansehen was du da genau treibst
sieht auf den ersten Blick aber mal gut aus

Edit:
Super vielen vielen vielen Dank.
Das ist genau das wofür ich geschätze 200 Zeilen code gebraucht hätte.