GDI+ & LAYERED Window == Keine Live Preview?

Taz77

Hallo zusammen, mich beschäftigt seit Tagen schon ein Problem welches ich leider nicht gelöst bekomme
(Hätte ich mal nicht mit den GDI+ zeug angefangen )

Das Problem ist das der Inhalt von der zweiten Gui nicht in der Live Preview angezeigt wird, sobald das Fenster Minimiert ist.

So sollte es aussehen:

Und wenn ich die Gui minimiere sieht es leider so aus:

Hier mal der Dazugehörige beispiel AutoIt Code:

AutoIt

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>


Func _SetBmp($hGUI, $hImage, $iWidth, $iHeight, $iOpacity = 255)
	Local $hScrDC = _WinAPI_GetDC($hGUI)
	Local $hMemDC = _WinAPI_CreateCompatibleDC($hScrDC)
	Local $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
	Local $hOld = _WinAPI_SelectObject($hMemDC, $hBitmap)
	Local $tSize = DllStructCreate("long X;long Y")
	Local $pSize = DllStructGetPtr($tSize)
	DllStructSetData($tSize, "X", $iWidth)
	DllStructSetData($tSize, "Y", $iHeight)


	Local $tSource = DllStructCreate("long X;long Y")
	Local $pSource = DllStructGetPtr($tSource)
	Local $tBlend = DllStructCreate("byte Op;byte Flags;byte Alpha;byte Format")
	Local $pBlend = DllStructGetPtr($tBlend)
	DllStructSetData($tBlend, "Alpha", $iOpacity)
	DllStructSetData($tBlend, "Format", 1)


	_WinAPI_UpdateLayeredWindow($hGUI, $hScrDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, 0x02)
	_WinAPI_ReleaseDC(0, $hScrDC)
	_WinAPI_SelectObject($hMemDC, $hOld)
	_WinAPI_DeleteObject($hBitmap)
	_WinAPI_DeleteDC($hMemDC)
EndFunc


Func _DrawItems(ByRef $hImage, $iWidth, $iHeight, $hGui)
	Local $hWindow = _GDIPlus_GraphicsCreateFromHWND($hGui)
	Local $hBmp = _GDIPlus_BitmapCreateFromGraphics($iWidth, $iHeight, $hWindow)
	Local $hGraphic = _GDIPlus_ImageGetGraphicsContext($hBmp)
	Local $hBrush = _GDIPlus_LineBrushCreateFromRect(_GDIPlus_RectFCreate(0, 0, $iWidth, $iHeight), 0xFF009917, 0xFF0F6029, 1)


	_GDIPlus_GraphicsFillRect($hGraphic, 0, 0, $iWidth, $iHeight, $hBrush)
	_GDIPlus_GraphicsDrawImageRect($hGraphic, $hImage, 0, 0, 92, 90)


	_GDIPlus_BrushDispose($hBrush)
	_GDIPlus_GraphicsDispose($hGraphic)
	_GDIPlus_GraphicsDispose($hWindow)


	Return $hBmp
EndFunc




_GDIPlus_Startup()


Global $Image = _GDIPlus_ImageLoadFromFile(StringRegExpReplace(@AutoItExe, "(?i)AutoIt(?:[\dx_]+)\.exe", "Examples\\GUI\\Torus.png"))
Global $Width = 400, $Height = 300
Global $Clone = _GDIPlus_BitmapCloneArea($Image, 0, 0, 92, 90, $GDIP_PXF32ARGB)
Global $Gui = GUICreate("Test Gui", $Width, $Height, -1, -1, BitOR($WS_POPUP, $WS_GROUP, $WS_SYSMENU), $WS_EX_LAYERED)
Global $Bmp = _DrawItems($Clone, $Width, $Height, $Gui)


_SetBmp($Gui, $Bmp, $Width, $Height)
_GDIPlus_ImageDispose($Image)
_GDIPlus_ImageDispose($Bmp)


Global $Child = GUICreate("", $Width-10, $Height-10, 10, 10, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_MDICHILD), $Gui)
GUISetBkColor(0x000000, $Child)
_WinAPI_SetLayeredWindowAttributes($Child, 0x000000, 255)


GUICtrlCreateLabel("Wo ist der Text und der Button, in der Live Vorschau, wenn das Fenster Minimiert ist?", 1, 94, 360, 152, $WS_BORDER)
GUICtrlSetFont(-1, 24, 800)
GUICtrlSetColor(-1, 0xEEEEEE)
Global $BtnExit = GUICtrlCreateButton("Beenden", 150, 256, 100, 25)
Global $BtnMinimize = GUICtrlCreateButton("Minimieren", 260, 256, 100, 25)




