RegEx?

Fr34k.

Hi zusammen, ich hoffe jemand kann mir sagen wie das ganze funktioniert. Von einem Source Code brauche ich mehrere Informationen.

Dieser Code steht auf drei verschiedenen Zeilen. Ich würde gerne die ID (6543) der angezeigt Namen (Test (12-34)) und der Preis 12154 zurückbekommen. Wie kann ich dies mit AutoIt und Regex lösen?
Teilweise ist dieser Code bis zu 1000 mal auf der Webseite vorhanden.

Bisher habe ich es mit einer eigenen SearchAndCut Funktion gelöst (Weiter unten), jedoch dauert das auslesen so bis zu einer Minute..

Gruss

AutoIt: SearchAndCut

Func SearchAndCut($string1, $string2, $string3, $string4, $string5)
	$tempPos1 = ''
	$tempPos2 = ''
	$tempPos3 = ''
	$tempPos4 = ''
	$tempPosEnd = ''
	$source = _IEDocReadHTML($oIE)
	If $string3 = '' And $string4 = '' And $string5 = '' Then
		$tempPos1 = StringInStr($source, $string1)
		$tempPosEnd = StringInStr($source, $string2, 0, 1, $tempPos1+StringLen($string1))
		$ReturnString = StringMid($source, $tempPos1+StringLen($string1), $tempPosEnd-($tempPos1+StringLen($string1)))
	ElseIf $string4 = '' And $string5 = '' Then
		$tempPos1 = StringInStr($source, $string1)
		$tempPos2 = StringInStr($source, $string2, 0, 1, $tempPos1)
		$tempPosEnd = StringInStr($source, $string3, 0, 1, $tempPos2+StringLen($string2))
		$ReturnString = StringMid($source, $tempPos2+StringLen($string2), $tempPosEnd-($tempPos2+StringLen($string2)))
	ElseIf $string5 = '' Then
		$tempPos1 = StringInStr($source, $string1)
		$tempPos2 = StringInStr($source, $string2, 0, 1, $tempPos1+StringLen($string1))
		$tempPos3 = StringInStr($source, $string3, 0, 1, $tempPos2+StringLen($string2))
		$tempPosEnd = StringInStr($source, $string4, 0, 1, $tempPos3+StringLen($string3))
		$ReturnString = StringMid($source, $tempPos3+StringLen($string3), $tempPosEnd-($tempPos3+StringLen($string3)))
	Else
		$tempPos1 = StringInStr($source, $string1)
		$tempPos2 = StringInStr($source, $string2, 0, 1, $tempPos1+StringLen($string1))
		$tempPos3 = StringInStr($source, $string3, 0, 1, $tempPos2+StringLen($string2))
		$tempPos4 = StringInStr($source, $string4, 0, 1, $tempPos3+StringLen($string3))
		$tempPosEnd = StringInStr($source, $string5, 0, 1, $tempPos4+StringLen($string4))
		$ReturnString = StringMid($source, $tempPos4+StringLen($string4), $tempPosEnd-($tempPos4+StringLen($string4)))
	EndIf


	Return $ReturnString
EndFunc

Alles anzeigen

Die SearchAndCut Funktion kann so mit mehreren Parametern aufgerufen werden..

**UEZ**

Probiere es mal damit:

Code

#include <Array.au3>


$sHTML = '<td><a href="index.php?id=6543&screen=view">Test (12-34)</a></td>' & @CRLF & _
		 "<td>12154</td>" & @CRLF & _
		 "<td>asdf</td>" & @CRLF & _
		 '<td><a href="index.php?id=6544&screen=view">Test (33-44)</a></td>' & @CRLF & _
		 "<td>95142</td>" & @CRLF & _
		 "<td>asdf</td>"


$aPreis = StringRegExp($sHTML, "(?m)<td>(\d+)<\/td>", 3)
$aNamen = StringRegExp($sHTML, '(?m)view">(.+)<\/a', 3)
For $i = 0 To UBound($aPreis) - 1
	ConsoleWrite($aNamen[$i] & @TAB & $aPreis[$i] & " €" & @CRLF)
Next

Alles anzeigen

Annahme: Name und Preis sind synchron.

**AspirinJunkie**

Da wir die kompletten Daten nicht kennen (um welche Seite handelt es sich denn?) kann man das Pattern lediglich auf das Beispiel hin basteln:

AutoIt

#include <Array.au3>
$s_String = '<td><a href="index.php?id=6543&screen=view">Test (12-34)</a></td>' & @CRLF & '<td>12154</td>' & "<td>asdf</td>"


For $Match in StringRegExp($s_String, '(?s)<td><a\shref="index\.php\?id=(\d+).*?>([^<]+)<.+?<td>(\d+)', 4)
	_ArrayDisplay($Match)
Next

Fr34k.

Bringe beide eure Lösungen nicht zum laufen..?

Hier mal ein Auszug, leider ist es ein geschützter Bereich welcher nur für Mitglieder sichtbar ist..

HTML

<tr class="nowrap row_a">
		<td><a href="index.php?id=5277&amp;screen=view">Art1(12-31)</a></td>
		<td>499</td>
		<td>Beschreibung</td>
		<td>Dies ist eine Beschreibung</td>
	</tr>
	<tr class="nowrap row_b">
		<td><a href="index.php?id=5278&amp;screen=view">Art2 (40-483)</a></td>
		<td>899</td>
		<td>Beschreibung</td>
		<td>Lalala</td>
	</tr>
	<tr class="nowrap row_a">
		<td><a href="index.php?id=5280&amp;screen=view">Art3 (399-486)</a></td>
		<td>19999</td>
		<td>Beschreibung</td>
		<td>Bablaldfhusdfwe</td>
	</tr>

Alles anzeigen

Schon mal grosses Dankeschön im vorraus!

Greetz

Edit:
Sorry, AspirinJunkie, deine Lösung ist perfekt!
Vielen Dank dafür

**UEZ**

Dieser Code

AutoIt

#include <Array.au3>


