Überprüfen ob GUICTRL aktiv ist

svart

Hallo,

ich würde gerne eine Funktion ausführen, wenn ENTER gedrückt wird und ein Inputfeld aktiv ist.

Beispiel: Wenn ENTER gedrückt wurde und Input1 aktiv ist - soll eine Funktion ausgeführt werden.

C

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>




HotKeySet("{ENTER}","_test")
$Form1 = GUICreate("TESTFENSTER", 234, 100, 237, 163)
$Input1 = GUICtrlCreateInput("", 40, 24, 161, 21)
$Input2 = GUICtrlCreateInput("", 40, 64, 161, 21)
GUISetState(@SW_SHOW)




While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit


	EndSwitch
WEnd


func _test()
	msgbox(0,"","TEST")
EndFunc

Alles anzeigen

svart

Hat sich erledigt,

ich stand auf dem Schlauch

Yjuq

Stell dir folgendes vor:
Jemand sucht nach diesem Problem und stößt auf dem Thread.
Nun kann er nichts hiermit anfangen und sucht weiter, findet noch 3 solche Themen und ist frustriert;
Einfach weil die bösen Threadstarter zu egoistisch waren, ihre eigene gefundenen Lösungen mit der Welt zu teilen.

**Oscar**

Dann will ich hier mal meine Lösung posten:

AutoIt

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>


$Form1 = GUICreate("TESTFENSTER", 234, 100, 237, 163)
$Input1 = GUICtrlCreateInput("", 40, 24, 161, 21)
$Input2 = GUICtrlCreateInput("", 40, 64, 161, 21)
$Dummy = GUICtrlCreateDummy()
GUISetState(@SW_SHOW)
Global $aAccelKeys[1][2] = [["{ENTER}", $Dummy]]
GUISetAccelerators($aAccelKeys)
While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Dummy
			_InputEvent()
	EndSwitch
WEnd


Func _InputEvent()
	Local $hWnd = _WinAPI_GetFocus()
	Switch _WinAPI_GetDlgCtrlID($hWnd)
		Case $Input1
			MsgBox(0, 'Input1', GUICtrlRead($Input1))
		Case $Input2
			MsgBox(0, 'Input2', GUICtrlRead($Input2))
	EndSwitch
EndFunc

Alles anzeigen