XML Erstellung _XMLCreateChildNode

horphi

Hallo zusammen,

hat sich jemand schon mit dem _XMLDomWrapper.au3 auseinandergesetzt?

Ich verstehe die Funktion _XMLCreateChildNode nicht.

Ich will in einer For Schleife die Bestellnummern in ein XML Child schreiben lassen.

Die Ubound For Schleife gibt mir aber erst den kompletten Arrayblock und dann zeilenweise weniger werdend die Nummern wieder.

Liegt das an der Array FOr Schleife, oder an der _XMLCreateChildNode Funktion?

Spoiler anzeigen

AutoIt

For $iR = 0 To UBound($aExtract, $UBOUND_ROWS) - 1
		$sItem = $aExtract[$iR]
		_XMLCreateRootChild("Order", "")
		_XMLCreateChildNode("//Orders/Order", "OrderNr", $sItem & "(Bestellnr. des Shops)", "")
Next

Spoiler anzeigen

AutoIt

;===============================================================================
; Function Name:	_XMLCreateChildNode
; Description:		Create a child node under the specified XPath Node.
; Parameter(s):		$path	Path from root
;					$node	Node to add
; Syntax:			_XMLCreateChildNode($path,$node)
; Author(s):		Stephen Podhajecki <gehossafats@netmdc.com>
; Return Value(s)			on error set error to 1 and returns -1
;===============================================================================
Func _XMLCreateChildNode($strXPath, $strNode, $strData = "", $strNameSpc = "")
	If not IsObj($objDoc) then
		_XMLError("No object passed to function _XMLCreateChildNode")
		Return SetError(1,16,-1)
	EndIf
	Local $objParent, $objChild, $objNodeList
		$objNodeList = $objDoc.selectNodes ($strXPath)
		If IsObj($objNodeList) And $objNodeList.length > 0 Then
			For $objParent In $objNodeList
				If Not ($objParent.hasChildNodes ()) Then
					_AddFormat($objDoc, $objParent)
				EndIf
				If $strNameSpc = "" Then
					If Not ($objParent.namespaceURI = 0 Or $objParent.namespaceURI = "") Then $strNameSpc = $objParent.namespaceURI
				EndIf
				;ConsoleWrite("$strNameSpc=" & $strNameSpc & @LF)
				$objChild = $objDoc.createNode ($NODE_ELEMENT, $strNode, $strNameSpc)
				If $strData <> "" Then $objChild.text = $strData
				$objParent.appendChild ($objChild)
				_AddFormat($objDoc, $objParent)
			Next
			If ($bXMLAUTOSAVE = True) Then $objDoc.save ($strFile)
			$objParent = ""
			$objChild = ""
			Return 1
		EndIf
	_XMLError("Error creating child node: " & $strNode & @CRLF & $strXPath & " does not exist." & @CRLF)
	Return SetError(1,0,-1)
EndFunc   ;==>_XMLCreateChildNode

Alles anzeigen

Das kommt dabei raus:

Spoiler anzeigen

XML

<?xml version="1.0" encoding="UTF-8"?>
<Orders>
	<FormatInfo>
		<DecimalSeperator>.</DecimalSeperator>
		<DefaultCurrency>EUR</DefaultCurrency>
		<OrderTypeText>MeinFormat</OrderTypeText>
		<TotalGrossAmountContainsShippingCosts>true</TotalGrossAmountContainsShippingCosts>
	</FormatInfo>
	<Order>
		<OrderNr>4365199(Bestellnr. des Shops)</OrderNr>
		<OrderNr>4349924(Bestellnr. des Shops)</OrderNr>
		<OrderNr>4357116(Bestellnr. des Shops)</OrderNr>
		<OrderNr>4364709(Bestellnr. des Shops)</OrderNr>
		<OrderNr>4353960(Bestellnr. des Shops)</OrderNr>
		<OrderNr>4363533(Bestellnr. des Shops)</OrderNr>
	</Order>
	<Order>
		<OrderNr>4349924(Bestellnr. des Shops)</OrderNr>
		<OrderNr>4357116(Bestellnr. des Shops)</OrderNr>
		<OrderNr>4364709(Bestellnr. des Shops)</OrderNr>
		<OrderNr>4353960(Bestellnr. des Shops)</OrderNr>
		<OrderNr>4363533(Bestellnr. des Shops)</OrderNr>
	</Order>
	<Order>
		<OrderNr>4357116(Bestellnr. des Shops)</OrderNr>
		<OrderNr>4364709(Bestellnr. des Shops)</OrderNr>
		<OrderNr>4353960(Bestellnr. des Shops)</OrderNr>
		<OrderNr>4363533(Bestellnr. des Shops)</OrderNr>
	</Order>
	<Order>
		<OrderNr>4364709(Bestellnr. des Shops)</OrderNr>
		<OrderNr>4353960(Bestellnr. des Shops)</OrderNr>
		<OrderNr>4363533(Bestellnr. des Shops)</OrderNr>
	</Order>
	<Order>
		<OrderNr>4353960(Bestellnr. des Shops)</OrderNr>
		<OrderNr>4363533(Bestellnr. des Shops)</OrderNr>
	</Order>
	<Order>
		<OrderNr>4363533(Bestellnr. des Shops)</OrderNr>
	</Order>