GUISetState(@SW_SHOW, $Gui)
GUISetState(@SW_SHOW, $Child)


While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE, $BtnExit
			ExitLoop
		Case $BtnMinimize
			WinSetState($Gui, "", @SW_MINIMIZE)
	EndSwitch
WEnd


_GDIPlus_Shutdown()
GUIDelete($Gui)
GUIDelete($Child)

Alles anzeigen

Ich hoffe ihr könnt mir weiterhelfen

**UEZ**

Warum im Vorschaufenster der Text nicht angezeigt wird, weiß ich nicht, aber du könntest den Text in das Bild schreiben, so dass du keine 2. GUI benötigst.

Taz77

Das hier ist ja nur ein kleines Beispiel.
In Wirklichkeit handelt es sich ja um eine komplexere Gui mit ganz vielen unterschiedlichen Elementen, und nicht einfach nur um einen Text.
(Select, Listen zig Buttons usw.)

Taz77

Zitat von UEZ

Warum im Vorschaufenster der Text nicht angezeigt wird, weiß ich nicht...

Ps: Es macht mir ihrgentwie Angst wenn eine Foren Legende wie UEZ so was schreibt

**UEZ**

Probiere es mal damit:

AutoIt

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>


_GDIPlus_Startup()


Global Const $STM_SETIMAGE = 0x0172
Global $Image = _GDIPlus_ImageLoadFromFile(StringRegExpReplace(@AutoItExe, "(?i)AutoIt(?:[\dx_]+)\.exe", "Examples\\GUI\\Torus.png"))
Global $Width = 400, $Height = 300
Global $Gui = GUICreate("Test Gui", $Width, $Height, -1, -1, BitOR($WS_POPUP, $WS_GROUP, $WS_SYSMENU))
Global $iPic_Bg = GUICtrlCreatePic("", 0, 0, $Width, $Height)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $hBrush = _GDIPlus_LineBrushCreateFromRect(_GDIPlus_RectFCreate(0, 0, $Width, $Height), 0xFF009917, 0xFF0F6029, 1)
Global $hBitmap = _GDIPlus_BitmapCreateFromScan0($Width, $Height)
Global $hGraphic = _GDIPlus_ImageGetGraphicsContext($hBitmap)
_GDIPlus_GraphicsFillRect($hGraphic, 0, 0, $Width, $Height, $hBrush)
_GDIPlus_GraphicsDrawImageRectRect($hGraphic, $Image, 0, 0, 92, 90, 0, 0, 92, 90)
Global $hBitmap_GDI = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)
_WinAPI_DeleteObject(GUICtrlSendMsg($iPic_Bg, $STM_SETIMAGE, $IMAGE_BITMAP, $hBitmap_GDI))
_GDIPlus_ImageDispose($Image)
_GDIPlus_BrushDispose($hBrush)
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_ImageDispose($hBitmap)


GUICtrlCreateLabel("Wo ist der Text und der Button, in der Live Vorschau, wenn das Fenster Minimiert ist?", 1, 94, 360, 152, $WS_BORDER)
GUICtrlSetFont(-1, 24, 800, 0, "Arial", 5)
GUICtrlSetColor(-1, 0xEEEEEE)
GUICtrlSetBkColor(-1, -2)
Global $BtnExit = GUICtrlCreateButton("Beenden", 150, 256, 100, 25)
Global $BtnMinimize = GUICtrlCreateButton("Minimieren", 260, 256, 100, 25)


GUISetState(@SW_SHOW, $Gui)


While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE, $BtnExit
			ExitLoop
		Case $BtnMinimize
			WinSetState($Gui, "", @SW_MINIMIZE)
	EndSwitch
WEnd


_WinAPI_DeleteObject($hBitmap_GDI)
_GDIPlus_Shutdown()
GUIDelete($Gui)

Alles anzeigen

Zitat von Taz77

Ps: Es macht mir ihrgentwie Angst wenn eine Foren Legende wie UEZ so was schreibt

Arbeite ich bei MS?

Taz77

Zitat von UEZ

Arbeite ich bei MS?

hihi
Danke für deinen Lösungs Vorschlag, das Problem dabei ist aber leider, das die Gui nicht mehr Transparent ist
Deswegen musste ich ja, mit der zweiten Gui und _WinAPI_SetLayeredWindowAttributes arbeiten.
Aber ich glaube ich hatte auch vergessen zu erwähnen, das die Gui Transparent bleiben muss.

**UEZ**

Da du nur sehr wage die tatsächliche GUI beschreibst, ist es sehr schwer dir richtig zu helfen.