$sHTML = '<tr class="nowrap row_a">' & @CRLF & _
		'<td><a href="index.php?id=5277&amp;screen=view">Art1(12-31)</a></td>' & @CRLF & _
		'<td>499</td>' & @CRLF & _
		'<td>Beschreibung</td>' & @CRLF & _
		'<td>Dies ist eine Beschreibung</td>' & @CRLF & _
	'</tr>' & @CRLF & _
	'<tr class="nowrap row_b">' & @CRLF & _
		'<td><a href="index.php?id=5278&amp;screen=overview">Art2 (40-483)</a></td>' & @CRLF & _
		'<td>899</td>' & @CRLF & _
		'<td>Beschreibung</td>' & @CRLF & _
		'<td>Lalala</td>' & @CRLF & _
	'</tr>' & @CRLF & _
	'<tr class="nowrap row_a">' & @CRLF & _
		'<td><a href="index.php?id=5280&amp;screen=view">Art3 (399-486)</a></td>' & @CRLF & _
		'<td>19999</td>' & @CRLF & _
		'<td>Beschreibung</td>' & @CRLF & _
		'<td>Bablaldfhusdfwe</td>' & @CRLF & _
	'</tr>'


$aPreis = StringRegExp($sHTML, "(?m)<td>(\d+)<\/td>", 3)
$aNamen = StringRegExp($sHTML, '(?m)view">(.+)<\/a', 3)
$aID = StringRegExp($sHTML, '(?m)\?id=(\d+)\&', 3)
For $i = 0 To UBound($aPreis) - 1
	ConsoleWrite($aNamen[$i] & @TAB & $aID[$i] & @TAB & $aPreis[$i] & " €" & @CRLF)
Next

Alles anzeigen

produziert folgendes Ergebnis:

Code

Art1(12-31)	5277	499 €
Art2 (40-483)	5278	899 €
Art3 (399-486)	5280	19999 €

Dieses Resultat willst du doch oder?

Fr34k.

Siehe mein anderen Post
Ein andere Frage hätte ich jedoch noch.. Ich habe die Lösung von AspirinJunkie verwendet, verstehe den RegEx jedoch nur halb..

Wenn der Quellcode so aussieht:

HTML

<tr class="nowrap row_a">
		<td><a href="index.php?id=5277&amp;screen=view">Art1(12-31)</a></td>
		<td>499</td>
		<td>Beschreibung</td>
		<td>Dies ist eine Beschreibung</td>
		<td>1/23</td>
	</tr>
	<tr class="nowrap row_b">
		<td><a href="index.php?id=5278&amp;screen=view">Art2 (40-483)</a></td>
		<td>899</td>
		<td>Beschreibung</td>
		<td>Lalala</td>
		<td>999/1000</td>
	</tr>
	<tr class="nowrap row_a">
		<td><a href="index.php?id=5280&amp;screen=view">Art3 (399-486)</a></td>
		<td>19999</td>
		<td>Beschreibung</td>
		<td>Bablaldfhusdfwe</td>
		<td>5/26</td>
	</tr>

Alles anzeigen

Und ich noch die Anzahl Artikel auslesen will (1/23, 99/1000 & 5/26), also beide Zahlen, wie müsste der RegEx aussehen? Habe es so probiert, funktioniert jedoch nicht..

AutoIt

For $Tmp in StringRegExp($source, '(?s)<td><a\shref="index\.php\?id=(\d+).*?>([^<]+)<.+?<td>(\d+)<\/td><td>.*<\/td><td>.*<\/td><td>(.*)<\/td>', 4)
		_ArrayDisplay($Tmp)
	Next

Danke für die Hilfe!

Gruss

**bernd670**

Hallo,

so sollte es gehen!

AutoIt

StringRegExp($source, '(?s)<td><a\shref="index\.php\?id=(\d+).*?>([^<]+)<.+?<td>(\d+)<\/td>.*?<td>(\d+\/\d+)<\/td>', 4)

**AspirinJunkie**

Wenn die Anzahl der Spalten fest ist, musst du eigentlich nur noch die beiden Spalten dazwischen auslassen.
Du hast jedoch .* verwendet. In dem Moment wird er solange im String weitersuchen bis er das letzte <td gefunden hat, denn .* ist gierig - es will soviel wie möglich sammeln.
Deswegen hilft .*?. Dann sucht er nur bis zum ersten <td.

Das erweiterte Pattern könnte daher so aussehen:

Code

(?s)<td><a href=".+?\?id=(\d+).*?>([^<]+)<.+?<td>(\d+).+?<td.+?<td.+?<td>([^<])+

Aber: Das wird mit dem Verständnis dann immer komplizierter.
Und spätestens in einem Jahr, wenn du das wieder anpassen willst, weißt du nicht mehr was hier eigentlich passiert.
Daher wäre eine intuitivere Methode sicherlich die bessere Wahl als ein solches RegEx-Ungetüm.

Hier daher mal ein Beispiel wie man an die Daten gelangt in dem man den XML-String schrittweise über CSS-Selektoren zerlegt:

Spoiler anzeigen

AutoIt

#include <array.au3>


Local $sString = '<tr class="nowrap row_a">' & @CRLF & _
'		<td><a href="index.php?id=5277&amp;screen=view">Art1(12-31)</a></td>' & @CRLF & _
'		<td>499</td>' & @CRLF & _
'		<td>Beschreibung</td>' & @CRLF & _
'		<td>Dies ist eine Beschreibung</td>' & @CRLF & _
'		<td>1/23</td>' & @CRLF & _
'	</tr>' & @CRLF & _
'	<tr class="nowrap row_b">' & @CRLF & _
'		<td><a href="index.php?id=5278&amp;screen=view">Art2 (40-483)</a></td>' & @CRLF & _
'		<td>899</td>' & @CRLF & _
'		<td>Beschreibung</td>' & @CRLF & _
'		<td>Lalala</td>' & @CRLF & _
'		<td>999/1000</td>' & @CRLF & _
'	</tr>' & @CRLF & _
'	<tr class="nowrap row_a">' & @CRLF & _
'		<td><a href="index.php?id=5280&amp;screen=view">Art3 (399-486)</a></td>' & @CRLF & _
'		<td>19999</td>' & @CRLF & _
'		<td>Beschreibung</td>' & @CRLF & _
'		<td>Bablaldfhusdfwe</td>' & @CRLF & _
'		<td>5/26</td>' & @CRLF & _
'	</tr>' & @CRLF




