GUICtrlSetBkColor auf Combo funktioniert nicht

mirko2002

Guten Morgen alle zusammen,

ich habe derzeit das Problem, dass GUICtrlSetBkColor auf ein Combo nicht reagiert.

Der Befehl schaut ganz simpel so aus:

GUICtrlSetBkColor($combo_anrede, 0x0000FF)

Letzendlich prüft mein Tool, ob bei klick auf ein Button, im Combofeld etwas ausgewählt wurde. Wenn nicht, soll der User einen Fehler erhalten - momentan durch eine MessageBox gelöst. Ich will davon aber wegkommen und wollte lieber das Control rot einfärben lassen.

Laut AutoIT Funktionsreferenz färbt GUICtrlSetBkColor auch Combo Controls ein - leider macht er das bei mir überhaupt nicht... irgendeine Idee warum ihn der Code nicht die Bohne interessiert? Er gibt keinen Fehler im Script aus - er arbeitet mein Skript ab ohne die Zeile zu beachten bzw umzusetzen.

LG
Mirko

**autoiter**

Hallo,
du musst wahrscheinlich mal deinen Code zeigen.
Prinzipiell funktioniert das nämlich.

mirko2002

So soll es sein

Snip:

AutoIt

$WinTitle = " BDG Mail " & $version
$GUI = GUICreate($WinTitle, 500, 230)
GUISetBkColor(0xdfddff)


GUICtrlCreateGroup("", 12, 0, 475, 192)
GUICtrlSetFont(-1, 8, 800, 0, "Verdana")


$combo_anrede = GUICtrlCreateCombo("Anrede auswählen:", 20, 15, 115, -1, $CBS_DROPDOWNLIST)
GUICtrlSetData(-1, "Sehr geehrter Herr |Sehr geehrte Frau ", "")
$input_anrede = GUICtrlCreateInput("", 140, 15, 100, 21)
GUICtrlSetState($input_anrede, $GUI_HIDE)
$input_phone = GUICtrlCreateInput("Telefonnummer", 250, 15, 105, 21)
$combo_customer_type = GUICtrlCreateCombo("Kundentyp:", 362, 15, 115, -1, $CBS_DROPDOWNLIST)
GUICtrlSetData(-1, "Private |Business", "")
$input = GUICtrlCreateEdit("", 20, 50, 457, 120, BitOR($WS_VSCROLL, $ES_MULTILINE, $ES_AUTOVSCROLL, $ES_WANTRETURN))
$button_input = GUICtrlCreateButton("Mediatrix Mail erstellen", 190, 200, 120, 19)


GUISetState(@SW_SHOW, $GUI)


While 1


	$read_anrede = GUICtrlRead($combo_anrede)
	If $read_anrede = "Sehr geehrter Herr " Then
		GUICtrlSetState($input_anrede, $GUI_SHOW)
		Sleep(50)
	ElseIf $read_anrede = "Sehr geehrte Frau " Then
		GUICtrlSetState($input_anrede, $GUI_SHOW)
		Sleep(50)
	Else
		GUICtrlSetState($input_anrede, $GUI_HIDE)
	EndIf


	$msg = GUIGetMsg(1)
		Switch $msg[0]
			Case $GUI_EVENT_PRIMARYDOWN
				If $phone = 0 Then
					$cInfo = GUIGetCursorInfo()
					If IsArray($cInfo) Then
						If $cInfo[4] = $input_phone Then
							GUICtrlSetData($input_phone, "")
							$phone = 1
						EndIf
					EndIf
				EndIf
			Case $button_input
				; hier wird der Input ausgelesen
				$read_anrede = GUICtrlRead($combo_anrede)
				$read_customer_type = GUICtrlRead($combo_customer_type)
				$read_input_anrede = GUICtrlRead($input_anrede)
				$read_input_phone = GUICtrlRead($input_phone)
				If $read_anrede = "Sehr geehrter Herr " Or $read_anrede = "Sehr geehrte Frau " Then
					If $read_input_anrede = "" Then
						MsgBox(48, "Hier lief etwas schief...", "Kein Ansprechpartner ausgewählt!")
						_WriteLog("Kein Ansprechpartner ausgewählt. Zeile: " & @ScriptLineNumber)
					Else
						If $read_input_phone = "" Or $read_input_phone = " " Or $read_input_phone = "Telefonnummer" Then
							MsgBox(48, "Hier lief etwas schief...", "Keine Telefonnummer eingetragen!")
							_WriteLog("Keine Telefonnummer eingetragen. Zeile: " & @ScriptLineNumber)
						Else
							If $read_customer_type = "Kundentyp:" Then
								MsgBox(48, "Hier lief etwas schief...", "Keinen Kundentyp ausgewählt!")
								_WriteLog("Kein Kundentyp ausgewählt. Zeile: " & @ScriptLineNumber)
							Else
								; rufe die _replace() Funktion auf
								_replace()
							EndIf
						EndIf
					EndIf
				Else
					GUICtrlSetBkColor($combo_anrede, 0x0000FF)
					MsgBox(48, "Hier lief etwas schief...", "Keine Anrede ausgewählt!")
					_WriteLog("Keine Anrede ausgewählt. Zeile: " & @ScriptLineNumber)
				EndIf
			Case $GUI_EVENT_CLOSE
				Exit
		EndSwitch
