Tree-View aus einer Textdatei auslesen

TheDeath24

Hallo,

ich bräuchte Hilfe bei auslesen einer Textdatei. Die Textdatei ist zum ersten sehr groß (1.8MB) und zum anderen weis ich leider nicht genau wie ich das anstellen soll genau diese Struktur aus der Datei auszulesen.

Einteil Auszug aus der Datei.

Grün = Varbiable die beim anklicken in dem Tree-View zum passenden Text ausgelesen wird.
Rot = Text in dem Tree-View

Struktur:

Techn. Platz DE02 Gültig ab 27.05.15
Bezeichnung Test
DE02 Test
|
|-- DE02-CCP Processing
| |
| |-- DE02-CCP-010 Processing allgemein
| | |
| | |-- DE02-CCP-010-010 ALLGEMEIN
| | | |
| | | |--- DE02-CCP-010-010-010 WAENDE, DECKEN, FUSSBOEDEN / CCP
| | | |--- DE02-CCP-010-010-020 KALT- UND WARMWASSER-LEITUNGEN / FC
| | | |--- DE02-CCP-010-010-030 SCHMUTZWASSER-LEITUNGEN / FC
| | | |--- DE02-CCP-010-010-040 REGENWASSER-LEITUNGEN / FC
| | | |--- DE02-CCP-010-010-050 DAMPF-LEITUNGEN / FC
| | | |--- DE02-CCP-010-010-060 KONDENSAT-LEITUNGEN / FC
| | | |-- DE02-CCP-010-010-070 PRESSLUFT-LEITUNGEN / FC
| | | | |
| | | | |-- 5269116 CPS Druckluft-Sterilfilter SMF 05/25,UF1 1 ST
| | | | |
| | | | |--- 79712744 ULTRAFILTERELEMENT SMF05/25 L 2 ST
| | | |
| | | |--- DE02-CCP-010-010-080 PRODUKTLEITUNGEN / FC
| | | |--- DE02-CCP-010-010-090 CO2 LEITUNGEN / FC
| | | |--- DE02-CCP-010-010-100 N2 LEITUNGEN / FC
| | | |--- DE02-CCP-010-010-110 LEITERN / FC
| | | |-- DE02-CCP-010-010-120 HOLAC-VIELZWECKSCHNEIDER
| | | | |
| | | | |--- 5269147 CPS HOLAC-VIELZWECKSCHNEIDER 1 ST
| | | |
| | | |--- DE02-CCP-010-010-130 Nauter Mischer T460
| | | |--- DE02-CCP-010-010-140 Pufferbehalter T 461
| | | |-- DE02-CCP-010-010-145 Sauger BQ690 WAP Alto Typ22

**Kanashius**

Für mich sieht die Struktur deiner Textdatei aber eher nach einer TreeView aus... Listview ist eigentlich nur ne Tabelle. Bäume (Trees) sind eher selten für ListViews.
Und ansonsten:
FileReadLine()
Dann kannst du ja die anzahl der | und --- zählen (stringinstr(),...) und dann passend splitten.
Struktur ist ja immer: (| )[0,*](-)[0,*]( )[0,1](DE...)( )(Text)
Sollte mit RegExp auch gut lösbar sein
(Falls sich bis heut abend keiner gefunden hat, werd ichs mir genauer ansehen. Jetzt muss ich erstmal off.)

TheDeath24

Ups da hast du recht. Habe mich vertan. Ja ich meine auch eine TreeView. Sorry

**Kanashius**

Habs fertiggeschrieben.

AutoIt

$Textdatei="TheDeath24_TreeViewText.txt"


$gGui=GUICreate("",400,400)
$hTreeView=GUICtrlCreateTreeView(5,5,390,390)
$FirstControl=$hTreeView
GUISetState()
$aTreeArray=_readFileToArray($Textdatei)
for $i=0 to UBound($aTreeArray)-1 step 1
	$i=_addTreeViewItem($aTreeArray,$i,$hTreeView)
next
$LastControl=$FirstControl+UBound($aTreeArray)


while 1
	$msg=GUIGetMsg()
	if $msg>$FirstControl and $msg<$LastControl+1 then
		msgbox(48,"",$aTreeArray[$msg-$FirstControl-1][1])
	endif
	if $msg=-3 then
		exit
	endif
WEnd


