Monitor schaltet sich nicht mehr ab bei "@SW_hide"

Harald654

Hallo,

Da ich gewisse Funktionen eines Programms (Kodi) gerne immer verfügbar haben möchte, hab ich mir ein kleines Skript geschrieben, um das Programm versteckt zu starten run ($KodiPfad, "", @SW_HIDE) und per Tastenkombination zwischen sichtbar und unsichtbar umzuschalten WinSetState($WKodi,"",@SW_SHOW) bzw. WinSetState($WKodi,"",@SW_HIDE).

Funktioniert im Prinzip alles super (sogar das GUI-Rendering des Programmes schaltet sich ab, wodurch die CPU Auslastung kaum wahrnehmbar ist ),
nur schaltet sich der Monitor nicht mehr nach der eingestellten Zeit ab, wenn ich das Programm mit "@SW_HIDE" in den Hintergund verschiebe.
Wenn das Programm Angezeigt wird bzw. im Vollbild läuft (ist keine echte Vollbildanwendung, wird als Fenster ohne Rand dargestellt), oder ich das Programm mit "@SW_MINIMIZE" minimiert habe, funktioniert das Abschalten des Monitors ohne Probleme. Nur mit "@SW_HIDE" nicht!
Ich kann in dem Programm auch eine Zeit einstellen, nachdem der Bildschirm bei Inaktivität abgeschaltet wird, aber auch das funktioniert nicht bei @SW_HIDE.
(Ich könnte das Programm natürlich auch nur mit "@SW_MINIMIZE" minimieren, aber da es immer ausgeführt werden soll stört mich es mich doch sehr, wenn immer die Anzeige von dem Programm in der Taskleiste ist.)

Kennt jemand dieses Problem bzw. hat jemand eine Lösung dafür?

Es kann gut sein dass an dem Programm selbst liegt (es unterdrückt ja auch das Abschalten des Bildschirms wenn z.B. ein Video läuft),
kann man dem Programm vielleicht die Berechtigung entziehen wodurch es den Bildschirm aktiv hält, oder das aktiv Halten irgendwie verhindern?

Gruß,

misterspeed

Anstatt das Verhalten mit Autoit zu beeinflussen würde ich einfach den Programmierer dieser Software anschreiben. Laut deinem Link wird die Software noch aktiv entwickelt (letzte Beta erst vor einer Woche). Schreib ihm einfach was dir fehlt und was du gerne erreichen willst und ich bin mir sicher er baut das entsprechend ein, sofern er Zeit dafür findet.

Harald654

Hallo misterspeed,

ich habe so etwas ähnliches schon im Forum von Kodi angefragt, das Programm ist nicht für Multitasking oder als Hintergrunddienst entwickelt oder gedacht. Ich könnte natürlich eine Feature Request Anfrage aufmachen, aber ich denke nicht das mein spezielles Problem für viele Andere von nutzen sein wird.
Zudem unterstützt das Programm ja das Abschalten des Monitor wenn es geöffnet oder minimiert ist, nur mit "@SW_HIDE" wird das Abschalten des Monitors verhindert.

