Struktur wird aus Pointer fehlerhaft befüllt

**BugFix**

Hi,
ich habe das Problem mal auf folgende Funktion reduziert, in der der Fehler entsteht.
Ich erstelle eine Struktur und befülle diese mit Werten. Die Struktur selbst wird als Pointer in einer anderen Struktur abgespeichert, ebenso der Struktur--String. Die Überprüfumg innerhalb der Funktion ist erfolgreich. Jedoch liefert dieselbe Überprüfung mit der zurückgegebenen Struktur fehlerhafte Werte. Jemand eine Idee warum?

AutoIt

$tRet = _SomeFunc()
$tRetTime = DllStructCreate($tRet.tagTime, $tRet.Time)
For $i = 1 To 6
	ConsoleWrite('Return ' & $i & ': ' & DllStructGetData($tRetTime, $i) & @CRLF)
Next


Func _SomeFunc()
	Local $tagTime = 'char Year[4];char Month[2];char Day[2];char Hour[2];char Min[2];char Sec[2]'
	Local $tTime = DllStructCreate($tagTime)
	DllStructSetData($tTime, 'Year',  @YEAR)
	DllStructSetData($tTime, 'Month', @MON)
	DllStructSetData($tTime, 'Day',   @MDAY)
	DllStructSetData($tTime, 'Hour',  @HOUR)
	DllStructSetData($tTime, 'Min',   @MIN)
	DllStructSetData($tTime, 'Sec',   @SEC)
	Local $t = DllStructCreate('struct;ptr Time;char tagTime[75];endstruct')
	DllStructSetData($t, 'Time', DllStructGetPtr($tTime))
	DllStructSetData($t, 'tagTime', $tagTime)


	; prüfen ob Struktur gefüllt und auslesbar
	Local $tCheck = DllStructCreate($t.tagTime, $t.Time)
	For $i = 1 To 6
		ConsoleWrite('Check Feld ' & $i & ': ' & DllStructGetData($tCheck, $i) & @CRLF)
	Next


	Return $t
EndFunc

Alles anzeigen

**minx**

Anmerkung nebenbei, das "." darf offensichtlich nicht verwendet werden: https://www.autoitscript.com/forum/topic/170435-i-managed-to-crash-scite-with-an-autoit-error-possible-error-in-struct-access/?do=findComment&comment=1246149

**BugFix**

Zitat von minx

das "." darf offensichtlich nicht verwendet werden:

Ist zwar unverständlich, wenn es in der Stable angeführt wird aber auch eine Verwendung von DllStructGetData statt dessen führt zum selben Fehler.

**minx**

Zitat von BugFix

Ist zwar unverständlich, wenn es in der Stable angeführt wird

Nicht? Ich finde das führt das Wort Stable doch etwas ad absurdum. Wollte es nur bemerkt haben, nicht das sich da noch mehr Fehler einschleichen

**AspirinJunkie**

Zitat von BugFix

Jedoch liefert dieselbe Überprüfung mit der zurückgegebenen Struktur fehlerhafte Werte.

Was meinst du exakt mit "fehlerhafte Werte"?
Die Ausgabe wirkt für mich nicht fehlerhaft:

Ausgabe mit v.3.3.12.0 sowohl x64 als auch x86

Code

Check Feld 1: 2015
Check Feld 2: 05
Check Feld 3: 26
Check Feld 4: 13
Check Feld 5: 46
Check Feld 6: 20
Return 1: 2015
Return 2: 05
Return 3: 26
Return 4: 13
Return 5: 46
Return 6: 20

Alles anzeigen

**BugFix**

Zitat von AspirinJunkie

Was meinst du exakt mit "fehlerhafte Werte"?

Ist ja krass, ich bekomme folgende Ausgabe (reproduzierbar):

Bash

Check Feld 1: 2015
Check Feld 2: 05
Check Feld 3: 26
Check Feld 4: 14
Check Feld 5: 03
Check Feld 6: 31
Return 1: y
Return 2: n
Return 3: 
Return 4: 
Return 5: 
Return 6: 31