WEnd

Alles anzeigen

Egal ob ich das SetBKColor direkt schon ganz oben unter dem Control haue oder erst unten in die Whileschleife beim Fehelr - er machts einfach nicht...

**autoiter**

Der Befehl färbt nicht den ausgeklappten Bereich, sondern den ersten Inhalt. Den hast du aber schon mit dem Style $CBS_DROPDOWNLIST belegt. Daher klappt das nicht.
Du müsstest den Style entfernen.

mirko2002

Ach na das ist ja doof. Der Style soll so bestehen bleiben, weil es die Art DropDown Menü ist die ich benötige.

Das heisst ich kann es also vergessen, dass ganze Control zu färben?

**autoiter**

Hier können sicher noch qualifiziertere Antworten als meine kommen. Also warte noch ab.
Alternativ könntest du ja ein rotes Label als Rahmen oder Unterstreichung um das Control legen. (Ist für die Lesbarkeit vllt. auch besser).
Es geht dir ja nur um den Hinweis, wo die Leute jetzt hinklicken sollen.

mirko2002

Korrekt...

ich hatte hier auch schon Threads zu gefunden wo Labels rot umrandet wurden. Ich kann sie aber ums verrecken nicht mehr finden. Das war nämlich auch meine erste Idee das so zu machen. Als ich es nicht mehr fand dachte ich an oben genannten Befehl

**Oscar**

Ich würde den Abschicken-Button solange deaktivieren, bis alle Eingaben gemacht worden sind.
Das erspart Dir eine Menge an If-Anweisungen. Im übrigen kann man mit _GUICtrlEdit_SetCueBanner Vorgaben in die Inputfelder schreiben, die beim Klick in das Eingabefeld automatisch verschwinden.

AutoIt

#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <WindowsConstants.au3>


$WinTitle = " BDG Mail "
$GUI = GUICreate($WinTitle, 500, 230)
GUISetBkColor(0xdfddff)


GUICtrlCreateGroup("", 12, 0, 475, 192)
GUICtrlSetFont(-1, 8, 800, 0, "Verdana")


$combo_anrede = GUICtrlCreateCombo("Anrede auswählen:", 20, 15, 115, -1, $CBS_DROPDOWNLIST)
GUICtrlSetData(-1, "Sehr geehrter Herr |Sehr geehrte Frau ", "")
$input_anrede = GUICtrlCreateInput("", 140, 15, 100, 21)
_GUICtrlEdit_SetCueBanner($input_anrede, "Name")
GUICtrlSetState($input_anrede, $GUI_HIDE)
$input_phone = GUICtrlCreateInput("", 250, 15, 105, 21)
_GUICtrlEdit_SetCueBanner($input_phone, "Telefonnummer")
$combo_customer_type = GUICtrlCreateCombo("Kundentyp:", 362, 15, 115, -1, $CBS_DROPDOWNLIST)
GUICtrlSetData(-1, "Private |Business", "")
$input = GUICtrlCreateEdit("", 20, 50, 457, 120, BitOR($WS_VSCROLL, $ES_MULTILINE, $ES_AUTOVSCROLL, $ES_WANTRETURN))
$button_input = GUICtrlCreateButton("Mediatrix Mail erstellen", 190, 200, 120, 19)
GUICtrlSetState($button_input, $GUI_DISABLE)


GUISetState(@SW_SHOW, $GUI)
AdlibRegister("_CheckInput")


While 1
	Switch GUIGetMsg()
		Case $button_input
			MsgBox(0, $WinTitle, "Jetzt kann die Mail verschickt werden! :-)")
		Case $combo_anrede
			If GUICtrlRead($combo_anrede) <> "Anrede auswählen:" Then
				GUICtrlSetState($input_anrede, $GUI_SHOW)
			Else
				GUICtrlSetState($input_anrede, $GUI_HIDE)
			EndIf
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch
WEnd


Func _CheckInput()
	Local $iCheck = 0
	$iCheck += Number(GUICtrlRead($combo_anrede) <> "Anrede auswählen:")
	$iCheck += Number(GUICtrlRead($input_anrede) <> "")
	$iCheck += Number(GUICtrlRead($input_phone) <> "")
	$iCheck += Number(GUICtrlRead($combo_customer_type) <> "Kundentyp:")
	$iCheck += Number(GUICtrlRead($input) <> "")
	If $iCheck = 5 Then
		GUICtrlSetState($button_input, $GUI_ENABLE)
	Else
		GUICtrlSetState($button_input, $GUI_DISABLE)
	EndIf
EndFunc

Alles anzeigen

mirko2002

Hallo Oskar,

danke für den Denkanstoss!

Kann Dein Skript leider nicht testen, da bei mir _GUICtrlEdit_SetCueBanner nicht existiert? Ich habe zwar eine _GUICtrlEdit_Set-Befehle zur Verfügung, aber dieser ist nicht dabei?

//Edit: testen kann ich es halt ohne den CueBanner Befehl... sieht schick aus gefällt mir sogar glatt besser als die blöden Msg-Boxen...

**Kanashius**

Für den grauen text, der verschwindet, tuts auch ein einfaches GUICtrlSendMsg($Control, 0x1501, 0, "Text")