Anfängerfrage: Bin ich auf dem richtigen Weg?

dmo

Hallo,

ich bin ziemlicher AutoIt- und Programmieranfänger. Bisher habe ich AutoIt vor allem für automatisierte Installationsscripte verwendet. Und auch das ist schon eine Weile her. Nun möchte ich mir ein kleines Programm schreiben, dass mich bei der Verwaltung von Bilddateien unterstützt. Gegeben ist ein Ordner mit jpg- und raw-Dateien. Diese haben den gleichen Namen, unterscheiden sich aber durch die Dateiendung. (So kommt das aus meiner Kamera.) In meinem Fotoworkflow durchforste ich die jpg-Dateien und lösche die, die ich nicht gebrauchen kann. In dem Ordner befinden sich dann aber noch die zugehörigen raw-Dateien. Das Programm soll diese "verwaisten" -raw-Dateien finden und löschen.

Dies ist erstmal die Grundidee. Ich habe den unten aufgeführten Ansatz gewählt und möchte hier einfach einmal nachfragen, ob dieses Vorgehen Sinn macht oder ob ich das Ganze auch ganz anders angehen könnte oder sollte. Für Tipps wäre ich dankbar. Das "Programm" soll noch ausgebaut werden. So möchte ich z.B. mehrere Raw-Dateiformate berücksichtigen können (verschiedene Dateiendungen) oder auch verschiedene Quellordner. Am Ende hätte ich auch gern ein GUI. Bis dahin ist es für mich sicher noch ein weiter Weg und ich habe noch keine Idee, wie das gehen kann. Für mich ist dieses kleine Projekt eine Art Gehirntraining und ich versuche es einfach aus Spaß und Interesse an der Sache. Deshalb greife ich auch nicht auf Programme zurück, die ich im Netz gefunden habe und genau das tun, was ich möchte.

Also - ich freue mich über HInweise und hier mein erster Ansatz

AutoIt

#include <Array.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>


$QuellOrdner = @DesktopDir & "\JgpRawTest\"


; Alle Raw-Dateien in Array einlesen.
$aFileList = _FileListToArray($QuellOrdner, "*.raw", 1)


; Nacheinander Dateinamen im Array auslesen.
For $i = 1 To UBound($aFileList)-1
	$Datei = $aFileList[$i]
	; Dateierweiterung (raw) entfernen.
	$DateinameOhneErw = StringTrimRight ( $Datei, 4 )
	; MsgBox(1,"Info1",$DateinameOhneErw)


	; Prüfen, ob eine gleichnamige Datei mit der Endung jpg. vorhanden ist.
	$DateiVorhandenJpg = FileExists ($QuellOrdner & $DateinameOhneErw & ".jpg")
    ; MsgBox(1,"Info2",$DateiVorhanden)


	; Raw-Datei löschen, falls keine jpg-Datei vorhanden ist.
	If $DateiVorhandenJpg = 0 Then FileDelete ($QuellOrdner & $DateinameOhneErw & ".raw")
Next

Alles anzeigen

**Kanashius**

Das sieht doch ganz gut aus. Man kann da nicht mehr viel optimieren.
Ne Funktion wäre in deinem Fall sinnvoll, wenn du später mehrere Ordner durchsuchen willst oder den Typ ändern willst.
Gerade für solche sich wiederholende dinge sind Funktionen da.
Falls dich das mit dem = in der Funktion verwirrt: Das sind optionale Parameter. Wenn nichts angegeben wird, wird der hinter dem = angegebene Parameter genommen.

AutoIt

#include <Array.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>


_deleteFilesWithoutJpg(@DesktopDir & "\JgpRawTest")