</Orders>

Alles anzeigen

SO soll es aussehen:

Spoiler anzeigen

XML

<?xml version="1.0" encoding="UTF-8"?>
<Orders>
	<FormatInfo>
		<DecimalSeperator>.</DecimalSeperator>
		<DefaultCurrency>EUR</DefaultCurrency>
		<OrderTypeText>MeinFormat</OrderTypeText>
		<TotalGrossAmountContainsShippingCosts>true</TotalGrossAmountContainsShippingCosts>
	</FormatInfo>
	<Order>
		<OrderNr>4365199(Bestellnr. des Shops)</OrderNr>
	</Order>
	<Order>
		<OrderNr>4349924(Bestellnr. des Shops)</OrderNr>
	</Order>
	<Order>
		<OrderNr>4357116(Bestellnr. des Shops)</OrderNr>
	</Order>
	<Order>
		<OrderNr>4364709(Bestellnr. des Shops)</OrderNr>
	</Order>
	<Order>
		<OrderNr>4353960(Bestellnr. des Shops)</OrderNr>
	</Order>
	<Order>
		<OrderNr>4363533(Bestellnr. des Shops)</OrderNr>
	</Order>
</Orders>

Alles anzeigen

Liegt das an der FOR-Ubound Schleife?

Danke für eure Hilfe.

VG

horphi

**Kanashius**

Naja. Das Problem ist, dass du Order erstellst und dann in order die Nummern einfügst... in alle Order, die bis dahin existieren. Weiß jetzt nicht, wie mans lösen kann mit dem Wrapper ,da ich den nie benutzt habe.
Er kann die einzelnen Order - Childnodes nicht unterscheiden und fügt es deshalb in alle ein.
Könntest einfach so die Items erstellen (mit Stringbefehlen und Fileopen/filewrite/fileclose). Vermutlich deutlich einfacher.

horphi

Zitat von Kanashius

Könntest einfach so die Items erstellen (mit Stringbefehlen und Fileopen/filewrite/fileclose). Vermutlich deutlich einfacher.

Hallo Kanashius,

danke für deine Antwort.

Nun ja, es kommen noch ein paar Zeilen XML hinzu und es ist ganz charmant, wenn die Zelle keine Wert hat, wird die XML Zeile gleich abgeschlossen.

Du hast Recht, die Childnodes werden nicht unterschieden und das Objekt wird in der ganzen Datei gesucht und ergänzt, egal wie oft ich das wiederhole.

Habe jetzt das Item in die Order eingefügt (somit ist es eindeutig) und am ende werden alle Order durch einen Leersting ersetzt. Sollte als Workaround auch gehen...

VG
horphi und frohe Weihnachten...

**Raupi**

Kannst du mal ein lauffähiges Script mit Beispieldaten posten?
Und hänge mal den Wrapper mit an, habe keine Lust den jetzt zu suchen, da ich sonst mit dem Object selber arbeite.

horphi

Probier mal so..
Hab´s über eine nachgelagerte Schleife gelöst, in der ich vorher die Order mit dem $sItem eindeutig mache und danach wieder durch Order ersetze...

AutoIt