Alles anzeigen

Ich verwende auch die 3.3.12.0

Yjuq

Also, der Fehler versteckt sich in Zeile 9. Du deklarierst dort eine LOKALE Variable. Der Speicherplatz wird ja normalerweise beim Beenden der Funktion wieder freigegeben. Da du aber mit einen Pointer arbeitest und auf den freigegebenen Speicherplatz verweist, kann es sein dass der Speicher bereits schon mit neuen Werten überschrieben wurde. Das ist auch der Grund warum der Code bei AspirinJunkie scheinbar funktioniert, er hatte nur Glück bei der Ausführung, dass die Werte in dem Speicherbereich noch nicht überschrieben wurde. Abhilfe schafft hier eine statische lokale oder globale Variable.

[autoit][/autoit][autoit][/autoit][autoit]

$tRet = _SomeFunc()
$tRetTime = DllStructCreate($tRet.tagTime, $tRet.Time)
For $i = 1 To 6
ConsoleWrite('Return ' & $i & ': ' & DllStructGetData($tRetTime, $i) & @CRLF)
Next

[/autoit][autoit][/autoit][autoit]

Func _SomeFunc()
Local $tagTime = 'char Year[4];char Month[2];char Day[2];char Hour[2];char Min[2];char Sec[2]'
Local Static $tTime = DllStructCreate($tagTime)
DllStructSetData($tTime, 'Year', @YEAR)
DllStructSetData($tTime, 'Month', @MON)
DllStructSetData($tTime, 'Day', @MDAY)
DllStructSetData($tTime, 'Hour', @HOUR)
DllStructSetData($tTime, 'Min', @MIN)
DllStructSetData($tTime, 'Sec', @SEC)
Local $t = DllStructCreate('struct;ptr Time;char tagTime[75];endstruct')
DllStructSetData($t, 'Time', DllStructGetPtr($tTime))
DllStructSetData($t, 'tagTime', $tagTime)

[/autoit][autoit][/autoit][autoit]

; prüfen ob Struktur gefüllt und auslesbar
Local $tCheck = DllStructCreate($t.tagTime, $t.Time)
For $i = 1 To 6
ConsoleWrite('Check Feld ' & $i & ': ' & DllStructGetData($tCheck, $i) & @CRLF)
Next

[/autoit][autoit][/autoit][autoit]

Return $t
EndFunc

[/autoit][autoit][/autoit][autoit][/autoit]

**BugFix**

Grr, ist ja eigentlich klar. Danke für die Erleuchtung.

**AspirinJunkie**

Yo das isses.

Zur Lösung würde ich zu HeapAlloc raten.
Musst halt nur sicherstellen, dass du den allokierten Speicher immer wieder selbst mit HeapFree freigeben musst um keine Speicherleichen zu produzieren.

Mal als Beispiel:

Spoiler anzeigen

AutoIt

Global Const $p_PROCHEAP = DllCall("kernel32.dll", "HANDLE", "GetProcessHeap")[0] ; Pointer zum Prozess-Heap


$tRet = _SomeFunc()
$tRetTime = DllStructCreate($tRet.tagTime, $tRet.Time)
For $i = 1 To 6
	ConsoleWrite('Return ' & $i & ': ' & DllStructGetData($tRetTime, $i) & @CRLF)
Next


; dynamisch allozierten speicher wieder freigeben (wichtig!):
DllCall("kernel32.dll", "BOOL", "HeapFree", "handle", $p_PROCHEAP, "DWORD", 1, "ptr", $tRet.Time)