; alle trs durchgehen:
$a_TRs = _CssSelectFromString($sString, "tr.nowrap")
For $i = 0 To UBound($a_TRs) -1
	; alle tds im jeweilgen tr ermitteln:
	$a_TDs = _CssSelectFromString($a_TRs[$i][2], "td")


	; Artikel ist noch in <a>-Element verschachtelt - dieses noch auflösen:
	$a_TDs[0][2] = _CssSelectFromString($a_TDs[0][2], "a")[0][2]


	_ArrayDisplay($a_TDs)
Next




; #FUNCTION# ======================================================================================
; Name ..........: _CssSelectFromString()
; Description ...: extract elements out of a html string with css-style selectors
; Syntax ........: _CssSelectFromString($s_String, $s_Selector, {Const $b_First = True})
; Parameters ....: $s_String      - the html string
;                  $s_Selector    - the css-style selector
;                  {$b_First}     - dont't touch! - for internal use only!
; Return values .: Success: Array[...][0] = element attributes string
;                           Array[...][1] = element content string
;                  Failure: ""
;                     @error = 1: no balanced elements found
; Remarks .......: The following CSS-Selector-Features are implemented:
;                  .class               - class of a element
;                  #ID                  - ID of a element
;                  [attribute]          - attribute exist
;                  [attribute="value"]  - elements with attribute=value
;                  [attribute^="value"] - elements where attribute starting with value
;                  [attribute~="value"] - elements where attribute containing value
;                  [attribute$="value"] - elements where attribute ending with value
; Known bugs ....: - no empty element type is allowed - you have to set a type
;                  - If Balancing is not correct in the string - the result is also not correct
;                  - If selector is too general - some result may get doubled - to solve this: be as exactly as possible
; Author ........: AspirinJunkie
; Version .......: 0.8
; =================================================================================================
Func _CssSelectFromString($s_String, $s_Selector, Const $b_First = True)
	Local $s_Type = ""
	Local $a_RegEx, $b_Match, $ID, $i, $j, $a_Ret
	Local Static $o_Result


	If $b_First Then
		$s_String = StringRegExpReplace($s_String, "(?s)(?x)(?:<!--.+?)(?R)?(?:-->)", "") ; Kommentare killen
		$s_String = StringRegExpReplace($s_String, "(?s)(?x)(?:<script.+?)(?R)?(?:</script)", "") ; Script-Elemente killen (Inhalt könnte Probleme beim Parsen bringen)
		$s_String = StringRegExpReplace($s_String, "(?s)^.+<body\b(.+?)</body>.+$", "$1") ; Nur Inhalt des Bodys verwenden
		$o_Result = ObjCreate('Scripting.Dictionary')
	EndIf


	$s_Selector = StringStripWS($s_Selector, 7)
	Local $s_CurrentSelector = StringRegExp($s_Selector, "^(\S+)", 3)[0]
	Local $s_SelectorRest = StringStripWS(StringRegExpReplace($s_Selector, "^(\S+)", ""), 7)


	; Get the element type:
	$a_RegEx = StringRegExp($s_CurrentSelector, "^(\w*)", 3)
	If @error Then Return SetError(1, @error, "")
	$s_Type = $a_RegEx[0]


	; Alle Typen durchgehen und auf Übereinstimmung mit weiteren KLassifikatoren prüfen
	Local $a_Types = _HtmlElements($s_String, $s_Type)


	Local $a_AttribOpt = StringRegExp($s_CurrentSelector, "\[(\w+)\s*([~\*|\^\$]?=)\s*['""](.+?)['""]\s*\]", 4)
	If @error Then Local $a_AttribOpt[0]
	Local $a_ClassesOpt = StringRegExp($s_CurrentSelector, "\.(\w+)", 3)
	If @error Then Local $a_ClassesOpt[0]
	Local $a_IDOpt = StringRegExp($s_CurrentSelector, "#(\w+)", 3)
	If @error Then Local $a_IDOpt[0]


	For $j = 0 To UBound($a_Types) - 1
		$b_Match = True
		; Check for ID:
		For $ID In $a_IDOpt
			If Not StringRegExp($a_Types[$j][0], "(?x)\bid=['""]\b" & $ID & "\b['""]") Then ContinueLoop 2
		Next


		; Check for class:
		For $Class In $a_ClassesOpt
			If Not StringRegExp($a_Types[$j][0], "(?x)\bclass=['""][^'"">]*?\b" & $Class & "\b[^'"">]*?['""](?x)") Then ContinueLoop 2
		Next


		; Check for attributes:
		; check for exist:
		$a_RegEx = StringRegExp($s_CurrentSelector, "\[(\w+)\s*\]", 3)
		If Not @error Then
			For $Attr In $a_RegEx
				If Not StringRegExp($a_Types[$j][0], "(?x)\b" & $Attr & "\b[=\s$]") Then ContinueLoop 2
			Next
		EndIf
		For $AttrVal In $a_AttribOpt
			Switch $AttrVal[2]
				Case "=" ; full match
					If Not StringRegExp($a_Types[$j][0], "(?x)" & $AttrVal[1] & "=['""]" & $AttrVal[3] & "['""]") Then ContinueLoop 2
				Case "~=", "*=" ; partial match
					If Not StringRegExp($a_Types[$j][0], "(?x)" & $AttrVal[1] & "=['""][^'""]*" & $AttrVal[3] & "[^'""]*['""]") Then ContinueLoop 2
				Case "|=", "^=" ; start match
					If Not StringRegExp($a_Types[$j][0], "(?x)" & $AttrVal[1] & "=['""]" & $AttrVal[3] & "[^'""]*['""]") Then ContinueLoop 2
				Case "$=" ; end match
					If Not StringRegExp($a_Types[$j][0], "(?x)" & $AttrVal[1] & "=['""][^'""]*" & $AttrVal[3] & "['""]") Then ContinueLoop 2
			EndSwitch
		Next


		; save result element
		If $s_SelectorRest = "" Then
			Local $a_T[3] = [$s_Type, $a_Types[$j][0], $a_Types[$j][1]]
			$o_Result($o_Result.Count) = $a_T
		Else
			_CssSelectFromString($a_Types[$j][1], $s_SelectorRest, False)
		EndIf


		; check for ":first" selector
		If StringInStr($s_CurrentSelector, ":first", 2) Then ExitLoop
