DateDiff bestimmter Monat innerhalb eines Zeitraums

xbl38spezial

Und wieder einmal recht herzlichen Dank!

Nur ein klein wenig Anpassung und es tut was es soll.

AutoIt

Func _KaufmMonat()
	$Tage = GUICtrlRead( $Diffausgabe) ;tatsächliche Anzahl der Tage im Dienstleistungsmonat
	$StringDate = GUICtrlRead($Enddate)
	$MaxTageMonat = _DateDaysInMonth(StringRight($StringDate,4), StringMid($StringDate,4,2))


	$Tage82 = $szdate
	If $Tage >= 30 and String($MaxTageMonat) > 30 Then
	GUICtrlSetData($82Teiler,  "30/30")
	ElseIf $Tage < 30 and String($MaxTageMonat) > 30 Then
	GUICtrlSetData($82Teiler,  $Tage & "/30")
	Else
	GUICtrlSetData($82Teiler, $Tage & "/" & String($MaxTageMonat))
	EndIf
EndFunc

Alles anzeigen

Zitat von BugFix

Dazu gibt es fertige Funktionen:

$tMin = _GUICtrlMonthCal_GetMonthRangeMin($idMonthCal)

$tMax = _GUICtrlMonthCal_GetMonthRangeMax($idMonthCal)

MfG BugFix

Diese Variante scheint leider bei dem verwendeten Kalender nicht zu funktionieren oder ich hab es vergeigt :-/

**BugFix**

Zitat von xbl38spezial

Diese Variante scheint leider bei dem verwendeten Kalender nicht zu funktionieren oder ich hab es vergeigt :-/

Ja, da war ich etwas zu schnell - geht nur bei GuiMonthCal

xbl38spezial

Nun ist das Berechnungsprogramm schon beinahe 4000 AutoIt-Zeilen lang und weiß noch immer zu überraschen...
Beim durchrechnen verschiedener Beispielfälle ist mir etwas sonderbares aufgefallen.

Und zwar: Beträge im Hunderter, und Zehnerbereich mit den ungeraden Nachkommastellen XXX,33 / XX,33 und XXX,55 / XX,55 werden beim teilen durch 2 bzw. auf 50% gerechnet, falsch kaufmännisch gerundet.

Beispiele:
500,33 € * 0,5 = 250,16 € anstatt wie es richtig wäre 250,17 € oder
55,55 € * 0,5 = 27,77 € anstatt 27,78 €

Nehme ich aber stattdessen Beträge über dem Hunderterbereich z.B. 5000,33 € * 0,5 wird mir folgerichtig 2500,17 € ausgegeben.
Beim Zehnerbereich verhält es sich ebenfalls korrekt.

Hat jemand ne Ahnung woran das liegt? Ein Bug?

Und wenn ich schon mal schreibe, kann ich die Beträge auch mit 1.000 er Trennpunkt darstellen?

Momentan werden sie dank bernd670 mit GUICtrlSetData($hHandle, StringFormat("%.2f €", Number($szValue))) im Format 1000.00 € ausgegeben/umgewandelt. Vermutlich wird es durch die Scriptsprache vorgegebene Formatierung für den Euro nicht möglich sein, zumindest nicht ohne das es Probleme beim Rechnen gibt.

**BugFix**

Zitat von xbl38spezial

Und wenn ich schon mal schreibe, kann ich die Beträge auch mit 1.000 er Trennpunkt darstellen?

AutoIt

; === Formatierter Währungsstring


; Ausgabe Euro, Standard-Währungseinstellung
ConsoleWrite(_FormatCurrency(200*12345) & @CRLF)  ; ==> 2.469.000,00 €


; Ausgabe Dollar, WÃ¤hrungssymbol führend
ConsoleWrite(_FormatCurrency(-200*12345, -1, -1, '
, -1, 1) & @CRLF)  ;==> $ -2.469.000,00


; Ausgabe Dollar, Währungssymbol führend, negativer Wert in Klammern
ConsoleWrite(_FormatCurrency(-200*12345, -1, -1, '
, -1, 1, 1) & @CRLF)  ;==> [$ -2.469.000,00]


; Ausgabe Euro, mit Vornull
ConsoleWrite(_FormatCurrency(4/80) & @CRLF)  ;==> 0,05 €


; Ausgabe Euro, ohne Vornull
ConsoleWrite(_FormatCurrency(4/80, -1, -1, -1, 0) & @CRLF)  ;==> ,05 €