Ich habe auch mal das Programm RTray ausprobiere, was eigentlich das gleiche macht wie der "@SW_HIDE" Befehl (ist glaube ich sogar mit Autoit geschrieben). Damit tritt das Problem nicht auf, der Monitor schaltet wie gewohnt ab, obwohl ich das Programm mit RTray in den Hintergrund verschoben habe (wenn ich danach zusätzlich noch @SW_HIDE" ausführe schaltet der Monitor wieder nicht ab).

Ich hab mal versucht die angegeben Codes auf der sourceforge Seite von RTray zu durchsuchen, um zu verstehen was das Programm anders macht. Leider finde ich weder die Codezeilen dafür, noch sieht es für mich nach Autoit aus^^

Versteht vielleicht jemand den Code und kann mir sagen wie RTray das macht, oder weiß jemand noch eine andere Möglichkeit um Programme zu "verstecken"?

Gruß,

**bernd670**

Hallo,

hast schon mal probiert @SW_MINIMIZE und @SW_HIDE zu kombinieren, bzw. @SW_SHOW und @SW_RESTORE.

AutoIt: verstecken

WinSetState("$WKodi", "", @SW_MINIMIZE)
WinSetState("$WKodi", "", @SW_HIDE)

AutoIt: wiederherstellen

WinSetState("$WKodi", "", @SW_SHOW)
WinSetState("$WKodi", "", @SW_RESTORE)

Harald654

Hallo bernd670,

hab ich auch schon versucht, aber auch wenn ich das Programm zuerst mit @SW_MINIMIZE minimiere und dann erst mit @SW_HIDE verstecke, habe ich das Problem das sich mein Bildschirm nicht mehr abschaltet.

CentuCore

RBTray ist in C++ geschrieben.
Wenn das Programm minimiert funktioniert dann mach folgendes:

Spoiler anzeigen

AutoIt

WinSetState($wnd, "", @SW_MINIMIZED)
_DelTab($wnd) ;Entfernt den Taskbar Eintrag


WinSetState($wnd, "", @SW_RESTORE)
_AddTab($wnd) ;Fügt einen neuen Taskbar Eintrag hinzu




Func _AddTab($wnd)
	Local Const $sCLSID_TaskbarList = "{56FDF344-FD6D-11d0-958A-006097C9A090}"
	Local Const $sIID_ITaskbarList = "{56FDF342-FD6D-11d0-958A-006097C9A090}"


	Local Const $sTagITaskbarList = "HrInit hresult(); AddTab hresult(hwnd); DeleteTab hresult(hwnd); ActivateTab hresult(hwnd); SetActiveAlt hresult(hwnd);"


	; Create the object.
	Local $oTaskbarList = ObjCreateInterface($sCLSID_TaskbarList, $sIID_ITaskbarList, $sTagITaskbarList)


	; Initialize the iTaskbarList object.
	$oTaskbarList.HrInit()


	$oTaskbarList.AddTab($wnd)
	$oTaskbarList = 0
EndFunc


Func _DelTab()
	Local Const $sCLSID_TaskbarList = "{56FDF344-FD6D-11d0-958A-006097C9A090}"
	Local Const $sIID_ITaskbarList = "{56FDF342-FD6D-11d0-958A-006097C9A090}"


	Local Const $sTagITaskbarList = "HrInit hresult(); AddTab hresult(hwnd); DeleteTab hresult(hwnd); ActivateTab hresult(hwnd); SetActiveAlt hresult(hwnd);"


	; Create the object.
	Local $oTaskbarList = ObjCreateInterface($sCLSID_TaskbarList, $sIID_ITaskbarList, $sTagITaskbarList)


	; Initialize the iTaskbarList object.
	$oTaskbarList.HrInit()


	$oTaskbarList.DeleteTab($wnd)
	$oTaskbarList = 0
EndFunc

Alles anzeigen

Harald654

Für $wnd setzt ich mein Programm ein oder? Brauch ich für dein Code sonst noch irgendwelche Konstanten?
Bei mir minimiert/wiederherstellt der Code das Programm, aber in der Taskbar wird es noch angezeigt (also wie bei @SW_MINIMIZE alleine, _DelTab($wnd) scheint keine Auswirkungen zu haben, ist das vielleicht Betriebssystem abhängig? ich nutze Win 8.1).

Code

Global $wnd = "Kodi"
WinSetState($wnd, "", @SW_MINIMIZE)
_DelTab($wnd) ;Entfernt den Taskbar Eintrag
;~ WinSetState($wnd, "", @SW_RESTORE)
;~ _AddTab($wnd) ;Fügt einen neuen Taskbar Eintrag hinzu
Func _AddTab($wnd)
	Local Const $sCLSID_TaskbarList = "{56FDF344-FD6D-11d0-958A-006097C9A090}"
	Local Const $sIID_ITaskbarList = "{56FDF342-FD6D-11d0-958A-006097C9A090}"
	Local Const $sTagITaskbarList = "HrInit hresult(); AddTab hresult(hwnd); DeleteTab hresult(hwnd); ActivateTab hresult(hwnd); SetActiveAlt hresult(hwnd);"
	; Create the object.
	Local $oTaskbarList = ObjCreateInterface($sCLSID_TaskbarList, $sIID_ITaskbarList, $sTagITaskbarList)
	; Initialize the iTaskbarList object.
	$oTaskbarList.HrInit()
	$oTaskbarList.AddTab($wnd)
	$oTaskbarList = 0
EndFunc
Func _DelTab($wnd)
	Local Const $sCLSID_TaskbarList = "{56FDF344-FD6D-11d0-958A-006097C9A090}"
	Local Const $sIID_ITaskbarList = "{56FDF342-FD6D-11d0-958A-006097C9A090}"
	Local Const $sTagITaskbarList = "HrInit hresult(); AddTab hresult(hwnd); DeleteTab hresult(hwnd); ActivateTab hresult(hwnd); SetActiveAlt hresult(hwnd);"
	; Create the object.
	Local $oTaskbarList = ObjCreateInterface($sCLSID_TaskbarList, $sIID_ITaskbarList, $sTagITaskbarList)
	; Initialize the iTaskbarList object.
	$oTaskbarList.HrInit()
	$oTaskbarList.DeleteTab($wnd)
	$oTaskbarList = 0
EndFunc

Alles anzeigen

CentuCore

Ne mit $wnd wird das Handle des zu minimierenden Fensters gemeint.
Kriegst du mit WinGetHandle().

Harald654

Super,

dein Script zum verstecken der Anwendung in der Taskleiste funktioniert

Ich hab nur fast die Krise bekommen weil das Programm auf einmal auch minimiert das ausschalten des Bildschirms verhinderte , bis ich festgestellt habe dass nur wenn ich vor dem Minimieren das Programm(Fenster) nicht mehr im Fokus habe (nennt man das so?), die Monitorabschaltung funktioniert^^. Ist wirklich komisch, wenn ich das Programm offen/maximiert habe funktioniert das Abschalten, nur versteckt oder minimiert nicht bzw. nicht richtig, wenn dann hätte ich mit dem gegenteiligen Verhalten gerechnet.

Ich hab mir nun mit WinActivate("[CLASS:Shell_TrayWnd]") vor WinSetState($WKodi, "", @SW_MINIMIZE) beholfen, ist nicht gerade schön und etwas umständlich aber es funktioniert jetzt wenigstens

Mein ganzes Programm:

AutoIt

#include <TrayConstants.au3>
;Create Traymenü-----------------------------------------
Opt("TrayMenuMode", 3) 	; Default tray menu items (Script Paused/Exit) will not be shown.
TraySetClick(16)
$TShow = TrayCreateItem("Show Kodi")
$THide = TrayCreateItem("Hide Kodi")
TrayCreateItem("")
$TKExit = TrayCreateItem("+K Exit")
TrayCreateItem("")
$TExit = TrayCreateItem("Exit")
TraySetState()
TraySetToolTip("Kodi.aHide - klick to show/hide it :)")
Global $sRead, $iSpec
Global $ix, $Itz, $iSmon = 0
Global $iAktiv = 1
;sampling time--------------------------------------------
Global $itw = IniRead(@ScriptDir & "\Kodi-CS.ini", "Timings", "itw", "")
;polling time (-Kodi is still active? / Kodi want visible /Kodi want hide)--------------------
Global $its = IniRead(@ScriptDir & "\Kodi-CS.ini", "Timings", "its", "")
$its = ($its/$itw)
Global $it = $its
;Movimode------------------------------------------------
;~ Global $KMMode = IniRead(@ScriptDir & "\Kodi-CS.ini", "Moviemode", "Kodi_Moviemode_aktiv", "")
IniWrite(@ScriptDir & "\Kodi-CS.ini", "Moviemode", "Kodi_Moviemode_aktiv", 0)
;AutoHide-------------------------------------------------
Global $KHideStart = IniRead(@ScriptDir & "\Kodi-CS.ini", "AutoHide", "Hide_Kodi_at_Start", "")
;Pfad von Kodi--------------------------------------------
Global $KodiPfad = IniRead(@ScriptDir & "\Kodi-CS.ini", "Verzeichnis", "Kodi_Pfad", "")
Global $KGUISetPfad = IniRead(@ScriptDir & "\Kodi-CS.ini", "Verzeichnis", "Kodi_GUISet_Pfad", "")
Global $sSearch = IniRead(@ScriptDir & "\Kodi-CS.ini", "Verzeichnis", 'sSearch', "")
Global $sReplace = IniRead(@ScriptDir & "\Kodi-CS.ini", "Verzeichnis", 'sReplace', "")
;Shortcuts------------------------------------------------
Global $SCShow = IniRead(@ScriptDir & "\Kodi-CS.ini", "Shortcuts", "SCShow", "")
Global $SCHide = IniRead(@ScriptDir & "\Kodi-CS.ini", "Shortcuts", "SCHide", "")
;Setzte Shortcuts----------------------------------------
If $SCHide = $SCShow Then
HotKeySet($SCShow, "_SCSh")
Else
HotKeySet($SCShow, "_SCShow")
HotKeySet($SCHide, "_SCHide")
Endif
;Aufruf-------------------------------------------------
If DllCall("user32.dll", "int", "GetSystemMetrics", "int", 80)[0] = 2 then
	$iSmon = 1
	Local $sRead = FileRead($KGUISetPfad)
	If StringInStr($sRead, $sSearch) Then
		Local $fH = FileOpen($KGUISetPfad, 2)
		FileWrite($fH, StringReplace($sRead, $sSearch, $sReplace))
		FileClose($fH)
	EndIf
endif
If $KHideStart = 0 then
	Global $Kodi = run ($KodiPfad)
	Global $WKodi = WinWait("[CLASS:Kodi]","", 20)		; Wait for start of Kodi (max 20s)
	_SCShow()
else
	Global $Kodi = run ($KodiPfad)
	Global $WKodi = WinWait("[CLASS:Kodi]","", 20)		; Wait for start of Kodi (max 20s)
	_SCHide()
endif
;Abfrageschleife---------------------------------------
While Sleep ($itw)
;TrayMenü----------------------------------------------
	$msg = TrayGetMsg()
	Select
		Case $msg = $TKExit
				Winclose($WKodi, "")
				If $iSpec = 0 and $iAktiv = 0 then
					run ("C:\Windows\System32\DisplaySwitch.exe /external")
				endif
				For $it = 0 to 200
					If not ProcessExists($Kodi) then
						ExitLoop
					endif
					Sleep (200)
				Next
					ProcessClose($Kodi)
				Exit
		Case $msg = $TExit
			Exit
		Case $msg = $THide
			_SCHide()
		Case $msg = $TShow
			_SCShow()
		Case $msg = $TRAY_EVENT_PRIMARYDOWN
			If $ix = 1 then
				_SCHide()
			Else
				_SCShow()
			endif
	EndSelect
If $it >= $its Then
	$it = 0
	;Wenn Kodi beendet, auch TrayProg beenden------------------
	If $Itz >= 8 then
		$Itz=0
		If not ProcessExists($Kodi) then
			If not ProcessExists("Kodi.exe") then
				If $iSpec = 0 then
					run ("C:\Windows\System32\DisplaySwitch.exe /external")
				endif
				Exit
			endif
		endif
	Else
		$Itz = ($Itz+1)
	EndIf
	;erweitern und Kodi auf diesem anzeigen-------------------
	If $iAktiv = 1 Then
		If IniRead(@ScriptDir & "\Kodi-CS.ini", "Moviemode", "Kodi_Moviemode_aktiv", "") = 1 then
			$iAktiv = 0
			IniWrite(@ScriptDir & "\Kodi-CS.ini", "Moviemode", "Kodi_Moviemode_aktiv", 0)
			If $iSmon = 0 then
				If DllCall("user32.dll", "int", "GetSystemMetrics", "int", 80)[0] = 1 then
					$iSpec = 0
					run ("C:\Windows\System32\DisplaySwitch.exe /extend")
					Sleep(1500)
				Else
					$iSpec = 1
				endif
			endif
			_SCShow()
			If $iSmon = 0 then								
				WinMove($WKodi, "", -1920, 0,1920, 1080)	
			endif											
		EndIf
	;Minimieren und nach rechts verschieben------------------
	elseif $iAktiv = 0 then
		If WinGetState ( $WKodi,"")	= "23" Then
			$iAktiv = 1									
			If $iSmon = 0 Then
				WinMove($WKodi, "", 0, 0,1920, 1080)
				If $iSpec = 0 then
					run ("C:\Windows\System32\DisplaySwitch.exe /external")
				endif
			endif
		endif
	endif
Else
	$it = ($it+1)
EndIf
WEnd
;___________________________________________________
Func _SCSh()
	If $ix = 1 then
		_SCHide()
	Else
		_SCShow()
	endif
EndFunc
Func _SCShow()
			$ix = 1
			TraySetIcon("iShow.ico", 0)
			TraySetToolTip("Kodi is visible -click to hide it ;)")
	WinSetState($WKodi, "", @SW_MAXIMIZE)
	Local Const $sCLSID_TaskbarList = "{56FDF344-FD6D-11d0-958A-006097C9A090}"
	Local Const $sIID_ITaskbarList = "{56FDF342-FD6D-11d0-958A-006097C9A090}"
	Local Const $sTagITaskbarList = "HrInit hresult(); AddTab hresult(hwnd); DeleteTab hresult(hwnd); ActivateTab hresult(hwnd); SetActiveAlt hresult(hwnd);"
	; Create the object.
	Local $oTaskbarList = ObjCreateInterface($sCLSID_TaskbarList, $sIID_ITaskbarList, $sTagITaskbarList)
	; Initialize the iTaskbarList object.
	$oTaskbarList.HrInit()
	$oTaskbarList.AddTab($WKodi)
	$oTaskbarList = 0
	;WinMove($wnd, "", -1920, 0,1920, 1080)
EndFunc
Func _SCHide()
			$ix = 0
			TraySetIcon("iHide.ico", 0)
			TraySetToolTip("Kodi is hidden :) -click to show it!")
	WinActivate("[CLASS:Shell_TrayWnd]")
	WinSetState($WKodi, "", @SW_MINIMIZE)
	Local Const $sCLSID_TaskbarList = "{56FDF344-FD6D-11d0-958A-006097C9A090}"
	Local Const $sIID_ITaskbarList = "{56FDF342-FD6D-11d0-958A-006097C9A090}"
	Local Const $sTagITaskbarList = "HrInit hresult(); AddTab hresult(hwnd); DeleteTab hresult(hwnd); ActivateTab hresult(hwnd); SetActiveAlt hresult(hwnd);"
	; Create the object.
	Local $oTaskbarList = ObjCreateInterface($sCLSID_TaskbarList, $sIID_ITaskbarList, $sTagITaskbarList)
	; Initialize the iTaskbarList object.
	$oTaskbarList.HrInit()
	$oTaskbarList.DeleteTab($WKodi)
	$oTaskbarList = 0
EndFunc

Alles anzeigen

Falls jemand noch etwas einfällt um das Ganze eleganter zu lösen,
oder allgein Verbesserungsvorschläge zu meinem Programm/Programmierstil hat (vorallem um die CPU belastung zu veringern),
immer her damit

Danke für eure Hilfe,