exe icon als Bild auf GUI

Gremlin78

Hallo Leute,
ich würde gern das Icon, dass ich über

AutoIt

#AutoIt3Wrapper_Icon=icon.ico

eingebunden habe auf meiner Info GUI als Bild verwenden. So hab ichs schon versucht aber ohne Ergebnis.

AutoIt

GUICtrlCreatePic($bild,200,100,48,48)
GUICtrlSetImage(-1, @ScriptFullPath, 0)

Ne andere Idee war diese aber auch ohne Erfolg.

Spoiler anzeigen

AutoIt

Global $hIcon1 = __WinAPI_ShellExtractIcons(@ScriptFullPath, 0, 48, 48)
GUICtrlCreateIcon($bild,$hIcon1,120,120,48,48)


Func __WinAPI_ShellExtractIcons($sIcon, $iIndex, $iWidth, $iHeight)
    Local $Ret = DllCall('shell32.dll', 'int', 'SHExtractIconsW', 'wstr', $sIcon, 'int', $iIndex, 'int', $iWidth, 'int', $iHeight, 'ptr*', 0, 'ptr*', 0, 'int', 1, 'int', 0)
    If (@error) Or ($Ret[0] = 0) Or ($Ret[5] = Ptr(0)) Then Return SetError(1, 0, 0)
    Return $Ret[5]
EndFunc   ;==>__WinAPI_ShellExtractIcons

Hättet ihr ne Idee?
Danke, Gruß Gremlin

**UEZ**

Probiere es mal so:

AutoIt

#pragma compile(Icon, "c:\Program Files (x86)\AutoIt3\Icons\MyAutoIt3_Green.ico")
#AutoIt3Wrapper_UseX64=y


#include <GuiConstantsEx.au3>
#include <WinAPIShellEx.au3>
#include <WinAPIGdi.au3>


Global Const $STM_SETIMAGE = 0x0172
Global Const $hIcon = _WinAPI_ShellExtractIcon(@AutoItExe, 0, 48, 48)
Global Const $hBmp = _WinAPI_Create32BitHBITMAP($hIcon, False, True)


Global Const $hGUI = GUICreate("Test", 300, 400)
Global Const $iPic = GUICtrlCreatePic("", 100, 100, 48, 48)
_WinAPI_DeleteObject(GUICtrlSendMsg($iPic, $STM_SETIMAGE, $IMAGE_BITMAP, $hBmp))
GUISetState()


Do
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			_WinAPI_DeleteObject($hBmp)
			GUIDelete()
			Exit
	EndSwitch
Until False

Alles anzeigen

Gremlin78

Wow, Danke. Das klappt.
Noch ne zweite Frage, wenn ich eine 32 und eine 64 bit Variante erstellen lasse, erhält nur die 32 bit Version das eingebundene Icon.
Ist es auch möglich die 64er Version mit dem Icon zu versehen?
Gruß Gremlin

**UEZ**

Mit

AutoIt

#pragma compile(Icon, "c:\Program Files (x86)\AutoIt3\Icons\MyAutoIt3_Green.ico")
#AutoIt3Wrapper_UseX64=y

sollte es auch funzen. Getestet auf Win 8.1 x64.

Gremlin78

Vielen Dank nochmals,
#pragma war mir bisher unbekannt, funktioniert alles super.
Endlich der große Erfolg.
Gruß Gremlin