;===============================================================================
; Function Name...: _FormatCurrency
; Description.....: Formatiert einen Ausdruck als Währung
; Parameter(s)....: $iExpression     der zu formatierende Ausdruck
; Requirement(s)..: $iNumDigit       Anzahl Nachkommastellen, -1 = Währungseinstellung PC (Standard)
;                   $iGroupDig       Anzahl Zeichen für Gruppierung, -1 = 3 Zeichen (Standard)
;                   $sCurr           Währungszeichen, -1 = Währungseinstellung PC (Standard)
;                   $iLeadingZero    Führende Null anzeigen, -1 = Währungseinstellung PC (Standard), 0 = nein
;                   $fLeadingSign    Währungszeichen führend anzeigen, 0 = nein (Standard)
;                   $fNegNumInPara   Negative Werte in eckigen Klammern anzeigen, 0 = nein (Standard)
; Return Value(s).: Der formatierte Währungsstring
; Note............: Die Gruppierung ermöglicht maximal 8 Blöcke
; Author(s).......: BugFix (bugfix@autoit.de)
;===============================================================================
Func _FormatCurrency($iExpression, $iNumDigit=-1, $iGroupDig=-1, $sCurr=-1, $iLeadingZero=-1, $fLeadingSign=0, $fNegNumInPara=0)
	Local $sRegKey = 'HKCU\Control Panel\International', $sReturn, $aTmp, $sTmp, $sNul = '000000000', $fNeg = 0
	Local $sDec = RegRead($sRegKey, 'sMonDecimalSep'), $sThousand = RegRead($sRegKey, 'sMonThousandSep')
	Local $sNegative = RegRead($sRegKey, 'sNegativeSign')
	If $iGroupDig < 0 Then $iGroupDig = 3
	If $sCurr = -1 Then $sCurr = RegRead($sRegKey, 'sCurrency')
	If $iNumDigit = -1 Then $iNumDigit = RegRead($sRegKey, 'iCurrDigits')
	If $iLeadingZero = -1 Then $iLeadingZero = RegRead($sRegKey, 'iLZero')
	If IsFloat($iExpression) Then
		$iExpression = Round($iExpression, $iNumDigit)
		$sReturn = String($iExpression)
		If $iNumDigit Then
			$aTmp = StringSplit(String($iExpression), '.')
			$sReturn = $aTmp[1] & Chr(29) & StringLeft($aTmp[2] & $sNul, $iNumDigit)
		EndIf
	Else
		$sReturn = String($iExpression)
		If $iNumDigit Then $sReturn = String($iExpression) & Chr(29) & StringLeft($sNul, $iNumDigit)
	EndIf
	If Not $iLeadingZero And StringRegExp($sReturn, '^-?0' & Chr(29) & '\d*') Then $sReturn = StringReplace($sReturn, '0' & Chr(29), Chr(29), 1)
	If $iGroupDig > 0 And StringLen(Abs($sReturn)) >= $iGroupDig Then
		$aTmp = StringRegExp(StringReplace($sReturn, '.', Chr(29)), _
		"(-?\d{1,"&$iGroupDig&"})(\d{"&$iGroupDig&"})?(\d{"&$iGroupDig&"})?(\d{"&$iGroupDig&"})?(\d{"&$iGroupDig&"})?(\d{"&$iGroupDig&"})?(\d{"&$iGroupDig&"})?(\d{"&$iGroupDig&"})?(?:\Z|("&Chr(29)&"\d+))", 3)
		For $i = 0 To UBound($aTmp) -1
			If $aTmp[$i] <> '' Then $sTmp &= $sThousand & $aTmp[$i]
		Next
		$sReturn = StringTrimLeft(StringReplace($sTmp, $sThousand&Chr(29), Chr(29)), 1)
	EndIf
	If StringLeft($sReturn, 1) = '-' Then $fNeg = 1
	$sReturn = StringReplace(StringReplace($sReturn, '-', $sNegative), Chr(29), $sDec)
	If $fLeadingSign Then
		$sReturn = $sCurr & ' ' & $sReturn
	Else
		$sReturn &= ' ' & $sCurr
	EndIf
	If $fNeg And $fNegNumInPara Then $sReturn = '[' & $sReturn & ']'
	Return $sReturn
EndFunc  ;==>_FormatCurrency

Alles anzeigen

Boah - das Syntaxhighlighting ist ja noch immer abartig.

Zitat von xbl38spezial

500,33 € * 0,5 = 250,16 € anstatt wie es richtig wäre 250,17 € oder

Verwende Round(Expression, 2) zum kaufmännischen Runden.

**AspirinJunkie**

Zitat von xbl38spezial

Hat jemand ne Ahnung woran das liegt? Ein Bug?

Ja - der binäre Rundungsfehler.
Ist von AutoIt unabhängig und tritt bei jeder Programmiersprache mit Gleitkommazahlen auf.
Konkret für dein Beispiel siehst du den Grund für das Rundungsverhalten hier:

AutoIt

ConsoleWrite(StringFormat("%.16f\n", 500.33*0.5))
ConsoleWrite(StringFormat("%.16f\n", 5000.33*0.5))

Daher wird in (vernünftiger) Software welche mit Geldbeträgen umgeht auf keinen Fall eine Gleitkommazahl zur Speicherung der Werte verwendet sondern Festkommazahlen.
AutoIt hat so einen Typ zwar nicht aber da Festkommazahlen sich intern nicht anders als Integer verhalten, kann man stattdessen Integer verwenden.

Heißt konkret: Rechne statt in € alles in Cent (und achte zwischendurch darauf, dass nicht implizit mal in Float gewandelt wird) und lasse dir erst bei der Ausgabe daraus €-Beträge machen.
Konkret für dein Beispiel:

AutoIt

ConsoleWrite(Ceiling(50033/2)/100 & @CRLF)
ConsoleWrite(Ceiling(500033/2)/100 & @CRLF)

xbl38spezial

Wow, das ging wieder schnell. Danke ihr Beiden.
Mal schauen ob ich da durch steige