Func _readFileToArray($file)
	local $array[10][3],$count=0
	$file=FileOpen($file,0)
	if @error then
		MsgBox(16,"Error","Die Datei "&$file&" konnte nicht geöffnet werden!")
		exit
	endif
	While 1
		local $line=FileReadLine($file)
		If @error=-1 then
			ExitLoop
		ElseIf @error then
			MsgBox(16,"Error","Die Datei "&$file&" konnte nicht geöffnet werden!")
			exit
		Endif
		if $line<>"" then
			local $ar=StringSplit($line,"|",1+2)
			if $ar[UBound($ar)-1]<>"" or $ar[UBound($ar)-1]<>"" then
				if $count>UBound($array)-1 then
					ReDim $array[$count+10][3]
				endif
				local $rows=StringSplit($ar[UBound($ar)-1]," ",1+2)
				local $row2=""
				local $tmp=StringRegExp($rows[0],"-{1,}")?2:1
				for $i=$tmp to UBound($rows)-1 step 1
					$row2&=$rows[$i]
					if $i<>UBound($rows)-1 then
						$row2&=" "
					endif
				next
				$array[$count][0]=UBound($ar)-1
				$array[$count][1]=StringRegExp($rows[0],"-{1,}")?$rows[1]:$rows[0]
				$array[$count][2]=$row2
				$count+=1
			endif
		endif
	WEnd
	ReDim $array[$count][3]
	return $array
EndFunc


Func _addTreeViewItem(ByRef $list,$aktNumber,$ctrlId)
	local $thisNumber=$aktNumber
	local $newCtrlID=GUICtrlCreateTreeViewItem($list[$aktNumber][2],$ctrlId)
	if $aktNumber+1>UBound($list)-1 then
		return $aktNumber
	endif
	if $list[$aktNumber+1][0]>$list[$thisNumber][0] then
		$aktNumber=_addTreeViewItem($list,$aktNumber+1,$newCtrlID)
	ElseIf $list[$aktNumber+1][0]=$list[$thisNumber][0] then
		$aktNumber=_addTreeViewItem($list,$aktNumber+1,$ctrlId)
	endif
	if $aktNumber+1>UBound($list)-1 then
		return $aktNumber
	endif
	While $list[$aktNumber+1][0]>$list[$thisNumber][0]
		$aktNumber=_addTreeViewItem($list,$aktNumber+1,$newCtrlID)
		if $aktNumber+1>UBound($list)-1 then
			return $aktNumber
		endif
	WEnd
	Return $aktNumber
EndFunc

Alles anzeigen

Falls du möchtest kannst du das auswerten der TreeView ja noch verbessern (mit dem Klick). Hatte grad nicht mehr die Motivation das mit WM_Notifity,... umzusetzen.
An deinem Beispiel funktioniert es. Ich hoffe, so war es gemeint.
Mit freundlichen Grüßen, Kanashius

TheDeath24

Hi,

erstmal vielen Dank für die Mühe. Doch leider kommen dort Sachen durcheinander. Das heißt es sind dort Teile zu finden die nicht in diese Struktur gehören sondern unter einem anderen Punkt.

Ich habe hier nochmal ein Teilausschnitt mit angehängt.

Leider darf ich die gesamte Datei nicht hochladen.

**BugFix**

Vielleicht hilft dir das weiter.

**Kanashius**

Ich habs umgeändert.
Allgemein:
1. Wenn du in Zukunft sowas postest, häng bitte direkt eine txt dran, so wie es sein soll. Mit den Daten, die du oben gepostet hattest funktionierte es Perfekt. (hatte die Daten Copy&Paste in eine Txt geschrieben).
Es ist gerade beim Text-Parsen wichtig, alles exakt so anzugeben, wie es ist. Jedes Zeichen zählt da. Wenn da 1 Leerzeichen zu viel ist kann es schon Fehler geben. Teilweise auch durch unsichtbare Zeichen, wie Zeilenumbrüche.
So musste ich doppelt arbeiten -.-
2.Wenn du ein fertiges Script haben möchtest, und nicht eigenen Quellcode lieferst, wo du nur nicht weiterkommst, oder wenn du nicht nur eine Anregung/Idee brauchst, dann Poste bitte deine Anfrage in die Unterkategorie Programmieranfragen mit/ohne Gegenleistung.

Hier das Script, wie es für die von dir gepostete Txt funktioniert:

AutoIt

#include <array.au3>
;$Textdatei="TheDeath24_TreeViewText.txt"
$Textdatei="Teilausschnitt.txt"


