Mehrzeilige Eingabe aus GUI Edit per Tastendruck in Word eingeben

andynbg9000

Hallo liebe Community

Ich hab hier ein echtes Problem. Ich versuche mir ein Tool zu schreiben, mit dessen Hilfe ich mir einen Text, welcher in einer GUI hinterlegt wird, per Knopfdruck auf F4 ausgeben lassen kann.

Das Problem dabei ist, dass in Word/ OpenOffice für jede Zeile eine neue Seite angelegt wird und nicht wie vorhergesehen einfach nur ein {Enter} gesendet wird.

Hier ist mein Code:

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <EditConstants.au3>


global $text
HotKeySet ("{F4}", "startf4")


Opt("GUIOnEventMode", 1)
GUICreate("GUI", 200, 100, -1, -1)
$Input = GUICtrlCreateEdit("",5,5,190,21*3, BitOR($ES_WANTRETURN,$ES_AUTOVSCROLL))
GUICtrlCreateButton("ok", 70, 70, 60, 20)
GUICtrlSetOnEvent(-1, "speichern")
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUISetState()


While 1
	Sleep(100)
WEnd


Func _Exit()
	Exit
EndFunc


Func speichern()
   $text = GUICtrlRead ($Input)
   MsgBox($MB_SYSTEMMODAL,"", "Dein Text wurde auf F4 hinterlegt:" &@CRLF&@CRLF& $text)
EndFunc


Func startf4 ()
   Send ($text)
EndFunc

Alles anzeigen

Ein Beispiel:

Ich gebe in die GUI folgenden Text ein:

hallo
hall
hal

Genau so erwarte ich ihn dann auch wieder in Word, jedoch wird mir für jede Zeile eine neue Seite angelegt...

Wäre Klasse wenn jemand von euch mir da weiterhelfen kann

**autoBert**

Nimm die Word.au3. Diese UDF ist standardmäßig bei AutoIt dabei, damit lässt sich dein Problem lösen. Einfach die _Word_*-Funktionen nutzen, zb.: _Word_DocRangeSet .

andynbg9000

Danke für den Vorschlag

Leider steht Word hier nur als Beispiel. Ich will dieses Tool wirklich in allen Eingabefeldern benutzen können. Ganz Programmunabhängig.

z.B. in Google Keep, Thunderbird und co.

Hat jemand noch eine weitere Idee dazu?

**chesstiger**

Ich kann mir dieses Verhalten zwar nicht erklären... Dafür ist mir ein Workarround eingefallen. Du schiebst deinen zu schreibenden Text einfach in die Zwischenablage und sendest dann nur noch Strg+V, um ihn einzufügen. Das geht auch schneller und sieht nicht so aus, als ob die Tasten wirklich nacheinander gedrückt werden würden. Sähe in deinem Code etwa so aus:

[autoit]

Func startf4()
$vOldClip = ClipGet()
ClipPut($text)
Send("^v")
ClipPut($vOldClip)
EndFunc

[/autoit]

andynbg9000

Vielen Dank chesstiger!

Daran habe ich gar nicht gedacht! Das ist auf jeden Fall eine Lösung für mich.

Dann kann ich gleich mal weiter machen

**chesstiger**

Kein Ding. Wenn dein Problem damit gelöst ist, könntest du noch durch Bearbeiten des ersten Posts diesen Thread auf "gelöst" setzen. Das wäre super.

Runa

Das Problem ist, dass die Edits CRLF mitspeichern - nicht Enter. Und das Dokument behandelt CRLF nicht wie Enter:

Code

Func startf4 ()
	$text = StringReplace($text, @CR, "")
	$text = StringReplace($text, @LF, "{Enter}")
   Send ($text)
EndFunc