;~ 		If StringInStr($s_CurrentSelector, ":nth-of-type(" & $d_RetCounter & ")", 2) Then
	Next


	If $b_First Then
		Local $n = $o_Result.Count
		Local $a_Return[$n][3]
		Local $v = 0
		For $i In $o_Result.Keys()
			$a_Return[$v][0] = StringStripWS($o_Result($i)[0], 3)
			$a_Return[$v][1] = StringStripWS($o_Result($i)[1], 3)
			$a_Return[$v][2] = StringStripWS($o_Result($i)[2], 3)
			$v += 1
		Next
		Return $a_Return
	EndIf
EndFunc   ;==>_CssSelectFromString








; #FUNCTION# ======================================================================================
; Name ..........: _HtmlElements()
; Description ...: extract all elements of type $s_Type from a html string
; Syntax ........: _HtmlElements(ByRef $s_Html, Const $s_Type)
; Parameters ....: $s_Html        - the html string
;                  $s_Type        - the html element type which should to extract
; Return values .: Success: Array[...][0] = element attributes string
;                           Array[...][1] = element content string
;                  Failure: ""
;                     @error = 1: no balanced elements found
; Known bugs ....: If Balancing is not correct in the string - the result is also not correct
; Author ........: AspirinJunkie
; =================================================================================================
Func _HtmlElements(ByRef $s_Html, Const $s_Type)
	Local $d_Start, $d_End, $d_T, $d_Pos = 1, $x = 0, $a_Element
	Local $s_Begin = "<" & $s_Type, $s_Ende = "</" & $s_Type


	Local $n = UBound(StringRegExp($s_Html, $s_Begin, 3))
	Local $u = UBound(StringRegExp($s_Html, $s_Ende, 3))


	If $n = 0 Or $u = 0 Then Return SetError(1, 0, "")
	Local $a_Starts[$n], $a_Ends[$u]


	; Alle Tag-Anfänge ermitteln:
	Do
		$d_T = StringInStr($s_Html, $s_Begin, 2, 1, $d_Pos)
		If $d_T = 0 Then ExitLoop


		$a_Starts[$x] = $d_T
		$d_Pos = $d_T + StringLen($s_Begin)
		$x += 1
	Until 0


	; Alle Tag-Enden ermitteln:
	$x = 0
	$d_Pos = 1
	Do
		$d_T = StringInStr($s_Html, $s_Ende, 2, 1, $d_Pos)
		If $d_T = 0 Then ExitLoop


		$a_Ends[$x] = $d_T
		$d_Pos = $d_T + StringLen($s_Ende)
		$x += 1
	Until 0


	; Funde matchen
	Local $dMax = UBound($a_Ends) > UBound($a_Starts) ? UBound($a_Starts) - 1 : UBound($a_Ends) - 1
	Local $d_End
	Local $a_Return[$dMax + 1][3]
	For $i = 0 To $dMax
		$d_End = $a_Ends[$i]
		For $j = $dMax To 0 Step -1
			$d_Start = $a_Starts[$j]
			If $d_Start = 1000000000 Then ContinueLoop
			If $d_Start < $d_End Then
				$a_Element = StringRegExp(StringMid($s_Html, $d_Start, $d_End - $d_Start + StringLen($s_Ende)), "(?s)^<" & $s_Type & "\s?(.*?)>(.*)</" & $s_Type, 3)
				If UBound($a_Element) < 2 Then ContinueLoop
				$a_Return[$i][0] = $a_Element[0]
				$a_Return[$i][1] = $a_Element[1]
				$a_Return[$i][2] = $d_Start


				$a_Starts[$j] = 1000000000
				ContinueLoop 2
			EndIf
		Next
	Next


	Return $a_Return
EndFunc   ;==>_HtmlElements

Alles anzeigen

Fr34k.

Vielen Dank erneut AspirinJunkie
Beim RegEx war lediglich das letzte '+' um eine Stellle verschoben.
Ich hoffe ich finde mich zurecht, werde nun das ganze ein bisschen öfter probieren.

Gruss
Fr34k

Fr34k.

Und hier kommt nochmals eine Frage - Weiss nicht wieso ich nicht gleich von Anfang an den Kompletten Code verwendet habe.. -.^
Es werden mehrere Zeilen, ich komme jedoch mit dem hidden nicht klar..

HTML

