Combobox - Defaultwert setzen - wenn die Combobox bereits gefüllt ist

AutoMit

Hallo Freunde der automatisierten Schritte,

mir gelingt es nicht, den default-Wert der Combox zu ändern, während das Programm läuft. Wisst Ihr, wie das geht?

AutoIt

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>




Local $Form_01 = GUICreate("Form_01", 262, 151, 1022, 155)
Local $Combo1 = GUICtrlCreateCombo("", 32, 24, 193, 25, BitOR($CBS_DROPDOWNLIST,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Kiwi|Apfel|Weintraube")
GUISetState(@SW_SHOW)




; diesen Wert lese ich aus einer ini-Datei, daher steht der Begriff erst ab dieser Stelle zur Verfügung
$DropDownListe = "Apfel"


; ... Wie kann ich an dieser den defaultWert der Combobox ändern?




#comments-start


so geht es nicht ... ich möchte nur den Defaultwert - also jener, der beim Start des Programmes angezeigt wird - hier festlegen, ohne dass die Werte der Combobox überschrieben werden


GUICtrlSetData($Combo_01, '',"2")
GUICtrlSetData($Combo_01, '',"Test")
GUICtrlSetData($Combo_01, ,"Test")
#comments-end




While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit


	EndSwitch
WEnd

Alles anzeigen

Viele Grüße
AutoMit

**Kanashius**

Mit der UDF:
_GuiCtrlComboBoxEx...
evtl. ohne EX, einfach mal in der Hilfe gucken.

AutoMit

Danke für den Tipp - hier gibt es eine schier ungeheure Befehlsvielfalt für die Comboboxen - da ist sicherlich was dabei. Für heute - gute Nacht

**autoBert**

Einfach

AutoIt

GUICtrlSetData($Combo1, $DropDownListe,$DropDownListe)

AutoMit

Danke autoBert.

Vor 2 Minuten gefunden - es reicht sogar:

GUICtrlSetData($Combo1, $DropDownListe)

Runa

AutoMit:

Das stimmt, allerdings nur solange, bis in der Ini ein kleiner Buchstabendreher oder ähnliches vorkommt.

GUICtrlSetData($Combo1, $DropDownListe) -> DropDownList wird um $DropDownListe ergänzt
GUICtrlSetData($Combo1, $DropDownListe, $DropDownListe) -> DropDownList wird um $DropDownListe ergänzt und dieses ausgewählt

Ich glaube, dass das nicht geplant ist: Daher hier mal dein Code ergänzt um eine Funktion die ich mal verwendet habe...

AutoIt

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
;Neuer Include
#include <GuiComboBox.au3>


Local $Form_01 = GUICreate("Form_01", 262, 151, 1022, 155)
Local $Combo1 = GUICtrlCreateCombo("", 32, 24, 193, 25, BitOR($CBS_DROPDOWNLIST,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Kiwi|Apfel|Weintraube")
GUISetState(@SW_SHOW)




;Ein "falsch geschriebener Ini-Wert"
$DropDownListe = "Ai"


;Kleine Funktion zum Setzen des Wertes nach Ähnlichkeit
_GUICtrlSetData_Combo($Combo1, $DropDownListe)


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit


	EndSwitch
WEnd


;Neue Funktionen
Func _GUICtrlSetData_Combo($hCombo, $sData)
	Local $iMin = 5000
	Local $sTemp = ""
	Local $aRead = _GUICtrlComboBox_GetListArray($hCombo)


	For $i = 1 To $aRead[0]
		$iDis = __Levenshtein($sData, $aRead[$i])
		If $iDis < $iMin Then
			$iMin = $iDis
			$sTemp = $aRead[$i]
		EndIf
	Next


	GUICtrlSetData($Combo1, $sTemp, $sTemp)
EndFunc


;Berechnet die Levenshtein-Distanz von zwei Worten
Func __Levenshtein($s, $t)
	Local $m, $n, $iMaxM, $iMaxN


	$n = StringLen($s)
	$m = StringLen($t)
	$ss = StringSplit($s, "")
	$tt = StringSplit($t, "")
	$iMaxN = $n + 1
	$iMaxM = $m + 1
	Dim $d[$iMaxN + 1][$iMaxM + 1]
	$d[0][0] = 0


	If $n = 0 Then
		Return $m
		ElseIf $m = 0 Then
		Return $n
	EndIf


	For $i = 1 To $n
		$d[$i][0] = $d[$i - 1][0] + 1
	Next
	For $j = 1 To $m
		$d[0][$j] = $d[0][$j - 1] + 1
	Next


	For $i = 1 To $n
		For $j = 1 To $m
			$jj = $j - 1
			$ii = $i - 1
			Local $cost
			If (StringMid($s, $i, 1) = StringMid($t, $j, 1)) Then
				$cost = 0
			Else
				$cost = 1
			EndIf
			$d[$i][$j] = __Min(__Min($d[$ii][$j] + 1, $d[$i][$jj] + 1), $d[$ii][$jj] + $cost)
		Next
	Next
	Return $d[$n][$m]
EndFunc


;Gibt die kleinere Zahl aus
Func __Min($iNum1, $iNum2)
	Return (Number($iNum1) > Number($iNum2)) ? Number($iNum2) : Number($iNum1)
EndFunc

Alles anzeigen

Evtl. hilft dir das ja

AutoMit

Vielen Dank Bioshade. Das ist ein sehr interessanter Script-Schnipsel, den ich am Wochenende durcharbeite. Heute brummt mein Kopf vor lauter Autoit-Zeilen