Vielleicht zeigst du uns mal, wie die tatsächliche GUI aussieht, so dass wir nicht "umsonst" Zeit verschwenden.

Taz77

Ich bin halt gerade dabei, mir einen eigenen flexiblen Gui Style zu erstellen.
Dabei wird die Umrandung, also der Rahmen aus einer png Datei mittels _GDIPlus_BitmapCloneArea geschnitten, und flexibel auf die Größe angepasst.
Ein Teil für die Ecke Oben links, Oben Mitte x mal wiederholt, Oben Rechts, usw...

Das Script was ich im ersten Post eingefügt habe war ja, als einfache Demonstration gedacht, welches mein Problem sichtbar macht, und sich auf das wesentliche beschränkt,
da ich nicht direkt 700 Zeilen Code Posten wollte, und das ganze zu unübersichtlich wird, und mir keiner mehr helfen kann

Sorry nochmal, das ich die Transparenz vergessen hatte zu erwähnen.

Edit: Beispiel Bild, und Code im nächsten Post

Taz77

Hier noch mal ein anderes Beispiel, welches mein vorhaben besser verdeutlichen sollte.
(Ich weiß das es nicht perfekt ist )

Beispiel - Bild:
_Frage2-Gui2.png

Und der dazugehörige Code:

AutoIt

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>


Func _MaxInt($iNum1, $iNum2)
	Return ($iNum1 > $iNum2) ? $iNum1 : $iNum2
EndFunc


Func _SetBmp($hGUI, $hImage, $iWidth, $iHeight, $iOpacity = 255)
	Local $hScrDC = _WinAPI_GetDC($hGUI)
	Local $hMemDC = _WinAPI_CreateCompatibleDC($hScrDC)
	Local $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
	Local $hOld = _WinAPI_SelectObject($hMemDC, $hBitmap)
	Local $tSize = DllStructCreate("long X;long Y")
	Local $pSize = DllStructGetPtr($tSize)
	DllStructSetData($tSize, "X", $iWidth)
	DllStructSetData($tSize, "Y", $iHeight)


	Local $tSource = DllStructCreate("long X;long Y")
	Local $pSource = DllStructGetPtr($tSource)
	Local $tBlend = DllStructCreate("byte Op;byte Flags;byte Alpha;byte Format")
	Local $pBlend = DllStructGetPtr($tBlend)
	DllStructSetData($tBlend, "Alpha", $iOpacity)
	DllStructSetData($tBlend, "Format", 1)


	_WinAPI_UpdateLayeredWindow($hGUI, $hScrDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, 0x02)
	_WinAPI_ReleaseDC(0, $hScrDC)
	_WinAPI_SelectObject($hMemDC, $hOld)
	_WinAPI_DeleteObject($hBitmap)
	_WinAPI_DeleteDC($hMemDC)
EndFunc


