Child Window& GUICTRL

rallemeister

Hallo,

ich habe hier ein Script in dem ein Child Window erstellt wird. Hat jemand einen Ansatz, warum die Input Felder nicht aktiviert sind??

Danke im voraus

C

#include <Array.au3>
#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>


Global $gDatenbankMain,$OpenDatabase


Opt("GUIOnEventMode", 1)
#Region
$gMain = GUICreate("Diluma Formular Builder V 1.0", @DesktopWidth-20, @DesktopHeight-100, 0, 0, BitOR($WS_MAXIMIZEBOX,$WS_MINIMIZEBOX,$WS_SIZEBOX,$WS_THICKFRAME,$WS_SYSMENU,$WS_CAPTION,$WS_OVERLAPPEDWINDOW,$WS_TILEDWINDOW,$WS_POPUP,$WS_POPUPWINDOW,$WS_GROUP,$WS_TABSTOP,$WS_BORDER,$WS_CLIPSIBLINGS))
GUISetOnEvent($GUI_EVENT_CLOSE, "wClose")
$mFile = GUICtrlCreateMenu("&Datei")
$mDateiOeffnen = GUICtrlCreateMenuItem("&öffnen"  , $mFile)
$mDateiSpeichern = GUICtrlCreateMenuItem("&speichern"  , $mFile)
$mDateiExit = GUICtrlCreateMenuItem("&Exit" & @TAB & "         Esc", $mFile)
GUICtrlSetOnEvent(-1, "wClose")


$mFile2 = GUICtrlCreateMenu("&Datenbank")
$mDatenbankOeffnen = GUICtrlCreateMenuItem("&Anbindung setzen"  , $mFile2)
GUICtrlSetOnEvent(-1, "DatenbankOeffnen")


GUISetState(@SW_SHOW)
#EndRegion




while 1




WEnd


Func DatenbankOeffnen()
		if $OpenDatabase=1 then Return
		$gDatenbankMain = GUICreate("Datenbank Anbindung", 363, 123, 0, 0,BitOR($WS_CAPTION,$WS_CHILD,$WS_MINIMIZEBOX,$WS_SYSMENU), "", $gMain)
		GUISetOnEvent($GUI_EVENT_CLOSE, "wClose")
		$gHost = GUICtrlCreateInput("", 96, 8, 249, 21)
		$gDatenbank = GUICtrlCreateInput("", 96, 34, 121, 21)
		$gBenutzer = GUICtrlCreateInput("", 96, 60, 121, 21)
		$gPasswort = GUICtrlCreateInput("", 96, 86, 121, 21)
		$g1Label1 = GUICtrlCreateLabel("Host", 16, 10, 26, 17)
		$g1Label2 = GUICtrlCreateLabel("Datenbank", 16, 34, 57, 17)
		$g1Label3 = GUICtrlCreateLabel("Benutzername", 16, 60, 72, 17)
		$g1Label4 = GUICtrlCreateLabel("Passwort", 16, 88, 47, 17)
		$gBTestDatabase = GUICtrlCreateButton("Test", 232, 32, 113, 25)
		$gBSpeicherDatenbank = GUICtrlCreateButton("speichern", 232, 64, 113, 41)
		GUISetState(@SW_SHOW, $gDatenbankMain)
		Global $OpenDatabase=1
EndFunc




Func wClose()
	Switch @GUI_WINHANDLE ; See which GUI sent the CLOSE message
		Case $gMain
			Exit
		Case $gDatenbankMain
			GUIDelete($gDatenbankMain)
			Global $OpenDatabase=0
		EndSwitch


EndFunc

Alles anzeigen

**BugFix**

Das Main-Window hat einen sehr seltsamen Style-Mix. Einige dieser Styles widersprechen sich selbst (z.B. POPUP und CAPTION).
Erstelle also das Main erst mal mit gültigem Style, vielleicht ist dein Problem dann schon gelöst.

rallemeister

Zitat von BugFix

Das Main-Window hat einen sehr seltsamen Style-Mix. Einige dieser Styles widersprechen sich selbst (z.B. POPUP und CAPTION).
Erstelle also das Main erst mal mit gültigem Style, vielleicht ist dein Problem dann schon gelöst.

Ich habe einfach mal alle nicht wichtigen enfernt, da diese Parameterisierenungen "geklaut" waren. Ergebniss bleibt das Gleiche! Ich glaube, das Fenster wird einfach nicht richtig als "aktiviert" markiert.

C

#include <Array.au3>
#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>


Global $gDatenbankMain,$OpenDatabase


Opt("GUIOnEventMode", 1)
#Region
$gMain = GUICreate("Diluma Formular Builder V 1.0", @DesktopWidth-20, @DesktopHeight-100, 0, 0)
GUISetOnEvent($GUI_EVENT_CLOSE, "wClose")
$mFile = GUICtrlCreateMenu("&Datei")
$mDateiOeffnen = GUICtrlCreateMenuItem("&öffnen"  , $mFile)
$mDateiSpeichern = GUICtrlCreateMenuItem("&speichern"  , $mFile)
$mDateiExit = GUICtrlCreateMenuItem("&Exit" & @TAB & "         Esc", $mFile)
GUICtrlSetOnEvent(-1, "wClose")


$mFile2 = GUICtrlCreateMenu("&Datenbank")
$mDatenbankOeffnen = GUICtrlCreateMenuItem("&Anbindung setzen"  , $mFile2)
GUICtrlSetOnEvent(-1, "DatenbankOeffnen")