<tr class="nowrap row_a">
		<td><a href="index.php?id=5277&amp;screen=view">Art1(12-31)</a></td>
		<td><a href="view.php?id=5280&screen=object"><img src="a.png" title="a" alt="" /></a></td>
		<td><a href="view.php?id=5280&screen=object"><img src="b.png" title="b" alt="" /></a></td>
		<td><a href="view.php?id=5280&screen=object"><img src="c.png" title="c" alt="" /></a></td>
		<td><a href="view.php?id=5280&screen=object"><img src="d.png" title="d" alt="" /></a></td>
		<td><a href="view.php?id=5280&screen=object"><img src="e.png" title="e" alt="" /></a></td>
		<td><a href="bestand.php?id=5280&screen=best">1/23</a></td>
		<td>8364</td>
		<td class="hidden">0</td>
		<td>723</td>
		<td>45</td>
		<td class="hidden">0</td>
		<td>3</td>
		<td>1256</td>
		<td class="hidden">0</td>
		<td><a href="view.php&id=5280&screen=buy">200/200</a></td>
	</tr>
	<tr class="nowrap row_b">
		<td><a href="index.php?id=5278&amp;screen=view">Art2 (40-483)</a></td>
		<td><a href="view.php?id=5278&screen=object"><img src="a.png" title="a" alt="" /></a></td>
		<td><a href="view.php?id=5278&screen=object"><img src="b.png" title="b" alt="" /></a></td>
		<td><a href="view.php?id=5278&screen=object"><img src="c.png" title="c" alt="" /></a></td>
		<td><a href="view.php?id=5278&screen=object"><img src="d.png" title="d" alt="" /></a></td>
		<td><a href="view.php?id=5278&screen=object"><img src="e.png" title="e" alt="" /></a></td>
		<td><a href="bestand.php?id=5280&screen=best">999/1000</a></td>
		<td>1234</td>
		<td>3762</td>
		<td>723</td>
		<td class="hidden">0</td>
		<td class="hidden">0</td>
		<td>3</td>
		<td class="hidden">0</td>
		<td>12</td>
		<td><a href="view.php&id=5278&screen=buy">200/200</a></td>
	</tr>
	<tr class="nowrap row_a">
		<td><a href="index.php?id=5280&amp;screen=view">Art3 (399-486)</a></td>
		<td><a href="view.php?id=5280&screen=object"><img src="a.png" title="a" alt="" /></a></td>
		<td><a href="view.php?id=5280&screen=object"><img src="b.png" title="b" alt="" /></a></td>
		<td><a href="view.php?id=5280&screen=object"><img src="c.png" title="c" alt="" /></a></td>
		<td><a href="view.php?id=5280&screen=object"><img src="d.png" title="d" alt="" /></a></td>
		<td><a href="view.php?id=5280&screen=object"><img src="e.png" title="e" alt="" /></a></td>
		<td><a href="bestand.php?id=5280&screen=best">5/26</a></td>
		<td class="hidden">0</td>
		<td>2348</td>
		<td>723</td>
		<td>1</td>
		<td class="hidden">0</td>
		<td>3</td>
		<td class="hidden">0</td>
		<td>12</td>
		<td><a href="view.php&id=5280&screen=buy">200/200</a></td>
	</tr>

Alles anzeigen

Ich brauche folgende Infos:
Artikelname: Art1(12-31)
Bestand: 1/23
8364
0
723
45
0
3
1256
0

Wie komme ich an all diese Infos? Die Anzahl der Spalten bleibt immerhin immer die gleiche
Gruss
Fr34k

**AspirinJunkie**

Siehe mein vorheriges Beispiel ohne RegEx:

Spoiler anzeigen

AutoIt

#include <array.au3>


Local $sString = '<tr class="nowrap row_a">' & @CRLF & _
		'		<td><a href="index.php?id=5277&amp;screen=view">Art1(12-31)</a></td>' & @CRLF & _
		'		<td><a href="view.php?id=5280&screen=object"><img src="a.png" title="a" alt="" /></a></td>' & @CRLF & _
		'		<td><a href="view.php?id=5280&screen=object"><img src="b.png" title="b" alt="" /></a></td>' & @CRLF & _
		'		<td><a href="view.php?id=5280&screen=object"><img src="c.png" title="c" alt="" /></a></td>' & @CRLF & _
		'		<td><a href="view.php?id=5280&screen=object"><img src="d.png" title="d" alt="" /></a></td>' & @CRLF & _
		'		<td><a href="view.php?id=5280&screen=object"><img src="e.png" title="e" alt="" /></a></td>' & @CRLF & _
		'		<td><a href="bestand.php?id=5280&screen=best">1/23</a></td>' & @CRLF & _
		'		<td>8364</td>' & @CRLF & _
		'		<td class="hidden">0</td>' & @CRLF & _
		'		<td>723</td>' & @CRLF & _
		'		<td>45</td>' & @CRLF & _
		'		<td class="hidden">0</td>' & @CRLF & _
		'		<td>3</td>' & @CRLF & _
		'		<td>1256</td>' & @CRLF & _
		'		<td class="hidden">0</td>' & @CRLF & _
		'		<td><a href="view.php&id=5280&screen=buy">200/200</a></td>' & @CRLF & _
		'	</tr>' & @CRLF & _
		'	<tr class="nowrap row_b">' & @CRLF & _
		'		<td><a href="index.php?id=5278&amp;screen=view">Art2 (40-483)</a></td>' & @CRLF & _
		'		<td><a href="view.php?id=5278&screen=object"><img src="a.png" title="a" alt="" /></a></td>' & @CRLF & _
		'		<td><a href="view.php?id=5278&screen=object"><img src="b.png" title="b" alt="" /></a></td>' & @CRLF & _
		'		<td><a href="view.php?id=5278&screen=object"><img src="c.png" title="c" alt="" /></a></td>' & @CRLF & _
		'		<td><a href="view.php?id=5278&screen=object"><img src="d.png" title="d" alt="" /></a></td>' & @CRLF & _
		'		<td><a href="view.php?id=5278&screen=object"><img src="e.png" title="e" alt="" /></a></td>' & @CRLF & _
		'		<td><a href="bestand.php?id=5280&screen=best">999/1000</a></td>' & @CRLF & _
		'		<td>1234</td>' & @CRLF & _
		'		<td>3762</td>' & @CRLF & _
		'		<td>723</td>' & @CRLF & _
		'		<td class="hidden">0</td>' & @CRLF & _
		'		<td class="hidden">0</td>' & @CRLF & _
		'		<td>3</td>' & @CRLF & _
		'		<td class="hidden">0</td>' & @CRLF & _
		'		<td>12</td>' & @CRLF & _
		'		<td><a href="view.php&id=5278&screen=buy">200/200</a></td>' & @CRLF & _
		'	</tr>' & @CRLF & _
		'	<tr class="nowrap row_a">' & @CRLF & _
		'		<td><a href="index.php?id=5280&amp;screen=view">Art3 (399-486)</a></td>' & @CRLF & _
		'		<td><a href="view.php?id=5280&screen=object"><img src="a.png" title="a" alt="" /></a></td>' & @CRLF & _
		'		<td><a href="view.php?id=5280&screen=object"><img src="b.png" title="b" alt="" /></a></td>' & @CRLF & _
		'		<td><a href="view.php?id=5280&screen=object"><img src="c.png" title="c" alt="" /></a></td>' & @CRLF & _
		'		<td><a href="view.php?id=5280&screen=object"><img src="d.png" title="d" alt="" /></a></td>' & @CRLF & _
		'		<td><a href="view.php?id=5280&screen=object"><img src="e.png" title="e" alt="" /></a></td>' & @CRLF & _
		'		<td><a href="bestand.php?id=5280&screen=best">5/26</a></td>' & @CRLF & _
		'		<td class="hidden">0</td>' & @CRLF & _
		'		<td>2348</td>' & @CRLF & _
		'		<td>723</td>' & @CRLF & _
		'		<td>1</td>' & @CRLF & _
		'		<td class="hidden">0</td>' & @CRLF & _
		'		<td>3</td>' & @CRLF & _
		'		<td class="hidden">0</td>' & @CRLF & _
		'		<td>12</td>' & @CRLF & _
		'		<td><a href="view.php&id=5280&screen=buy">200/200</a></td>' & @CRLF & _
		'	</tr>' & @CRLF