Func _SomeFunc()
	Local $tagTime = 'char Year[4];char Month[2];char Day[2];char Hour[2];char Min[2];char Sec[2]'
	Local $pMem = DllCall("kernel32.dll", "ptr", "HeapAlloc", "HANDLE", $p_PROCHEAP, "DWORD", 0x1, "ulong_ptr", DllStructGetSize(DllStructCreate($tagTime)))[0]  ; Speicher dynamisch im Heap allokieren
	Local $tTime = DllStructCreate($tagTime, $pMem)
	DllStructSetData($tTime, 'Year',  @YEAR)
	DllStructSetData($tTime, 'Month', @MON)
	DllStructSetData($tTime, 'Day',   @MDAY)
	DllStructSetData($tTime, 'Hour',  @HOUR)
	DllStructSetData($tTime, 'Min',   @MIN)
	DllStructSetData($tTime, 'Sec',   @SEC)
	Local $t = DllStructCreate('struct;ptr Time;char tagTime[75];endstruct')
	DllStructSetData($t, 'Time', $pMem)
	DllStructSetData($t, 'tagTime', $tagTime)


	; prüfen ob Struktur gefüllt und auslesbar
	Local $tCheck = DllStructCreate($t.tagTime, $t.Time)
	For $i = 1 To 6
		ConsoleWrite('Check Feld ' & $i & ': ' & DllStructGetData($tCheck, $i) & @CRLF)
	Next


	Return $t
EndFunc

Alles anzeigen

**BugFix**

Zitat von AspirinJunkie

Zur Lösung würde ich zu HeapAlloc raten.

Ist mit Sicherheit die sauberste Lösung. Für den von mir gewollten Zweck werde ich aber auf Local Static zurückgreifen. Zum Einen wird die Struktur u.U. mehrfach hintereinander genutzt und zum Anderen muß der User dann nicht dran denken den Speicher freizugeben.

Danke noch mal.

**bernd670**

Hallo,

du weißt aber schon das du so nur eine Zeitangabe speichern kannst?

AutoIt

$tRet1 = _SomeFunc()
Sleep(5000)
$tRet2 = _SomeFunc()


$tRetTime1 = DllStructCreate($tRet1.tagTime, $tRet1.Time)
$tRetTime2 = DllStructCreate($tRet2.tagTime, $tRet2.Time)


For $i = 1 To 6
	ConsoleWrite('Return1 ' & $i & ': ' & DllStructGetData($tRetTime1, $i) & @CRLF)
	ConsoleWrite('Return2 ' & $i & ': ' & DllStructGetData($tRetTime2, $i) & @CRLF)
Next


Func _SomeFunc()
	Local $tagTime = 'char Year[4];char Month[2];char Day[2];char Hour[2];char Min[2];char Sec[2]'
	Local Static $tTime = DllStructCreate($tagTime)
	DllStructSetData($tTime, 'Year',  @YEAR)
	DllStructSetData($tTime, 'Month', @MON)
	DllStructSetData($tTime, 'Day',   @MDAY)
	DllStructSetData($tTime, 'Hour',  @HOUR)
	DllStructSetData($tTime, 'Min',   @MIN)
	DllStructSetData($tTime, 'Sec',   @SEC)
	Local $t = DllStructCreate('struct;ptr Time;char tagTime[75];endstruct')
	DllStructSetData($t, 'Time', DllStructGetPtr($tTime))
	DllStructSetData($t, 'tagTime', $tagTime)
	; prüfen ob Struktur gefüllt und auslesbar
	Local $tCheck = DllStructCreate($t.tagTime, $t.Time)
	For $i = 1 To 6
		ConsoleWrite('Check Feld ' & $i & ': ' & DllStructGetData($tCheck, $i) & @CRLF)
	Next
	Return $t
EndFunc

Alles anzeigen

Im obigen Beispiel sollte ja die Differenz zwischen Ret1 und Ret2 5 Sekunden betragen. Wie du aber in der Ausgabe siehst wird immer nur der letzte Zeitwert ausgeben, das liegt daran das du ja immer in den gleichen Speicherbereich schreibst.

**BugFix**

Zitat von bernd670

du weißt aber schon das du so nur eine Zeitangabe speichern kannst?

Ja, das ist auch das Ziel.