Übersicht über das unterbrechen und fortsetzen eines Scripts – sowie der Positionierung des Fensters

AutoMit

Hallo Freunde der automatisierten Schritte,

mir ist bisher erst eine Möglichkeit bekannt, wie ich ein laufendes Skript an einer bestimmten Stelle unterbrechen und wieder fortsetzen kann.

Message Box – msgbox

Dieser Befehl hat den Nachteil, dass er bisher keine Koordinaten zulässt, an dem er erscheint.

Eine weitere Möglichkeit ist eine Oberfläche, GUI, z.B. mit dem „Koda Form Designer“.
Das ist vergleichbar aufwendig, als wenn man mit einer API/DLL die Position der Messagebox umbiegen.

Welche weiteren Möglichkeiten gibt es bei Autoit, ein Skript mit einer Nachricht zu unterbrechen und per Mausklick bzw. Tastatur fortzusetzen?

Ich suche insbesondere all jene Möglichkeiten, bei der das angezeigte Element einfach durch die Angabe von Koordinaten positioniert werden kann.

Viele Grüße
AutoMit

**Oscar**

Schreib Dir Deine eigene MsgBox-UDF, bei der Du die Koordinaten mitgeben kannst.
Dann kannst Du das in Dein Script includen und wie die normale MsgBox verwenden.

**Kanashius**

So würd ich es machen:

AutoIt

Global $closeBreak=false


Func _breakMsg($x,$y,$width,$height,$title,$message)
	$Gui=GuiCreate($title,$width,$height,$x,$y)
	$Label=GuiCtrlCreateLabel($message,5,5,$width-10,$height-10);
	GuiSetState(@SW_SHOW)
	While Sleep(10)
		$msg=GuiGetMsg()
		if $msg=-3 then
			ExitLoop
		endif
	WEnd
	GuiDelete($Gui)
EndFunc


Func _breakEvent($x,$y,$width,$height,$title,$message)
	$Gui=GuiCreate($title,$width,$height,$x,$y)
	$Label=GuiCtrlCreateLabel($message,5,5,$width-10,$height-10);
	GuiSetOnEvent("_exitBreak",-3)
	GuiSetState(@SW_SHOW)
	While NOT $closeBreak
		Sleep(10)
	WEnd
	$closeBreak=false
	GuiDelete($Gui)
EndFunc


Func _exitBreak()
	$closeBreak=true
EndFunc

Alles anzeigen

Können Syntax(/Tipp) Fehler drin sein... Bin grad auf Linux unterwegs.
Kann man dann dementsprechend noch um Buttons, Icons,... Erweitern.

MfG Kanashius

**Oscar**

Hier mal eine Version von mir:

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


$ret = _MsgBoxEx('Titel', 'Script fortsetzen?', -1, 30, 300, 100)
If $ret = 0 Then Exit
MsgBox(0, 'Test', 'Script fortsetzen...')


Func _MsgBoxEx($sTitle = 'MsgBox', $sText = '', $iLeft = -1, $iTop = -1, $iWidth = 320, $iHeight = 240, $hParent = 0)
	Local $iOldGuiMode = Opt('GUIOnEventMode', 0)
	Local $hGui = GUICreate($sTitle, $iWidth, $iHeight, $iLeft, $iTop, BitOR($WS_CAPTION, $WS_POPUPWINDOW), Default, $hParent)
	GUISetIcon('shell32.dll', 211, $hGui)
	GUISetFont(10, 400, 0, 'Arial', $hGui, 5)
	GUICtrlCreateLabel('', 0, 0, $iWidth, $iHeight - 40)
	GUICtrlSetBkColor(-1, 0xFFFFFF)
	GUICtrlCreateLabel($sText, 10, 20, $iWidth - 20, $iHeight - 80)
	GUICtrlSetFont(-1, 12, 400, 0, 'Arial', 5)
	GUICtrlSetBkColor(-1, 0xFFFFFF)
	Local $idYes = GUICtrlCreateButton('Ja', $iWidth - 140, $iHeight - 30, 60, 25, $BS_DEFPUSHBUTTON)
	Local $idNo = GUICtrlCreateButton('Nein', $iWidth - 70, $iHeight - 30, 60, 25)
	If Not $hParent Then TraySetState(2)
	GUISetState(@SW_SHOW, $hGui)
	Local $iReturn = 0
	While True
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE, $idNo
				$iReturn = 0
				ExitLoop
			Case $idYes
				$iReturn = 1
				ExitLoop
		EndSwitch
	WEnd
	GUIDelete($hGui)
	Opt('GUIOnEventMode', $iOldGuiMode)
	Return $iReturn
EndFunc   ;==>_MsgBoxEx

Alles anzeigen