Hallo Ihr Lieben da draußen,
ich würde gerne dem Benutzer erlauben meine GUI in der Höhe zu verändern. Die Breite soll aber nicht veränderbar sein. Ist das möglich ?
Meine GUI hat die SIZEBOX Eigenschaft. Auch kenne ich das GUICtrlSetResizing, aber dies ist ja nur für Controls gedacht 
Ich freue mich über eine Antwort!
LG Tim
Ja, das ist möglich:
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt('GUIOnEventMode', 1)
Global $hGUI = GUICreate('Test', 600, 600, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
GUISetOnEvent($GUI_EVENT_CLOSE, '_End')
GUISetState(@SW_SHOW, $hGUI)
Global $aWinPos = WinGetPos($hGUI)
GUIRegisterMsg($WM_GETMINMAXINFO, "MY_WM_GETMINMAXINFO")
While True
Sleep(100)
WEnd
Func _End()
Exit
EndFunc ;==>_End
Func MY_WM_GETMINMAXINFO($hWnd, $msg, $wParam, $lParam)
If $hWnd = $hGUI Then
Local $minmaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
DllStructSetData($minmaxinfo, 7, $aWinPos[0]) ; min X
DllStructSetData($minmaxinfo, 8, 100) ; min Y
DllStructSetData($minmaxinfo, 9, $aWinPos[0]) ; max X
DllStructSetData($minmaxinfo, 10, 1024) ; max Y
EndIf
EndFunc ;==>MY_WM_GETMINMAXINFOVielen Dank für das Beispiel Oscar
Jetzt muss ich leider meine GUI auf OnEventMode umbauen, ich denke da komme ich nicht drann vorbei..
Schönen Tag noch
Auf OnEvent musst du nicht umbauen:
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $hGUI = GUICreate('Test', 600, 600, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
GUISetState(@SW_SHOW, $hGUI)
Global $aWinPos = WinGetPos($hGUI)
GUIRegisterMsg($WM_GETMINMAXINFO, "MY_WM_GETMINMAXINFO")
While True
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
EndSwitch
WEnd
Func _End()
Exit
EndFunc ;==>_End
Func MY_WM_GETMINMAXINFO($hWnd, $msg, $wParam, $lParam)
If $hWnd = $hGUI Then
Local $minmaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
DllStructSetData($minmaxinfo, 7, $aWinPos[2]) ; min X
DllStructSetData($minmaxinfo, 8, 100) ; min Y
DllStructSetData($minmaxinfo, 9, $aWinPos[2]) ; max X
DllStructSetData($minmaxinfo, 10, @DesktopHeight) ; max Y
EndIf
EndFunc ;==>MY_WM_GETMINMAXINFO
Oscar : Bei dir hat sich ein Fehler eingeschlichen:
WinGetPos gibt einen Array zurück, in dem 0 die X-Position, 1 die Y-Position, 2 die Breite und 3 die Höhe ist - in deinem Beispiel oben verwendest du 0 als Breite. 
Stimmt! Das war ein Flüchtigkeitsfehler.
Bei Deinem Beispiel ist dann aber die Funktion "_End" überflüssig. 
Wo gehobelt wird und so... *fg*
AutoTim: Ja, 64. 
@Bioshade: Tolle Band, Tolles Lied, Ich teile deinen Musik Geschmack 
Das glaube ich kaum. Mein Musikgeschmack ist keineswegs zu beschreiben...