;~ ; alle trs durchgehen:
$a_TRs = _CssSelectFromString($sString, "tr.nowrap")
For $i = 0 To UBound($a_TRs) - 1
	; alle tds im jeweilgen tr ermitteln:
	$a_TDs = _CssSelectFromString($a_TRs[$i][2], "td")


	; in <a> verpackte Elemente noch auflösenist noch in <a>-Element verschachtelt - dieses noch auflösen:
	For $j = 0 To UBound($a_TDs) - 1
		If StringLeft($a_TDs[$j][2], 3) = "<a " Then $a_TDs[$j][2] = _CssSelectFromString($a_TDs[$j][2], "a")[0][2]
	Next
	_ArrayDisplay($a_TDs)
Next






; #FUNCTION# ======================================================================================
; Name ..........: _CssSelectFromString()
; Description ...: extract elements out of a html string with css-style selectors
; Syntax ........: _CssSelectFromString($s_String, $s_Selector, {Const $b_First = True})
; Parameters ....: $s_String      - the html string
;                  $s_Selector    - the css-style selector
;                  {$b_First}     - dont't touch! - for internal use only!
; Return values .: Success: Array[...][0] = element attributes string
;                           Array[...][1] = element content string
;                  Failure: ""
;                     @error = 1: no balanced elements found
; Remarks .......: The following CSS-Selector-Features are implemented:
;                  .class               - class of a element
;                  #ID                  - ID of a element
;                  [attribute]          - attribute exist
;                  [attribute="value"]  - elements with attribute=value
;                  [attribute^="value"] - elements where attribute starting with value
;                  [attribute~="value"] - elements where attribute containing value
;                  [attribute$="value"] - elements where attribute ending with value
;                  :first               - only the first element gets returned
;                  :nth-of-type(<number>) - match only the nth match of the element
;                  :has(<Selector>)     - elements which contain at least one element that matches the specified selector
;                  :nothas(<Selector>)  - elements which not contain a element that matches the specified selector
; Known bugs ....: - If Balancing is not correct in the string - the result is also not correct
;                  - If selector is too general - some result may get doubled - to solve this: be as exactly as possible
; Author ........: AspirinJunkie
; Version .......: 0.8.1
; =================================================================================================
Func _CssSelectFromString($s_String, $s_Selector, Const $b_First = True, Const $b_SubCheck = False)
	Local $s_Type = ""
	Local $a_RegEx, $ID, $i, $j, $a_Ret, $s_Attrs
	Local Static $o_Result
	Local $d_RetCounter = 0


	If $b_First Then
		$s_String = StringRegExpReplace($s_String, "(?s)(?x)(?:<!--.+?)(?R)?(?:-->)", "") ; Kommentare killen
		$s_String = StringRegExpReplace($s_String, "(?s)(?x)(?:<script.+?)(?R)?(?:</script)", "") ; Script-Elemente killen (Inhalt könnte Probleme beim Parsen bringen)
		$s_String = StringRegExpReplace($s_String, "(?s)^.+<body\b(.+?)</body>.+$", "$1") ; Nur Inhalt des Bodys verwenden
		$o_Result = ObjCreate('Scripting.Dictionary')
	EndIf


	$s_Selector = StringStripWS($s_Selector, 7)
	Local $s_CurrentSelector = StringRegExp($s_Selector, '^((?:"\s*[^"]+\s*[^"]+"|\(((?:.|(?R))*)\)|\S)+)', 1)[0]
	Local $s_SelectorRest = StringStripWS(StringTrimLeft($s_Selector, @extended), 1)


	; Get the element type:
	$a_RegEx = StringRegExp($s_CurrentSelector, "^(\w*)", 1)
	If @error Then Return SetError(1, @error, "")
	$s_Type = $a_RegEx[0]


	; Alle Typen durchgehen und auf Übereinstimmung mit weiteren KLassifikatoren prüfen
	Local $a_Types = _HtmlElements($s_String, $s_Type, True)


	Local $a_HasProperty = StringRegExp($s_CurrentSelector, ":has\(\s*((?:.|(?R))*)\)", 3)
	If @error Then Local $a_HasProperty[0]
	Local $a_nothasProperty = StringRegExp($s_CurrentSelector, ":nothas\(\s*((?:.|(?R))*)\)", 3)
	If @error Then Local $a_nothasProperty[0]
	$s_CurrentSelector = StringRegExpReplace($s_CurrentSelector, ":(has|nothas)\(\s*((?:.|(?R))*)\)", "") ; delete :has and :nothas-Selectors because the inner Selector shouldn't processed by the following Selectors
	Local $a_AttribOpt = StringRegExp($s_CurrentSelector, "\[(\w+)\s*([~\*|\^\$]?=)\s*['""](.+?)['""]\s*\]", 4)
	If @error Then Local $a_AttribOpt[0]
	Local $a_ClassesOpt = StringRegExp($s_CurrentSelector, "\.(\w+)", 3)
	If @error Then Local $a_ClassesOpt[0]
	Local $a_IDOpt = StringRegExp($s_CurrentSelector, "#(\w+)", 3)
	If @error Then Local $a_IDOpt[0]
	Local $b_EmptyProperty = StringRegExp($s_CurrentSelector, ":empty\b", 0)
	$a_RegEx = StringRegExp($s_CurrentSelector, ":nth-of-type\((\d+)\)", 1)
	Local $d_NthOfType = @error ? 0 : $a_RegEx[0]


	For $j = 0 To UBound($a_Types) - 1
		$s_Attrs = $a_Types[$j][1]
		; Check for ID:
		For $ID In $a_IDOpt
			If Not StringRegExp($s_Attrs, "(?x)\bid=['""]\b" & $ID & "\b['""]") Then ContinueLoop 2
		Next
		; Check for class:
		For $Class In $a_ClassesOpt
			If Not StringRegExp($s_Attrs, "(?x)\bclass=['""][^'"">]*?\b" & $Class & "\b[^'"">]*?['""](?x)") Then ContinueLoop 2
		Next
		; Check for attributes:
		; check for exist:
		$a_RegEx = StringRegExp($s_CurrentSelector, "\[(\w+)\s*\]", 3)
		If Not @error Then
			For $Attr In $a_RegEx
				If Not StringRegExp($s_Attrs, "(?x)\b" & $Attr & "\b[=\s$]") Then ContinueLoop 2
			Next
		EndIf
		For $AttrVal In $a_AttribOpt
			Switch $AttrVal[2]
				Case "=" ; full match
					If Not StringRegExp($s_Attrs, "(?x)" & $AttrVal[1] & "=['""]" & $AttrVal[3] & "['""]") Then ContinueLoop 2
				Case "~=", "*=" ; partial match
					If Not StringRegExp($s_Attrs, "(?x)" & $AttrVal[1] & "=['""][^'""]*" & $AttrVal[3] & "[^'""]*['""]") Then ContinueLoop 2
				Case "|=", "^=" ; start match
					If Not StringRegExp($s_Attrs, "(?x)" & $AttrVal[1] & "=['""]" & $AttrVal[3] & "[^'""]*['""]") Then ContinueLoop 2
				Case "$=" ; end match
					If Not StringRegExp($s_Attrs, "(?x)" & $AttrVal[1] & "=['""][^'""]*" & $AttrVal[3] & "['""]") Then ContinueLoop 2
			EndSwitch
		Next


		;has(<Selector>)
		For $HasSelector In $a_HasProperty
			If Not _CssSelectFromString(StringMid($s_String, $a_Types[$j][4], $a_Types[$j][5] - $a_Types[$j][4]), $HasSelector, False, True) Then ContinueLoop 2
		Next
		;nothas(<Selector>)
		For $NotSelector In $a_nothasProperty
			If _CssSelectFromString(StringMid($s_String, $a_Types[$j][4], $a_Types[$j][5] - $a_Types[$j][4]), $NotSelector, False, True) Then ContinueLoop 2
		Next
		;:empty
		If $b_EmptyProperty Then
			If Not StringIsSpace(StringMid($s_String, $a_Types[$j][4], $a_Types[$j][5] - $a_Types[$j][4])) Then ContinueLoop
		EndIf
		;:nth-of-type()
		If $d_NthOfType Then
			$d_RetCounter += 1
			If $d_RetCounter <> $d_NthOfType Then ContinueLoop
		EndIf


		; save result element
		If $s_SelectorRest = "" Then
			If $b_SubCheck Then Return True
			Local $a_T[3] = [$a_Types[$j][0], $a_Types[$j][1], StringMid($s_String, $a_Types[$j][4], $a_Types[$j][5] - $a_Types[$j][4])]
			$o_Result($o_Result.Count) = $a_T
		Else
			If $b_SubCheck Then
				Return _CssSelectFromString(StringMid($s_String, $a_Types[$j][4], $a_Types[$j][5] - $a_Types[$j][4]), $s_SelectorRest, False, True)
			Else
				_CssSelectFromString(StringMid($s_String, $a_Types[$j][4], $a_Types[$j][5] - $a_Types[$j][4]), $s_SelectorRest, False)
			EndIf
		EndIf


		; check for ":first" selector
		If StringInStr($s_CurrentSelector, ":first", 2) Then ExitLoop
		If $d_NthOfType And $d_RetCounter = $d_NthOfType Then ExitLoop ; :nth-of-type() - break because following elements could'nt match
	Next


	If $b_SubCheck Then Return False ; if recursion is inside a :has or :nothas-Selector


	If $b_First Then
		Local $n = $o_Result.Count
		Local $a_Return[$n][3]
		Local $v = 0
		For $i In $o_Result.Items()
			$a_Return[$v][0] = StringStripWS($i[0], 3)
			$a_Return[$v][1] = StringStripWS($i[1], 3)
			$a_Return[$v][2] = StringStripWS($i[2], 3)
			$v += 1
		Next
		Return $a_Return
	EndIf