#include <Array.au3>
#include <_XMLDomWrapper.au3>
_XMLCreator()
Exit
Func _XMLCreator()
	Const $FileName = @YEAR & @MON & @MDAY & "_export.xml"
	Const $XMLNS = "http://schemas.microsoft.com/windows/tasks/v1"
	Const $filenameloc = @ScriptDir & "/" & $FileName
	Dim $aExtract[2] = ["1212", "1313"]
	Dim $Values[2]
	Local $timestamp = @YEAR & "-" & @MON & "-" & @MDAY & " " & @HOUR & ":" & @MIN & ":" & @SEC
	;Create file (force overwrite existing file)
	$result = _XMLCreateFile($FileName, "Orders", 1, 1)
	Switch @error
		Case 0
			ConsoleWrite("No error" & @CRLF)
		Case 1
			ConsoleWrite("Failed to create file" & @CRLF)
		Case 2
			ConsoleWrite("No object" & @CRLF)
		Case 3
			ConsoleWrite("File creation failed MSXML error" & @CRLF)
		Case 4
			ConsoleWrite("File exists" & @CRLF)
	EndSwitch
	;Open created file
	_XMLFileOpen($FileName)
	_XMLCreateRootChild("FormatInfo", "")
	_XMLCreateChildNode("//Orders/FormatInfo", "DecimalSeperator", ".", "")
	_XMLCreateChildNode("//Orders/FormatInfo", "DefaultCurrency", "EUR", "")
	_XMLCreateChildNode("//Orders/FormatInfo", "OrderTypeText", "MeinFormat", "")
	_XMLCreateChildNode("//Orders/FormatInfo", "TotalGrossAmountContainsShippingCosts", "true", "")
	For $iR = 0 To UBound($aExtract) - 1
		$sItem = $aExtract[$iR]
		ConsoleWrite($sItem)
		_XMLCreateRootChild("Order", "")
;~ 		_XMLCreateRootChild("Order" & $sItem, "");-------------Damit geht´s eine eindeutige ID für die Objektsuche zu erzeugen....
		_XMLCreateChildNode("//Orders/Order", "OrderNr", $sItem & "(Bestellnr. des Shops)", "")
;~ 		_XMLCreateChildNode("//Orders/Order" & $sItem, "OrderNr", $sItem & "(Bestellnr. des Shops)", "") ;-------------Damit geht´s eine eindeutige ID für die Objektsuche zu erzeugen....
	Next
;~ ------------------------> und hier wird $sItem durch "" ersetzt-------------------
;~ 	For $iR = 0 To UBound($aExtract) - 1
;~ 		$sItem = $aExtract[$iR]
;~ 		$uSearch = "Order" & $sItem
;~ 		$uReplace = "Order"
;~ 		_FileSearchAndReplace($filenameloc, $uSearch, $uReplace)
;~ 	Next
;~ ------------------------> und hier wird $sItem durch "" ersetzt-------------------
	MsgBox(0, '', "Export erfolgreich" & @CRLF & $FileName)
EndFunc   ;==>_XMLCreator
Func _FileSearchAndReplace($sFile, $uSearch, $uReplace, $bCaseSensitive = 0)
	Local $bResult = True
	$hFile = FileOpen($sFile, 0)
	If $hFile > 0 Then
		$sContent = FileRead($hFile)
		FileClose($hFile)
		If IsArray($uSearch) And IsArray($uReplace) And UBound($uSearch) == UBound($uReplace) Then
			$iCount = UBound($uSearch)
			For $i = 1 To $iCount
				$sContent = StringReplace($sContent, $uSearch[$i], $uReplace[$i], 0, $bCaseSensitive)
			Next
		ElseIf IsString($uSearch) And IsString($uReplace) Then
			$sContent = StringReplace($sContent, $uSearch, $uReplace, 0, $bCaseSensitive)
		Else
			$bResult = False
		EndIf
		If $bResult Then
			$hFile = FileOpen($sFile, 2)
			FileWrite($hFile, $sContent)
			FileClose($hFile)
		EndIf
	Else
		$bResult = False
	EndIf
	Return $bResult
EndFunc   ;==>_FileSearchAndReplace

Alles anzeigen

VG

horphi

**Raupi**

Soll die XML mit deinem Beispiel so aussehen?

XML