$gGui=GUICreate("",400,400)
$hTreeView=GUICtrlCreateTreeView(5,5,390,390)
$FirstControl=$hTreeView
GUISetState()
$aTreeArray=_readFileToArray($Textdatei)
for $i=0 to UBound($aTreeArray)-1 step 1
	$i=_addTreeViewItem($aTreeArray,$i,$hTreeView)
next
$LastControl=$FirstControl+UBound($aTreeArray)


while 1
	$msg=GUIGetMsg()
	if $msg>$FirstControl and $msg<$LastControl+1 then
		msgbox(48,"",$aTreeArray[$msg-$FirstControl-1][1])
	endif
	if $msg=-3 then
		exit
	endif
WEnd


Func _readFileToArray($file)
	local $array[10][3],$count=0
	$file=FileOpen($file,0)
	if @error then
		MsgBox(16,"Error","Die Datei "&$file&" konnte nicht geöffnet werden!")
		exit
	endif
	While 1
		local $line=FileReadLine($file)
		If @error=-1 then
			ExitLoop
		ElseIf @error then
			MsgBox(16,"Error","Die Datei "&$file&" konnte nicht geöffnet werden!")
			exit
		Endif
		if $line="" then
			ExitLoop
		endif
	WEnd
	While 1
		local $line=FileReadLine($file)
		If @error=-1 then
			ExitLoop
		ElseIf @error then
			MsgBox(16,"Error","Die Datei "&$file&" konnte nicht geöffnet werden!")
			exit
		Endif
		if $line<>"" then
			$line=_checkEbene($line)
			local $ar=StringSplit($line,"|",1+2)
			if $ar[UBound($ar)-1]<>"" or $ar[UBound($ar)-1]<>"" then
				if $count>UBound($array)-1 then
					ReDim $array[$count+10][3]
				endif
				$ar[UBound($ar)-1]=StringReplace($ar[UBound($ar)-1],@crlf,"")
				local $rows=StringSplit($ar[UBound($ar)-1]," ",1+2)
				local $row2=""
				local $tmp=StringRegExp($rows[0],"-{1,}")?2:1
				local $start=0
				;_ArrayDisplay($rows)
				for $i=$tmp to UBound($rows)-1 step 1
					if $rows[$i]="" then
						$start+=1
					else
						ExitLoop
					endif
				next
				;MsgBox(48,"",$start)
				for $i=$tmp+$start+1 to UBound($rows)-1 step 1
					if $rows[$i]<>"" then
						$row2&=$rows[$i]
						if $i<>UBound($rows)-1 then
							$row2&=" "
						endif
					endif
				next
				$array[$count][0]=UBound($ar)-1
				$array[$count][1]=$rows[$start+$tmp]
				$array[$count][2]=$row2
				$count+=1
			endif
		endif
	WEnd
	ReDim $array[$count][3]
	return $array
EndFunc


Func _checkEbene($line)
	local $ar=StringSplit($line,"|",1+2)
	for $i=0 to UBound($ar)-2 step 1
		$ar[$i]=StringReplace($ar[$i],"    ","|   ")
	next
	local $string=""
	for $i=0 to UBound($ar)-1 step 1
		$string&=$ar[$i]
		if $i<>UBound($ar)-1 then
			$string&="|"
		endif
	next
	return $string
EndFunc


Func _addTreeViewItem(ByRef $list,$aktNumber,$ctrlId)
	local $thisNumber=$aktNumber
	local $newCtrlID=GUICtrlCreateTreeViewItem($list[$aktNumber][2],$ctrlId)
	if $aktNumber+1>UBound($list)-1 then
		return $aktNumber
	endif
	if $list[$aktNumber+1][0]>$list[$thisNumber][0] then
		$aktNumber=_addTreeViewItem($list,$aktNumber+1,$newCtrlID)
	ElseIf $list[$aktNumber+1][0]=$list[$thisNumber][0] then
		$aktNumber=_addTreeViewItem($list,$aktNumber+1,$ctrlId)
	endif
	if $aktNumber+1>UBound($list)-1 then
		return $aktNumber
	endif
	While $list[$aktNumber+1][0]>$list[$thisNumber][0]
		$aktNumber=_addTreeViewItem($list,$aktNumber+1,$newCtrlID)
		if $aktNumber+1>UBound($list)-1 then
			return $aktNumber
		endif
	WEnd
	Return $aktNumber
EndFunc

Alles anzeigen

MfG Kanashius