EndFunc   ;==>_CssSelectFromString








; #FUNCTION# ======================================================================================
; Name ..........: _HtmlElements()
; Description ...: extract all elements of type $s_Type from a html string
; Syntax ........: _HtmlElements(ByRef $s_Html, Const $s_Type)
; Parameters ....: $s_Html        - the html string
;                  $s_Type        - the html element type which should to extract
;                  $bN            - False: returns 4-column array with element content as a string
;                                 - True: returns 6-column array with substring positions of
;                                         element and it's content inside of $s_Html
; Return values .: Success: Array[...][0] = element attributes string
;                           Array[...][1] = element content string
;                  Failure: ""
;                     @error = 1: no balanced elements found
; Known bugs ....: If Balancing is not correct in the string - the result is also not correct
; Author ........: AspirinJunkie
; =================================================================================================
Func _HtmlElements(ByRef $s_Html, Const $s_Type = "", Const $bN = False)
	Local $d_Start, $d_End, $d_T, $d_Pos = 1, $x = 0, $a_Element
	Local $s_Begin = "<" & $s_Type, $s_Ende = "</" & $s_Type
	Local $nB = StringLen($s_Begin)
	Local $oVoids = ObjCreate("Scripting.Dictionary") ; replace later with AutoIt-Maps


	Local $s_Ends = "", $s_Begins = ""
	Local $s_VoidEnds = "", $s_VoidBegins = ""
	Local $dOff, $a_T, $s_ElType, $s_T


	Local Const $s_REstart = ($s_Type = "") ? "(<\w+\b)" : "(<" & $s_Type & "\b)"
	Local Const $s_REend = ($s_Type = "") ? "(</\w+\b)" : "(</" & $s_Type & "\b)"


	; Alle Tag-Anfänge ermitteln:
	Do
		$a_T = StringRegExp($s_Html, $s_REstart, 1, $d_Pos)
		$dOff = @extended
		If $dOff = 0 Then ExitLoop
		$d_T = $dOff - StringLen($a_T[0])


		; void element form (e.g: <link href="fancy.css" type="text/css" /> )
		$a_T = StringRegExp($s_Html, "\G<(area|base|br|col|command|embed|hr|img|input|keygen|link|meta|param|source|track|wbr)\s*([^<]*?)/?>", 1, $d_T)
		$dOff = @extended
		If $dOff Then
			Local $aTemp[4] = [$a_T[0], $a_T[1], $d_T, $dOff]
			$d_Pos = $dOff
			$oVoids($d_T) = $aTemp
		Else ; normal elements
			$s_Begins &= $d_T & "|"
			$d_Pos = $d_T + $nB
		EndIf
		$x += 1
	Until 0


	; Alle Tag-Enden ermitteln:
	$d_Pos = 1
	Do
		$a_T = StringRegExp($s_Html, $s_REend, 1, $d_Pos)
		$dOff = @extended
		If $dOff = 0 Then ExitLoop
		$s_Ends &= $dOff - StringLen($a_T[0]) & "|"
		$d_Pos = $dOff
	Until 0


	If $s_Begins <> "" And $s_Ends <> "" Then
		Local $a_Starts = StringSplit(StringTrimRight($s_Begins, 1), "|", 2)
		Local $a_Ends = StringSplit(StringTrimRight($s_Ends, 1), "|", 2)
		For $i = 0 To UBound($a_Starts) - 1
			$a_Starts[$i] = Int($a_Starts[$i])
		Next
		For $i = 0 To UBound($a_Ends) - 1
			$a_Ends[$i] = Int($a_Ends[$i])
		Next


		; Funde matchen
		Local $dMax = UBound($a_Ends) > UBound($a_Starts) ? UBound($a_Starts) : UBound($a_Ends)
		Local $a_Return[$dMax + $oVoids.Count][($bN ? 6 : 4)]
		If $dMax > 0 Then
			Local $d_End
			For $i = 0 To UBound($a_Ends) - 1
				$d_End = $a_Ends[$i]
				For $j = UBound($a_Starts) - 1 To 0 Step -1
					$d_Start = $a_Starts[$j]
					If $d_Start = 1000000000 Then ContinueLoop
					If $d_Start < $d_End Then
						If $bN Then
							$a_Element = StringRegExp($s_Html, "(?s)\G<(\w+)\b\s?(.*?)>", 1, $d_Start)
							$dOff = @extended
							If UBound($a_Element) < 2 Then ContinueLoop
							$a_Return[$i][0] = $a_Element[0]
							$a_Return[$i][1] = $a_Element[1]
							$a_Return[$i][2] = Int($d_Start)
							$a_Return[$i][3] = Int($d_End) + 3 + StringLen($a_Element[0])
							$a_Return[$i][4] = $dOff
							$a_Return[$i][5] = Int($d_End)
						Else
							$a_Element = StringRegExp(StringMid($s_Html, $d_Start, $d_End - $d_Start + StringLen($s_Ende)), "(?s)^<(\w+)\b\s?(.*?)>(.*)</" & $s_Type, 3)