<?xml version="1.0" encoding="UTF-8"?><Orders>
<FormatInfo>
<DecimalSeperator>.</DecimalSeperator>
<DefaultCurrency>EUR</DefaultCurrency>
<OrderTypeText>MeinFormat</OrderTypeText>
<TotalGrossAmountContainsShippingCosts>true</TotalGrossAmountContainsShippingCosts>
</FormatInfo>
<Order>
<OrderNr>1212(Bestellnr. des Shops)</OrderNr>
</Order>
<Order>
<OrderNr>1313(Bestellnr. des Shops)</OrderNr>
</Order>
</Orders>

Alles anzeigen

Probier mal das aus :

Spoiler anzeigen

AutoIt

#include <Array.au3>
#include <_XMLDomWrapper.au3>
_XMLCreator()
Exit
Func _XMLCreator()
	Const $FileName = @YEAR & @MON & @MDAY & "_export.xml"
	Const $XMLNS = "http://schemas.microsoft.com/windows/tasks/v1"
	Const $filenameloc = @ScriptDir & "/" & $FileName
	Dim $aExtract[2] = ["1212", "1313"]
	Dim $Values[2]
	Local $timestamp = @YEAR & "-" & @MON & "-" & @MDAY & " " & @HOUR & ":" & @MIN & ":" & @SEC
	;Create file (force overwrite existing file)
	$result = _XMLCreateFile($FileName, "Orders", 1, 1)
	Switch @error
		Case 0
			ConsoleWrite("No error" & @CRLF)
		Case 1
			ConsoleWrite("Failed to create file" & @CRLF)
		Case 2
			ConsoleWrite("No object" & @CRLF)
		Case 3
			ConsoleWrite("File creation failed MSXML error" & @CRLF)
		Case 4
			ConsoleWrite("File exists" & @CRLF)
	EndSwitch
	;Open created file
	_XMLFileOpen($FileName)
	_XMLCreateRootChild("FormatInfo", "")
	_XMLCreateChildNode("//Orders/FormatInfo", "DecimalSeperator", ".", "")
	_XMLCreateChildNode("//Orders/FormatInfo", "DefaultCurrency", "EUR", "")
	_XMLCreateChildNode("//Orders/FormatInfo", "OrderTypeText", "MeinFormat", "")
	_XMLCreateChildNode("//Orders/FormatInfo", "TotalGrossAmountContainsShippingCosts", "true", "")
	For $iR = 0 To UBound($aExtract) - 1
		_XMLCreateRootChild("Order", "")
		Local $icnt= _XMLGetNodeCount("//Orders/Order"); Hier wird die Anzahl der Order Nodes ausgelesen, diese wird anschliessend benutz das Child im richtigen Node zu erstellen


		$sItem = $aExtract[$iR]
		ConsoleWrite($sItem)


;~ 		_XMLCreateRootChild("Order" & $sItem, "");-------------Damit geht´s eine eindeutige ID für die Objektsuche zu erzeugen....
		_XMLCreateChildNode("//Orders/Order[" & $icnt & "]", "OrderNr", $sItem & "(Bestellnr. des Shops)", ""); Wenn man das Node mit seiner Nummer anspricht funzt es auch 
;~ 		_XMLCreateChildNode("//Orders/Order" & $sItem, "OrderNr", $sItem & "(Bestellnr. des Shops)", "") ;-------------Damit geht´s eine eindeutige ID für die Objektsuche zu erzeugen....
	Next


	MsgBox(0, '', "Export erfolgreich" & @CRLF & $FileName)
EndFunc   ;==>_XMLCreator

Alles anzeigen

Btw, das mit der Nummerierung steht nirgends in der UDF, man muß schon google quälen.

horphi

Hallo Raupi,

vielen Dank. --> auf _XMLGetNodeCount wäre ich beim besten Willen nicht gekommen.
Wonach hast du in Google gesucht?

VG
horphi

**Raupi**

Ich habe nach der UDF gesucht und im EN-Forum irgendein Beispielscript gefunden.
Da ging es zwar um das Lesen eines Nodes, aber dazu muss man diese auch eindeutig ansprechen wenn es mehrer gleichnamige
Nodes gibt. Auf XMLGetNodeCount bin ich gekommen, weil ich mir einfach mal die UDF Funktionen angesehen habe.
Geht aber auch ohne, wenn man den Schleifenzähler $iR einfach um 1 erhöht, da dieser Zähler 0 Basiert ist.

horphi

Vielen Dank