Func _DrawItems(ByRef $hImage, $iWidth, $iHeight, $hGui)
	Local Enum $Bitmap, $x, $y, $Width, $Height
	#forceref $x, $y


	Local $aData[9][5] = [[0, 0, 0, 76, 76],[0, 77, 0, 1, 60],[0, 87, 0, 96, 76],[0, 0, 76, 76, 1],[1, 0, 0, 0, 0],  [0, 87, 76, 96, 1],[0, 0, 87, 76, 87],[0, 77, 87, 1, 87],[0, 87, 87, 96, 87]]
	Local $WidthSteps = _MaxInt(Round(($iWidth - ($aData[0][$Width] + $aData[2][$Width])) / $aData[1][$Width], 0), 0)
	Local $HeightSteps = _MaxInt(Round(($iHeight - ($aData[0][$Height] + $aData[6][$Height])) / $aData[3][$Height], 0), 0)
	Local $WidthTotal = $aData[0][$Width] + $aData[2][$Width] + ($WidthSteps * $aData[1][$Width])
	Local $HeightTotal = $aData[0][$Height] + $aData[6][$Height] + ($HeightSteps * $aData[3][$Height])


	Local $hWindow = _GDIPlus_GraphicsCreateFromHWND($hGui)
	Local $hBmp = _GDIPlus_BitmapCreateFromGraphics($WidthTotal, $HeightTotal, $hWindow)
	Local $hGraphic = _GDIPlus_ImageGetGraphicsContext($hBmp)
	Local $hBrush = _GDIPlus_LineBrushCreateFromRect(_GDIPlus_RectFCreate(0, 0, $iWidth, $iHeight), 0xFF009917, 0xFF0F6029, 1)




	For $i = 0 To UBound($aData) - 1
		If $aData[$i][0] <> 1 Then
			$aData[$i][0] = _GDIPlus_BitmapCloneArea($hImage, $aData[$i][1], $aData[$i][2], $aData[$i][3], $aData[$i][4], $GDIP_PXF32ARGB)
		EndIf
	Next


	_GDIPlus_GraphicsFillRect($hGraphic, 30, 30, $iWidth-80, $iHeight-70, $hBrush)


	; Left: Top, Bottom
	_GDIPlus_GraphicsDrawImageRect($hGraphic, $aData[0][$Bitmap], 0, 0, $aData[0][$Width], $aData[0][$Height])
	_GDIPlus_GraphicsDrawImageRect($hGraphic, $aData[6][$Bitmap], 0, $HeightTotal-$aData[6][$Height], $aData[6][$Width], $aData[6][$Height])


	; Right: Top, Bottom
	_GDIPlus_GraphicsDrawImageRect($hGraphic, $aData[2][$Bitmap], $WidthTotal-$aData[2][$Width], 0, $aData[2][$Width], $aData[2][$Height])
	_GDIPlus_GraphicsDrawImageRect($hGraphic, $aData[8][$Bitmap], $WidthTotal-$aData[8][$Width], $HeightTotal-$aData[8][$Height], $aData[8][$Width], $aData[8][$Height])


	; Center: Top, Bottom
	For $i = 0 To $WidthSteps - 1
		_GDIPlus_GraphicsDrawImageRect($hGraphic, $aData[1][$Bitmap], $aData[0][$Width] + ($i * $aData[1][$Width]), 0, $aData[1][$Width], $aData[1][$Height])
		_GDIPlus_GraphicsDrawImageRect($hGraphic, $aData[7][$Bitmap], $aData[3][$Width] + ($i * $aData[7][$Width]), $HeightTotal - $aData[7][$Height], $aData[7][$Width], $aData[7][$Height])
	Next


	; Center: Left, Right
	For $i = 0 To $HeightSteps - 1
		_GDIPlus_GraphicsDrawImageRect($hGraphic, $aData[3][$Bitmap], 0, $aData[0][$Height] + ($i * $aData[3][$Height]), $aData[3][$Width], $aData[3][$Height])
		_GDIPlus_GraphicsDrawImageRect($hGraphic, $aData[5][$Bitmap], $WidthTotal - $aData[5][$Width], $aData[2][$Height] + ($i * $aData[5][$Height]), $aData[5][$Width], $aData[5][$Height])
	Next


	For $i = 0 To UBound($aData) - 1
		If $aData[$i][0] <> 1 Then
			_GDIPlus_ImageDispose($aData[$i][0])
		EndIf
	Next


	_GDIPlus_BrushDispose($hBrush)
	_GDIPlus_GraphicsDispose($hGraphic)
	_GDIPlus_GraphicsDispose($hWindow)


	Return $hBmp
EndFunc




_GDIPlus_Startup()


Global $Image = _GDIPlus_ImageLoadFromFile(StringRegExpReplace(@AutoItExe, "(?i)AutoIt(?:[\dx_]+)\.exe", "Examples\\GUI\\Torus.png"))
Global $Width = 500, $Height = 300
Global $Gui = GUICreate("Test Gui", $Width, $Height, -1, -1, BitOR($WS_POPUP, $WS_GROUP, $WS_SYSMENU), $WS_EX_LAYERED)
Global $Bmp = _DrawItems($Image, $Width, $Height, $Gui)


_SetBmp($Gui, $Bmp, $Width, $Height)
_GDIPlus_ImageDispose($Image)
_GDIPlus_ImageDispose($Bmp)


Global $Child = GUICreate("", $Width-10, $Height-10, 10, 10, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_MDICHILD), $Gui)
GUISetBkColor(0x000000, $Child)
_WinAPI_SetLayeredWindowAttributes($Child, 0x000000, 255)


GUICtrlCreateLabel("Where is the text and the buttons in the Live Preview, when the window is minimized?", 50, 58, 360, 152)
GUICtrlSetFont(-1, 22, 800, 0, "Comic Sans Ms")
GUICtrlSetColor(-1, 0xEEEEEE)
Global $BtnExit = GUICtrlCreateButton("Exit", 140, 222, 100, 25)
Global $BtnMinimize = GUICtrlCreateButton("Minimize", 250, 222, 100, 25)


GUISetState(@SW_SHOW, $Gui)
GUISetState(@SW_SHOW, $Child)


While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE, $BtnExit
			ExitLoop
		Case $BtnMinimize
			WinSetState($Gui, "", @SW_MINIMIZE)
	EndSwitch
WEnd


_GDIPlus_Shutdown()
GUIDelete($Gui)
GUIDelete($Child)

Alles anzeigen