;~ 						$a_Element = StringRegExp($s_Html, "(?s)\G<" & $s_Type & "\s?(.*?)>(.*?)</" & $s_Type, 3, $d_Start)
							If UBound($a_Element) < 2 Then ContinueLoop
							$a_Return[$i][0] = $a_Element[0]
							$a_Return[$i][1] = $a_Element[1]
							$a_Return[$i][2] = $a_Element[2]
							$a_Return[$i][3] = Int($d_Start)
						EndIf


						$a_Starts[$j] = 1000000000
						ContinueLoop 2
					EndIf
				Next
			Next
		EndIf
	Else
		Local $a_Return, $dMax = 0
	EndIf


	; add the void elements to the result array
	If Not IsArray($a_Return) Then Local $a_Return[$oVoids.Count][($bN ? 6 : 4)]
	Local $c = 0
	For $i In $oVoids.Items
		$a_Return[$dMax + $c][0] = $i[0]
		$a_Return[$dMax + $c][1] = $i[1]
		If $bN Then
			$a_Return[$dMax + $c][2] = $i[2]
			$a_Return[$dMax + $c][3] = $i[3]
		Else
			$a_Return[$dMax + $c][3] = $i[2]
		EndIf
		$c += 1
	Next


	_ArraySort($a_Return, 0, 0, 0, ($bN ? 2 : 3))
	Return $a_Return
EndFunc   ;==>_HtmlElements

Alles anzeigen

Fr34k.

Und nochmals eine Frage -.-'
Teils Links sehen so aus:

Code

class="result-item detail-page-link result-item--visited" href="/kaufen/105038365"

andere so:

Code

class="result-item detail-page-link" href="/kaufen/104485987"

Ich möchte in beiden Fällen die Nummer hinter dem /kaufen/ haben.
Bin bisher so weit:

AutoIt

$Match = StringRegExp($source, '(?s)class=\"result-item detail-page-lin.+?\" href="\/kaufen\/(.+?)\"')

Gemäss verschiedenen Online-Regex Tester sollte dies auch funktionieren, macht es aber nicht. Wieso?

Gruss

**AspirinJunkie**

Möchtest du die Nummer nun als String haben oder willst du nur testen ob es matcht?
Momentan enthält $Match nur entweder True oder False - je nachdem ob es matcht.

Den Inhalt von $source kennen wir nicht - für die beiden Schnipsel funktioniert es aber:

AutoIt

#include <Array.au3>


$source = 'class="result-item detail-page-link result-item--visited" href="/kaufen/105038365"' & @CRLF & _
'class="result-item detail-page-link" href="/kaufen/104485987"'


$a_Match = StringRegExp($source, 'class="result-item detail-page-link[^"]*?"[^>]+?href="/kaufen/(.+?)"', 3)
_ArrayDisplay($a_Match)

Fr34k.

Vielen Dank, ganz vergessen die Zahl anzuhängen.