Brauche Hilfe bei Skripterstellung

Neucki

Hallo.
Ich habe folgendes Problem:
Mit Autoit befasse ich mich noch nicht lange und besitze auch keine weiteren Pragrammierkenntnisse.
Nun habe ich aber die Aufgabe bekommen ein Skript zu erstellen (was genau siehe Quelltext) und bin gerade am verzweifeln,
da ich mit meinem momentanen Kenntnisstand die Aufgabe nicht erldeigen kann.
Wäre super lieb, wenn mir jemand helfen könnte.
Danke schonmal!

#include <MsgBoxConstants.au3>
#include <FileConstants.au3>
$sFilePath="Test_eingegangene_Aufträge"
ShellExecute ($sFilePath,"","","", @SW_MAXIMIZE)
Sleep (1000)
Local $key=MsgBox ($MB_YESNOCANCEL, "Aufträge", "Möchten Sie die heutigen Aufträge in einen neuen Ordner verschieben?",10)
Local $iTimeout=10

#cs
bin nicht fündig geworden, gibt es einen Befehl, mit dem man beim Test nicht immer das ganze Skript ausführen zu muss?

Problemteil:
Datum der Dateien in Ornder ermitteln und alle Dateien des heutigen Datums kopieren.
Neuen Ordner anlegen und benennen.
Dann heutige Dateien in neuen Ordner verschieben und in Test1, Test2,...Testn umbenennen.
Es soll laufend nach neuen Dateien des heutigen Datums im alten Ordner gesucht werden.
#ce

;Versuch-erster Ansatz:
$FT_STRING= YYYY"/"MM"/"DD ;$FT_STRING kann wahrscheinlich nicht neu definiert werden?
If $key= 6 Then
$result= FileGetTime ("Test_eingegangene_Aufträge", Default, $FT_STRING) ;funktioniert, aber nur wenn ich String nicht als Variable definiere
EndIf
If Not $result= @error Then
MsgBox (0, "", $result) ;Das Ergebnis soll als YYYY/MM/DD und nicht als YYYY/MM/DD/HH/MM/SS dargestellt werden
EndIf
;==> ^ ERROR

;Versuch-zweiter Ansatz:
$Date= @YEAR &"/"& @MON &"/"& @MDAY
If $key= 6 Then
MsgBox (0,"", $Date)
EndIf
;==> gewünschtes Format, nur wie kann ich jetzt die Dateien mit einbinden?

**autoBert**

Hallo Neucki,

herzlich willkommen im Forum.

Wie nur Dateien mit heutigen Datum kopieren? sollte dir bei deinem Skript weiderhelfen.

mfg autoBert

**Kanashius**

Ich habs dir mal geschrieben und kommentiert. Fall du noch Fragen hast, einfach hier posten

Was das "bin nicht fündig geworden, gibt es einen Befehl, mit dem man beim Test nicht immer das ganze Skript ausführen zu muss?" angeht:
Man schreibt Dinge, die sich wiederholen oder oft benutzt werden in Funktionen. Dann muss man weniger schreiben (bzw. C&P) und wenn man was falsch hat und das ändern muss, dann nur an einer Stelle.
Dementsprechend schnell kannst du einen einzelnen Funktionsaufruf recht schnell auskommentieren, sodass nicht immer alles laufen muss.

AutoIt

#include <MsgBoxConstants.au3>
#include <FileConstants.au3>
#include <array.au3>
#include <file.au3>


$sFilePath=@ScriptDir
ShellExecute ($sFilePath,"","","", @SW_MAXIMIZE)
Sleep (1000)
Local $iTimeout=10
Global $dayDate=[@YEAR,@MON,@MDAY]
global $sFileCopyPath=FileSelectFolder("Wähle Ordner zum kopieren",@DesktopDir,1)
;Prüfen ob ein ordner gewählt wurde
If $sFileCopyPath="" then
	MsgBox(16,"Error","Kein Ordner zum kopieren gewählt. Das Programm wird beendet.")
	exit
endif
;Abfragen, ob verschoben werden soll, wenn nicht, einfach beenden
If MsgBox ($MB_YESNOCANCEL, "Aufträge", "Möchten Sie die heutigen Aufträge in einen neuen Ordner verschieben?",10)<>6 then
	Exit
EndIf


;Schleife, damit immer wieder kopiert wird. Wartezeit 1000ms
while sleep(1000);Wartezeit
	_aktDate();aktualisiere das Datum (falls ein anderer Tag ist)
	;Rufe die Dateien ab
	$arFiles=_getFiles()
	;Gib alle Dateien, die verschoben werden müssen
	$arFilesMove=_checkMove($arFiles)
	;Verschiebe alle Dateien, die verschoben werden sollen
	_moveFiles($arFilesMove)
WEnd


Func _moveFiles(ByRef $arFilesMove)
	;Geht das übergebene Array durch und verschiebt die Dateien, dabei wird überschrieben
	for $i=0 to UBound($arFilesMove)-1 step 1
		;Hier kannst du gucken, ob alles so ist wie du möchtest. Wenn ja, dann beim FileMove das ; entfernen (Zeile darunter), dann wird wirklich kopiert.
		MsgBox(48,"",$sFilePath&"\"&$arFilesMove[$i]&@crlf&"	verschieben nach"&@crlf&$sFileCopyPath&"\"&$arFilesMove[$i])
		;Wenn diese Zeile nicht auskommentiert ist, wird kopiert.
		;FileMove($sFilePath&"\"&$arFilesMove[$i],$sFileCopyPath&"\"&$arFilesMove[$i],BitOR(1,8));BitOr(1,8)->überschreibe existierende Datei und erzeuge Ordner, wenn er nicht existiert
	next
EndFunc


;Gibt alle Dateien aus dem Ordner aus (siehe Parameter, wenn auch Ordner,... _FileListToArrayRec gibt auch alle Dateien aus Unterordnern)
Func _getFiles()
	local $arFiles
	$arFiles=_FileListToArray($sFilePath,"*",1)
	;_ArrayDisplay($arFiles)						;nur für dich zum gucken
	;Array mit Dateien wird zurückgegeben
	return $arFiles
EndFunc


Func _checkMove(ByRef $arFiles)
	local $counter,$arFilesMove[UBound($arFiles)]
	;Zähler, wie viele Dateien schon verschoben werden sollen
	$counter=0
	;Gehe das übergebene Array durch und pack alles in ein neues Array, bei dem das Datum passt
	for $i=1 to UBound($arFiles)-1 step 1
		$date=FileGetTime($sFilePath&"\"&$arFiles[$i],1,0)
		if $dayDate[0]=$date[0] and $dayDate[1]=$date[1] and $dayDate[2]=$date[2] then
			$arFilesMove[$counter]=$arFiles[$i]
			;Datei hinzugefügt->counter wird erhöht
			$counter+=1
		endif
	next
	;Array wird auf die passende größe gesetzt. Vorher war es so groß, wie alle Dateien, die in dem Ordner sind
	ReDim $arFilesMove[$counter]
	;gib das Array mit den passenden Dateien zurück
	return $arFilesMove
EndFunc


Func _aktDate()
	;Dem globalen Array $dayDate werden die Werte neu zugewiesen
	Global $dayDate=[@YEAR,@MON,@MDAY]
	#cs
	;Hier ginge auch:
	$dayDate[0]=@YEAR
	$dayDate[1]=@MON
	$dayDate[2]=@MDAY
	#ce
EndFunc

Alles anzeigen

MfG Kanashius. Ich hoffe ich konnte dir helfen

rheims

.............

Neucki

Super, vielen Dank!