Dateiliste - Verzeichnisliste ... „Koda Form Designer“

AutoMit

Hallo Freunde der automatisierten Schritte,

wahrscheinlich benutze ich nur den falschen Suchbegriff.

Ich möchte auf der Form mit dem „Koda Form Designer“ einfach ein Objekct erstellen, dass eine Datei- und Verzeichnisliste ausgehend von einem bestimmten Startverzeichnis enthält.

Nur ich finde das nicht.

Ist sowas nicht integriert?

Es sollte die grundlegenden Funktionen mitbringen wie per Doppelklick eine Datei mit dem verknüpftem Programm starten.

Ich wäre davon ausgegangen, dass es unter win32 - Controls zu finden ist. So wie das Kalendermodul.

Dort ist aber nur ein leeres Treeview und Listview.

Gibt es für Autoit eine Datei- und Verzeichnisliste ein fertiges Control? Oder eine UDF?

Viele Grüße
AutoMit

**Kanashius**

An sich gibt es das nicht als Standartcontrol. Ich hab mal eine UDF geschrieben, die genau das macht.
FileExplorere List and TiewView
Unterstützt wird List oder Treeview, oder beides, je nachdem, was du haben möchtest.
Einfach das Beispiel ansehen.
In der _WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam) kannst du dann das öffnen bei doppelklick,... hinzufügen, dafür die Hilfe durchsehen und sonst hier fragen.

Edit hatte grad nen Moment. Kannst jetzt ne Funktion hinzufügen und entfernen für doppelklicks:
_TLE_AddListviewFileDoubleClickFunction("testfunktion")
_TLE_DelListviewFileDoubleClickFunction("testfunktion")

AutoMit

Super - vielen Dank für Deinen Tipp! Das schaue ich mir gerne in Ruhe an.

@all

Füllt Ihr ansonsten per Hand ein ListView oder wie nutzt Ihr Dateilsiten in Autoit?
Ich habe auch über Google keine Dateiisten-Beispiele finden können.

**Oscar**

Das kommt darauf an, was die Dateiliste für einen Zweck erfüllen soll.
Meist reicht ja schon _FileListToArray, das Array bearbeiten und _GUICtrlListView_AddArray.
Sollen noch Benutzeraktionen mit der Liste möglich sein, dann muss man halt noch etwas drumherum programmieren.

Auf gar keinen Fall benutze ich aber Koda.

AutoMit

@Kanashius

Leider erhalte ich unter win 8.1 / 64 folgende Fehlermeldung beim Ausführen von:

Example_doubleFunction.au3

[Window Title]
AutoIt v3 Script
[Main Instruction]
AutoIt v3 Script funktioniert nicht mehr
[Content]
Ein Problem hat die richtige Ausführung dieses Programms verhindert. Schließen Sie das Programm.
[Programm schließen]

Folgende Dateien liegen im gleichen Verzeichnis:
AutoItObject.au3
FileExplorerTreeAndListview UDF_doubleFunction.au3

Wie kann ich den Fehler weiter eingrenzen? Das Explorer-Fenster wird angezeigt - leer. Dann die Absturzmeldung.

AutoMit

Zitat von Oscar

Das kommt darauf an, was die Dateiliste für einen Zweck erfüllen soll.
Sollen noch Benutzeraktionen mit der Liste möglich sein, dann muss man halt noch etwas drumherum programmieren.

Die Dateiliste, die ich suche, solle "nur" 3 Aufgaben erfüllen.

Startverzeichnis: c:\test

1. alle *.pdf Dateien auflisten, die in diesem Verzeichnis sind

2. per Doppelklick öffnen mit dem verknüpften Programm

3. auf meiner Oberfläche sind ein paar Button mit unterschiedlichen Zielverzeichnissen, also z.B.

Button 1 = verschiebe die angeklickte Datei nach c:\test\archiv
Button 2 = verschiebe die angeklickte Datei nach c:\test\lesen
...
Button 9 = lösche die angeklickte Datei in den Papierkorb

Falls Ihr für so ein ListView mit Doppelklick und Pfadübergabe ein Programmschnipsel habt, immer rein damit

AutoMit

(1)

Ich habe noch was ausgegraben, was der Grundidee schon nahe kommt:

Dateiliste ohne FileOpenDialog

Der Befehl:

RunWait(@ComSpec & ' /c start ' & $path & _GUICtrlListViewGetItemText($listview, _GUICtrlListViewGetCurSel($listview), 1), '', @SW_HIDE)