Func _deleteFilesWithoutJpg($Folder,$rec=false,$type="raw")
	; Alle Raw-Dateien in Array einlesen.
	local $aFileList
	if $rec then
		$aFileList = _FileListToArrayRec($Folder, "*." & $type, 1)
	else	
		$aFileList = _FileListToArray($Folder, "*." & $type, 1)
	endif
	; Nacheinander Dateinamen im Array auslesen.
	For $i = 1 To UBound($aFileList)-1
		$Datei = $aFileList[$i]
		; Dateierweiterung (raw) entfernen.
		$DateinameOhneErw = StringTrimRight ( $Datei, 1+stringlen($type) )
		; MsgBox(1,"Info1",$DateinameOhneErw)
		; Prüfen, ob eine gleichnamige Datei mit der Endung jpg. vorhanden ist.
		$DateiVorhandenJpg = FileExists ($Folder &"\" & $DateinameOhneErw & ".jpg")
		; MsgBox(1,"Info2",$DateiVorhanden)
		; Raw-Datei löschen, falls keine jpg-Datei vorhanden ist.
		If $DateiVorhandenJpg = 0 Then FileDelete ($Folder&"\" & $DateinameOhneErw & "." & $type)
	Next
EndFunc

Alles anzeigen

EDIT: Folder Fehler (s. Unten)

**BugFix**

Ja, schon korrekter Ansatz.
Hier mal als kpl. variable Funktion, sowohl für Raw-Typ als auch Bild-Typ:

AutoIt

#include <File.au3>


$QuellOrdner = @DesktopDir & "\JgpRawTest\"


_DeleteUnpaired($QuellOrdner)


Func _DeleteUnpaired($_sPath, $_sfxDel='raw', $_sfxPair='jpg')
	Local $aFiles = _FileListToArray($_sPath, StringFormat('*.%', $_sfxDel), 1, True) ; Rückgabe kpl. Pfad
	If @error Then Return SetError(1,0,0)
	For $i = 1 To $aFiles[0]
		If Not FileExists(StringFormat('%s%s', StringTrimRight($_sPath, StringLen($_sfxDel)), $_sfxPair)) Then
			FileDelete($aFiles[$i])
		EndIf
	Next
EndFunc

Alles anzeigen

dmo

Vielen Dank für eure Rückmeldungen.
Ich werde mir eure Ideen in Ruhe durchsehen und versuchen, sie nachzuvollziehen. Wenn ich weitere Fragen haben, melde ich mich wieder.
Das kann ein bisschen dauern - ich habe nicht täglich Zeit, das Vorhaben zu verfolgen. Aber das stört ja nicht.

Frage am Rande: Das Highlighten der Syntax in meinem Eintrag war nicht korrekt. Was könnte ich falsch gemacht haben?

Grüße

**Raupi**

Zitat von dmo

Frage am Rande: Das Highlighten der Syntax in meinem Eintrag war nicht korrekt. Was könnte ich falsch gemacht haben?

Du hast nichts falsch gemacht, der Syntaxhighlighter spinnt manchmal.

**Kanashius**

Naja. Es liegt an dem \", dass du genutzt hast. Der Highlighter escaped das " und deshalb wird alles danach als String betrachtet, bis zum nächsten nicht escapeten ". Und dann wechselt es halt. Ich hab das \ Einfach weggelassen, da du nur den Ordner brauchst für _fielreadtoarray
Hab dabei aber gemerkt, das mein Quellcode nicht passt. Änder den mal oben, hatte vergessen $Quellcode zu $Folder umzubenennen und dementsprechend auch das \ dort fehlt.

dmo

Hallo,

hier mal mein Version des Vorschlags von Kanashius. Ich will die Ideen ja nicht einfach per Copy and Paste verwenden, sondern ordentlich verstehen. Deshalb habe ich Elemente von Kanashius genommen und in mein Script eingefügt und das eine oder andere noch ergänzt/geändert.

Demnächst ist dann der Vorschlag von BugFix "dran".

Grüße

AutoIt

#include <Array.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>


; Variablen
$QuellOrdner = @DesktopDir & "\JgpRawTest\" ; Ordner mit den Bilddateien
$typeRaw = "raw" ; Dateiendung Raw-Format
$typeJpg = "jpg" ; Dateiendung Jpg-Format


; Funktion aufrufen
_deleteFilesWithoutJpg ($QuellOrdner, $typeRaw, $typeJpg)




; Funktion erstellen
Func _deleteFilesWithoutJpg ($Folder, $typeR, $typeJ)




	; Alle Raw-Dateien in Array einlesen. Es werden nur Dateien, keine Ordner eingelesen.
	$aFileList = _FileListToArray($Folder, "*." & $typeR, 1)


		; Nacheinander Dateinamen im Array auslesen.
		For $i = 1 To UBound($aFileList)-1
			$Datei = $aFileList[$i]
			; Dateierweiterung entfernen. Verwendung von StringLen ermöglicht Unabhängigkeit von Anzahl der Zeichen der Dateiendung.
			$DateinameOhneErw = StringTrimRight ( $Datei, 1+StringLen ($typeR) )
			; MsgBox(0,"Debug 01",$DateinameOhneErw)


			; Prüfen, ob eine gleichnamige Datei mit der Endung jpg. vorhanden ist.
			$DateiVorhandenJpg = FileExists ($Folder & $DateinameOhneErw & "." & $typeJ)


			; Raw-Datei löschen, falls keine jpg-Datei vorhanden ist.
			If $DateiVorhandenJpg = 0 Then FileDelete ($Folder & $DateinameOhneErw & "." & $typeR)
		Next
EndFunc

Alles anzeigen

dmo

Hallo,

also das Script von BufFix läuft bei mir so nicht erfolgreich. Es werden keine raw-Dateien gelöscht. Ich durchschau es ehrlich gesagt auch nicht richtig. Es ist sehr kompakt, was ja eigentlich sehr schön ist - aber die verschiedenen Stringmanipulationen habe ich nicht voll verstanden. Ist für mich wohl noch zu kompakt. Macht nichts. Die andere Variante funktioniert ja und ich kann damit gut weiterarbeiten.

Vielen Dank nochmal.

**Kanashius**

Wenn du in Zeile 8 bei Bugfix StringFormat('*.%', $_sfxDel) zu StringFormat('*.%s', $_sfxDel) änderst, sollte es glaubich funktionieren.
Ansonsten guck mal ob der Error kommt bei

$QuellOrdner = @DesktopDir & "\JgpRawTest\"
_DeleteUnpaired($QuellOrdner)
if @error then
msgbox(16,"Error","Something went wrong")
endif

**BugFix**

_{StringFormat('*.%', $_sfxDel) Ja, das war ein Schreibfehler. Der Platzhalter für den String muss natürlich %s} heissen.

dmo

Zitat von BugFix

_{Ja, das war ein Schreibfehler.}

Da bin ich ja beruhigt. Danke für die Info.

Ich habe meinem Script jetzt (zum Üben) noch um ein paar Optionen erweitert. Über weitere Tipps und Hinweise freundlicher Fachleute dazu würde ich mich freuen. Ich finde, dass das eine gute Art zu lernen ist. Ist hier dafür der richtige Platz oder sollte ich lieber im Unterforum "Skripte" ein neues Thema dafür aufmachen? Oder lieber gar nicht??

Grüße

**Kanashius**

Scripte ist eher für fertige Programme. Dann eher in Projekte, würd ich sagen, auch wenn das vermutlich auch eher für fertige Scripte ist.
(Bzw. wenn die Entwicklung weit genug für eine Veröffentlichung ist, auch wenn sie noch nicht fertig ist.)
Die Kategorien sind also eher zum Vorstellen, als um Hilfe zu bitten. Auch wenn dort konstruktive Kritik immer gerne erwünscht ist
Du kannst aber auch hier weiter schreiben, wenn es passt.

dmo

Zitat von Kanashius

Du kannst aber auch hier weiter schreiben, wenn es passt.

Danke. Dann hier also mal der aktuelle Status des Script. Hinweise und Tipps zum Code sind mir sehr willkommen.

AutoIt

#include <Array.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>
#include <Date.au3>
; #include <StringConstants.au3>


; Variablen
Global $sTypeRaw
Global $sTypeJpg = 'jpg'; Dateiendung Jpg-Format
Global $sLogFile; Datei mit Liste der gelöschten Bilddateien.
Global $sQuellOrdner; Ordner mit Bildateien
Local $sLetztesZeichen
Local $iReturnSicherheitsabfrage




; Abfrage Raw-Dateiendungen.
$sTypeRaw = InputBox('RAW-Dateien', 'Zu berücksichtigende Raw-Dateiendungen' & @CRLF & @CRLF & 'Exakte Eingabe erforderlich', '*.arw;*.rw2;*.raf')


; Pfad Quellordner abfragen
; $sQuellOrdner = InputBox ('Quellordner','Bitte vollständigen Pfad zum gewünschten Bilderordner angeben.')


; Quellordner auswählen über Dateiauswahlbox auswählen.
$sQuellOrdner = FileSelectFolder('Bitte den Bilderordner auswählen.', '', 2)
If @error Then
	MsgBox(0, '', 'Kein Ordner ausgewählt.')
EndIf


; Prüfen, ob der Pfad mit \ endet. Wenn nicht, dies ergänzen.
$sLetztesZeichen = StringRight($sQuellOrdner, 1)
If $sLetztesZeichen <> '\' Then
	$sQuellOrdner = $sQuellOrdner & '\'
EndIf




;~ ; Prüfe, ob Quellordner vorhanden ist.
;~ If Not FileExists($sQuellOrdner) Then
;~ 	MsgBox (0,'Debug','Quellordner nicht gefunden.')
;~ 	Exit
;~ EndIf


; Sicherheitsabfrage anzeigen.
$iReturnSicherheitsabfrage = MsgBox(49, 'Löschen?', 'Soll das Löschen gestartet werden?')
If $iReturnSicherheitsabfrage <> 1 Then Exit




; Log-Datei (s.u.)
; Alte Log-Datei in den Papierkorb verschieben, wenn vorhanden.
$sLogFile = $sQuellOrdner & "Geloescht.log"
If FileExists($sLogFile) Then FileRecycle($sLogFile)




; Funktion zum Löschen der verwaisten Raw-Dateien aufrufen
_deleteFilesWithoutJpg($sQuellOrdner, $sTypeRaw, $sTypeJpg)


; Funktion erstellen
; Raw-Dateien ohne zugehörige Jpg-Dateien werden identifiziert und gelöscht.
Func _deleteFilesWithoutJpg($Folder, $typeR, $typeJ)
	; Arrays deklariere.
	Local $sDatei
	Local $aListeRawDateien
	Local $aTeileDateiname
	Local $iIndexDateiendung
	Local $sDateiEndungRaw
	Local $iDateiVorhandenJpg
	Local $sDateinameOhneEndung
	Local $iZaehler = 0
	Local $hLogFile


	; Raw-Dateien in Array einlesen.
	; Es werden nur Dateien, keine Ordner eingelesen.
	; Unterordner werden nicht berücksichtigt.
	$aListeRawDateien = _FileListToArrayRec($Folder, $typeR, 1)


	; Prüfe, ob das Array erstellt wurde.
	If @error = 1 Then
		MsgBox(0, 'Debug', 'Fehler im Array.' & @CRLF & 'Fehlercode: ' & @extended)
		Exit
	EndIf


	; Nacheinander Dateinamen im Array auslesen.
	For $i = 1 To UBound($aListeRawDateien) - 1
		$sDatei = $aListeRawDateien[$i]


		; Dateinamen splitten, um Dateiendung extrahieren zu können und zwar unabhänging von der Anzahl der Zeichen der Endung
		; und unabhängig davon, ob im Dateinamen mehrere Punkte enthalten sind.
		$aTeileDateiname = StringSplit($sDatei, '.') ; Es wird ein Array ausgegeben.


		; Das letzte Element im Array ist die Dateiendung.
		; Die Anzahl der Elemente des Arrays kann variieren, wenn Dateinamen mehrere Punkte enthalten.
		; Zum Extrahieren der Endung wird deshalb der Index des letzten Elementes benötigt.
		$iIndexDateiendung = UBound($aTeileDateiname, 1) - 1


		; Die Dateiendung aus dem Array lesen.
		$sDateiEndungRaw = $aTeileDateiname[$iIndexDateiendung]


		; Vollständiger Dateiname, aber ohne Dateiendung. Auch, wenn im Namen mehrere Punkte enthalten sind.
		$sDateinameOhneEndung = StringTrimRight($sDatei, 1 + StringLen($sDateiEndungRaw))


		; Prüfen, ob im Ordner eine gleichnamige Datei mit der Endung jpg. vorhanden ist.
		$iDateiVorhandenJpg = FileExists($Folder & $sDateinameOhneEndung & '.' & $typeJ) ; Rückgabewert = 0, wenn Datei nicht existiert.


		; Raw-Datei in den Papierkorb löschen, falls keine jpg-Datei vorhanden ist.
		If $iDateiVorhandenJpg = 0 Then
			FileRecycle($Folder & $sDateinameOhneEndung & '.' & $sDateiEndungRaw); FileDelete löscht die Datei endgültig.


			; Gelöschte Dateien zählen.
			$iZaehler = $iZaehler + 1


			; Log-Datei schreiben.
			$hLogFile = FileOpen($sLogFile, 1)
			_FileWriteLog($hLogFile, $sDateinameOhneEndung & '.' & $sDateiEndungRaw) ; Write to the logfile passing the filehandle returned by FileOpen.
			FileClose($hLogFile) ; Close the filehandle to release the file.
		EndIf
	Next
	; Ausgabe Info Anzahl der gelöschten Dateien
	MsgBox(48, 'Info', 'Es wurden ' & $iZaehler & ' Dateien gelöscht.')


EndFunc   ;==>_deleteFilesWithoutJpg






#cs
	ToDo
	====
	Option, die Dateien nicht zu löschen, sondern in einen Unterordner zu verschieben.
	Option, endgültig Löschen oder in den Papierkorb verschieben.
	Vorschau der zu löschenden Dateien.
	Letzten Quellordner für den nächsten Programmaufruf merken.
	GUI
	Verschiedene Jpg-Dateiendungen berücksichtigen.
	Unterordner einbeziehen.
#ce

Alles anzeigen