GUISetState(@SW_SHOW)
#EndRegion




while 1




WEnd


Func DatenbankOeffnen()
		if $OpenDatabase=1 then Return
		$gDatenbankMain = GUICreate("Datenbank Anbindung", 363, 123, 0, 0,BitOR($WS_CAPTION,$WS_CHILD,$WS_MINIMIZEBOX,$WS_SYSMENU), "", $gMain)
		GUISetOnEvent($GUI_EVENT_CLOSE, "wClose")
		$gHost = GUICtrlCreateInput("", 96, 8, 249, 21)
		$gDatenbank = GUICtrlCreateInput("", 96, 34, 121, 21)
		$gBenutzer = GUICtrlCreateInput("", 96, 60, 121, 21)
		$gPasswort = GUICtrlCreateInput("", 96, 86, 121, 21)
		$g1Label1 = GUICtrlCreateLabel("Host", 16, 10, 26, 17)
		$g1Label2 = GUICtrlCreateLabel("Datenbank", 16, 34, 57, 17)
		$g1Label3 = GUICtrlCreateLabel("Benutzername", 16, 60, 72, 17)
		$g1Label4 = GUICtrlCreateLabel("Passwort", 16, 88, 47, 17)
		$gBTestDatabase = GUICtrlCreateButton("Test", 232, 32, 113, 25)
		$gBSpeicherDatenbank = GUICtrlCreateButton("speichern", 232, 64, 113, 41)
		GUISetState(@SW_SHOW, $gDatenbankMain)








		Global $OpenDatabase=1
EndFunc




Func wClose()
	Switch @GUI_WINHANDLE ; See which GUI sent the CLOSE message
		Case $gMain
			Exit
		Case $gDatenbankMain
			GUIDelete($gDatenbankMain)
			Global $OpenDatabase=0
		EndSwitch


EndFunc

Alles anzeigen

**bernd670**

Hallo,

lass $WS_CHILD weg und schon gehts!

rallemeister

Hallo Bernd.

dass hatte ich auch schon herausgefunden, aber dann ist es nicht mehr an das Hauptfenster gebunden... Darum ging es ja...

Gruß
Ralf

**BugFix**

Zitat von rallemeister

dass hatte ich auch schon herausgefunden, aber dann ist es nicht mehr an das Hauptfenster gebunden... Darum ging es ja...

Verwende WS_EX_MDICHILD und erstelle die GUI am Anfang und nicht bei jedem Aufruf neu:

AutoIt

Global $gDatenbankMain, $OpenDatabase = 0


Opt("GUIOnEventMode", 1)
#Region
$gMain = GUICreate("Diluma Formular Builder V 1.0", @DesktopWidth-20, @DesktopHeight-100, -1, -1, Default, $GUI_WS_EX_PARENTDRAG)
GUISetOnEvent($GUI_EVENT_CLOSE, "wClose")
$mFile = GUICtrlCreateMenu("&Datei")
$mDateiOeffnen = GUICtrlCreateMenuItem("&öffnen"  , $mFile)
$mDateiSpeichern = GUICtrlCreateMenuItem("&speichern"  , $mFile)
$mDateiExit = GUICtrlCreateMenuItem("&Exit" & @TAB & "         Esc", $mFile)
GUICtrlSetOnEvent(-1, "wClose")
$mFile2 = GUICtrlCreateMenu("&Datenbank")
$mDatenbankOeffnen = GUICtrlCreateMenuItem("&Anbindung setzen"  , $mFile2)
GUICtrlSetOnEvent(-1, "DatenbankOeffnen")


; Child
$gDatenbankMain = GUICreate("Datenbank Anbindung", 363, 123, 0, 0,BitOR($WS_CAPTION,$WS_MINIMIZEBOX,$WS_SYSMENU), $WS_EX_MDICHILD, $gMain)
GUISetOnEvent($GUI_EVENT_CLOSE, "wClose")
$gHost = GUICtrlCreateInput("", 96, 8, 249, 21)
$gDatenbank = GUICtrlCreateInput("", 96, 34, 121, 21)
$gBenutzer = GUICtrlCreateInput("", 96, 60, 121, 21)
$gPasswort = GUICtrlCreateInput("", 96, 86, 121, 21)
$g1Label1 = GUICtrlCreateLabel("Host", 16, 10, 26, 17)
$g1Label2 = GUICtrlCreateLabel("Datenbank", 16, 34, 57, 17)
$g1Label3 = GUICtrlCreateLabel("Benutzername", 16, 60, 72, 17)
$g1Label4 = GUICtrlCreateLabel("Passwort", 16, 88, 47, 17)
$gBTestDatabase = GUICtrlCreateButton("Test", 232, 32, 113, 25)
$gBSpeicherDatenbank = GUICtrlCreateButton("speichern", 232, 64, 113, 41)


GUISetState(@SW_SHOW, $gMain)
#EndRegion




while 1
	Sleep(50)
WEnd


Func DatenbankOeffnen()
		If $OpenDatabase = 1 Then Return
		GUISetState(@SW_HIDE, $gMain)
		GUISetState(@SW_SHOW, $gDatenbankMain)
		$OpenDatabase = 1
EndFunc




Func wClose()
	Switch @GUI_WINHANDLE ; See which GUI sent the CLOSE message
		Case $gMain
			Exit
		Case $gDatenbankMain
			GUISetState(@SW_HIDE, $gDatenbankMain)
			GUISetState(@SW_SHOW, $gMain)
			$OpenDatabase = 0
	EndSwitch
EndFunc

Alles anzeigen