Rekursives durchsuchen der Registry nach einem DWORD Namen

lumb

Hallo zusammen,

gestern habe ich mir fast die Finger gebrochen als ich folgendes versucht habe:

Die Registy soll ab einem bestimmten Zweig, zB HKLM64/Software/Zend alle Einträge (nicht Schlüssel, sondern Words) finden die zB Product heißen und den darin befindlichen Wert fortlaufend als String speichern. Wobei die Unterstruktur des Einstiefpunktes immer anders bzw unklar ist und der Wert Product öfters vorkommt.

Das Problem was ich habe ist das mit der Rekursiv, also dass erst alle Einträge im Ordner, dann alle Ordner im Ordner usw. durchsucht werden ohne dass man vorher weiss wieviele es gibt.

Kann mir da jemand auf die Sprünge helfen - toll wäre ja mit einem Codeansatz der durch den ganzen Registry Zweig geht....

Danke
lumb

**Oscar**

Da hatte ich mal zwei Funktionen geschrieben:

AutoIt

MsgBox(0, 'Key-Search', _RegKeySearch('HKEY_LOCAL_MACHINE', 'AutoIt v3'))
MsgBox(0, 'Val-Search', _RegValSearch('HKEY_LOCAL_MACHINE', 'v3.3.14.0'))


Func _RegKeySearch($sRegPath, $sKeySearch)
	Local $sKey, $ret, $i = 0
	While True
		$i += 1
		$sKey = RegEnumKey($sRegPath, $i)
		If $sKey == $sKeySearch Then Return $sRegPath & '\' & $sKey
		If @error Then ExitLoop
		$ret = _RegKeySearch($sRegPath & '\' & $sKey, $sKeySearch)
		If $ret <> '' Then ExitLoop
	WEnd
	Return $ret
EndFunc


Func _RegValSearch($sRegPath, $sValSearch)
	Local $sKey, $sVal, $sVar, $ret, $i = 0, $j = 0
	While True
		$i += 1
		$sKey = RegEnumKey($sRegPath, $i)
		If @error Then ExitLoop
		$ret = _RegValSearch($sRegPath & '\' & $sKey, $sValSearch)
		If $ret <> '' Then ExitLoop
		$j = 0
		While True
			$j += 1
			$sVal = RegEnumVal($sRegPath & '\' & $sKey, $j)
			If @error Then ExitLoop
			$sVar = RegRead($sRegPath & '\' & $sKey, $sVal)
			If $sVar == $sValSearch Then Return $sRegPath & '\' & $sKey & '\' & $sVal
		WEnd
	WEnd
	Return $ret
EndFunc

Alles anzeigen

**AspirinJunkie**

Klar könnte man das ganze mit AutoIt rekursiv aufziehen.
Aber warum nicht gleich auf die hierfür gedachten Windows-Bordmittel zurückgreifen.
Es gibt da z.B. den schönen Kommandozeilenbefehl "REG QUERY":

AutoIt

#include <Array.au3>


$s_Result = RunCmd("REG QUERY HKLM\SOFTWARE /v Product /s /t REG_DWORD")


$a_Results = StringRegExp($s_Result, "(?m)^(HKEY.+)$\s+(\w+)\s+(REG_\w+)\s+(.+)$", 4)
For $Match in $a_Results
	_ArrayDisplay($Match)
Next










Func RunCmd(Const $s_Cmd, $WorkDir = @WorkingDir)
	Local $iPID = Run($s_Cmd, $WorkDir, @SW_HIDE, 2 + 4)
	If @error Then Return SetError(1, @error, "")


	Local $s_Ret, $s_Line, $s_Err


	Do
		$s_Line = StdoutRead($iPID)
		If @extended > 0 Then $s_Ret &= $s_Line
	Until @error


	Do
		$s_Line = StderrRead($iPID)
		If @extended > 0 Then $s_Err &= $s_Line
	Until @error


	If $s_Err <> "" Then
		If $s_Ret <> "" Then Return SetError(2, 0, "------- StdOut -----------" & @CRLF & $s_Ret & @CRLF & @CRLF & "------- StdErr -----------" & @CRLF & $s_Err)
		Return SetError(3, 0, $s_Err)
	EndIf
	Return $s_Ret
EndFunc   ;==>RunCmd

Alles anzeigen