[Gelöst] Excel / Outlook Event Hilfe in VBA

**UEZ**

Irgendwie kriege ich es nicht gebacken aus Excel Outlook Events abzufragen.

Beispiel in Excel VBA:

Code

Public Sub Mail()
        Dim outApp As Object
        Dim outMail As Object
        Set outApp = CreateObject("Outlook.Application")
        Set outMail = outApp.CreateItem(0)
        On Error Resume Next
        With outMail
            .To = ""
            .CC = ""
            .BCC = ""
            .Subject = "VBA Test"
            .BodyFormat = olFormatHTML
            .HTMLBody = "Blah Blah Blah"
            .Display True
        End With
        On Error GoTo 0
        Set outMail = Nothing
        Set outApp = Nothing
End Sub

Alles anzeigen

Wie kann ich jetzt abfragen, ob der "Send" Button gedrückt wurde?

Irgendwie finde ich nichts, was in Excel läuft.

Hat jemand eine Idee?

Ich benutze Office 2013.

Danke.

Techmix

Moin!
Ich verstehe deine Fragestellung nicht ganz... Willst du auf einem Button drücken und dieser soll deinen Code ausführen - oder was meinst du mit der "Send" Button Abfrage?

Grüsse!

**BugFix**

Zitat von Techmix

Willst du auf einem Button drücken und dieser soll deinen Code ausführen - oder was meinst du mit der "Send" Button Abfrage?

Nein, er erstellt in einer Excel-Anwendung ein Outlook-Objekt um aus Excel heraus eine Mail zu versenden. Das Outlook-Objekt ist sichtbar, der Button zum Versenden (Send) der Mail wird betätigt und ich nehme stark an, dass UEZ jetzt in seinem Excel weiterarbeiten und das Outlook-Objekt schließen möchte. Auslöser dafür soll halt das Betätigen des Send-Mail-Button sein.

@UEZ Kann da leider konkret nicht helfen, mangels Outlook. Mußt wohl warten, bis water einen Blick drauf wirft.

**UEZ**

Es geht darum, wenn der VBA Code gestartet wird, wird ein Outlook Fenster gestartet (neue Mail). Ich will nun prüfen, ob die Mail nun versandt wurde oder nicht. D.h. wurde der "Senden" Knopf gedrückt oder nicht. Dem entsprechend soll dann eine Zeile in Excel gefärbt oder nicht gefärbt werden.

Das geht mit Event, aber ich bekomme das nicht aus Excel heraus nicht hin. Die Beispiele aus dem Internet funzen irgendwie nicht richtig. Um das Problem darzustellen muss das Office Paket installiert sein.

**UEZ**

So geht's:

Module1 in Excel erstellen:

Code

Option Explicit
Dim ItmEvt As New Class1
Public Sub Mail()
        Dim outApp As Object
        Dim outMail As Object
        Set outApp = CreateObject("Outlook.Application")
        Set outMail = outApp.CreateItem(0)
        Set ItmEvt.Itm = outMail
        On Error Resume Next
        With outMail
            .To = ""
            .CC = ""
            .BCC = ""
            .Subject = "VBA Test"
            .BodyFormat = olFormatHTML
            .HTMLBody = "Blah Blah Blah"
            .Display
        End With
        On Error GoTo 0
        Set outMail = Nothing
        Set outApp = Nothing
End Sub

Alles anzeigen

Class1 erstellen:

Code

Option Explicit


Public WithEvents itm As Outlook.MailItem


Private Sub itm_Close(Cancel As Boolean)


    Dim blnSent As Boolean
    On Error Resume Next
    blnSent = itm.Sent
    If Err.Number = 0 Then
        MsgBox "Email not sent"
    Else
        MsgBox "Email sent"
    End If
End Sub

Alles anzeigen

Wichtig: Tools->References muss "Microsoft Outlook 15.0 Object Library" selektiert sein (oder die entsprechende Version)!