funktioniert nicht mehr. Wie schreibt man den heute?

(2)

Scheinbar kann ich ein ListView nicht in einer Case - Klick - Anweisung abfragen - folgendes geht nicht. An der Stelle kommt nichts an, wenn ich auf das ListView klicke. Wie muss das geschrieben werden, damit ein ListView auf einen Mausklick reagiert?

AutoIt

While 1
	$nMsg = GUIGetMsg()


	Switch $nMsg


		Case $GUI_EVENT_CLOSE
			Exit


		Case $ListView_01


			Local $lesen = _GUICtrlListView_GetSelectionMark($ListView_01)
			Local $Datei_Name = _GUICtrlListView_GetItemTextString($ListView_01, $lesen)
			ConsoleWrite ($lesen & @TAB & $Datei_Name & @CRLF)


	EndSwitch
WEnd

Alles anzeigen

**Oscar**

Zitat von AutoMit

Falls Ihr für so ein ListView mit Doppelklick und Pfadübergabe ein Programmschnipsel habt, immer rein damit

Für die ersten beiden Punkte habe ich mal eben ein Script geschrieben:

AutoIt

#include <File.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <StructureConstants.au3>
#include <WindowsConstants.au3>


Opt('GUIOnEventMode', 1)


Global $hGui = GUICreate('PDF-List DblClick', 480, 300)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')


Global $idPath = GUICtrlCreateLabel('', 10, 12, 410, 22, Default, $WS_EX_STATICEDGE)
GUICtrlSetFont(-1, 11, 400, 0, 'Tahoma')


Global $idPathSelect = GUICtrlCreateButton('...', 422, 10, 48, 25)
GUICtrlSetFont(-1, 12, 600, 0, 'Tahoma')
GUICtrlSetOnEvent(-1, '_SelectPath')


Global $idListView = GUICtrlCreateListView('Dateiname|Größe (Bytes)', 10, 45, 460, 245)
Global $hListView = GUICtrlGetHandle($idListView)
_GUICtrlListView_JustifyColumn($hListView, 1, 1)
_GUICtrlListView_SetColumnWidth($hListView, 1, 120)


GUISetState(@SW_SHOW, $hGui)
GUIRegisterMsg($WM_NOTIFY, 'WM_NOTIFY')


WinWaitClose($hGui)
Exit


Func _CloseGui()
	GUIDelete($hGui)
EndFunc   ;==>_CloseGui


Func _SelectPath()
	Local $sPath = FileSelectFolder('Bitte Verzeichnis auswählen', '', 0, '', $hGui)
	If @error Or Not FileExists($sPath) Then Return
	If StringRight($sPath, 1) <> '\' Then $sPath &= '\'
	GUICtrlSetData($idPath, $sPath)
	Local $aPDFFiles = _FileListToArray($sPath, '*.pdf', $FLTA_FILES), $iFileSize
	If @error Then Return
	For $i = 1 To $aPDFFiles[0]
		$iFileSize = FileGetSize($sPath & $aPDFFiles[$i])
		GUICtrlCreateListViewItem($aPDFFiles[$i] & '|' & $iFileSize, $idListView)
	Next
	_GUICtrlListView_SetColumnWidth($hListView, 0, $LVSCW_AUTOSIZE)
EndFunc   ;==>_SelectPath


Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg, $wParam
	Local $tNMHDR, $hWndFrom, $iCode, $tInfo, $iIndex, $sPath, $sFile
	$tNMHDR = DllStructCreate($tagNMHDR, $lParam)
	$hWndFrom = HWnd(DllStructGetData($tNMHDR, 'hWndFrom'))
	$iCode = DllStructGetData($tNMHDR, 'Code')
	Switch $hWndFrom
		Case $hListView ; <- das Handle vom ListView
			Switch $iCode
				Case $NM_DBLCLK ; <- Doppelklick auf ein Item
					$tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
					$iIndex = DllStructGetData($tInfo, 'Index') ; <- der Index zu dem angeklickten Item
					If $iIndex > -1 Then
						$sPath = GUICtrlRead($idPath)
						$sFile = _GUICtrlListView_GetItemText($hListView, $iIndex, 0)
						ShellExecute($sPath & $sFile)
					EndIf
			EndSwitch
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Alles anzeigen

Den dritten Punkt kriegst Du wohl alleine hin.

AutoMit

Vielen Dank Oscar für Dein gutes Beispiel.

Ich schaue mir das am Wochenende in Ruhe an.