If..Then Verschachtelung umwandeln in Select..Case oder Switch..

Fintan

Ich habe da eine verschachtelte If..Then Schleife, die sehr unübersichlich geworden ist und würde die gerne umwandeln
und habs zwar im Wiki gelesen, weiß aber nicht wie ich meine so umwandeln kann.

Spoiler anzeigen

AutoIt: If..Then funktion

Func _goAngAlt()
	Local $IAngA = GUICtrlRead($InpAngAlt3) ; Jahr auslesen '8' oder '11'
	Local $AngAltGanzNum = GUICtrlRead($InpAngAlt1) & '-' & GUICtrlRead($InpAngAlt2) & '-' & $IAngA ; = AngebotsNummer 'XX-XXXX-X' oder 'XX-XXXX-XX'
	Local $OrdAngAlt = $OrdAngJa & "20" & $IAngA & "\" ; Pfad zusammen setzen "G:\Dateien\Kunden\ANGEBOT " +'20'+'8' oder '11'
	If (StringLen($IAngA) < 2) Then $OrdAngAlt = $OrdAngJa & "20" & "0" & $IAngA & "\" ; wenn nur '8' dann '20'+'0'+'8'
	Local $OrdAngAlt2 = $OrdJahrAA & "20" & $IAngA & "\" ; Pfad zusammen setzen "G:\Dateien\alte Aufträge\Kunden\ANGEBOT " +'20'+'8' oder '11'
	If (StringLen($IAngA) < 2) Then $OrdAngAlt2 = $OrdJahrAA & "20" & "0" & $IAngA & "\" ;  ; wenn nur '8' dann '20'+'0'+'8'


	If Not FileExists($OrdAngAlt) Or Not FileExists($OrdAngAlt & $AngAltGanzNum) Then ; normale 'ANGEBOT 20XX' oder 'ANGEBOT 20XX' + '01-XXXX-XX'
		If MsgBox(262144, $Inf, $LukAA, 0.3) = 1 Then
		Else
			If Not FileExists($OrdAngAlt2 & $AngAltGanzNum) Then ; alte Aufträge 01-2222-8
				If MsgBox(262144, $Inf, $LukAA, 0.3) = 1 Then
				Else
					Local $SuchOrdAngAlt = _FO_FolderSearch($OrdAngAlt2, '*' & $AngAltGanzNum, True, 0, 0, 0) ; Suche nach Ordner 'AN-01-XXXX-XX'
					If Not (StringLen($SuchOrdAngAlt) > 10) Then ; alte Aufträge Suche: AN-01-2222-8
						If MsgBox(262144, $Inf, $LukAA, 0.3) = 1 Then
						Else
							Local $SuchAngAlt2 = _FO_FolderSearch($OrdAufJa & "20" & $IAngA, $AngAltGanzNum, True, 2, 0, 0) ; Suche nach Ordner '01-XXXX-14' im AUFTRAG 2014
							If $SuchAngAlt2 = "" Then ; alte Aufträge Suche 'AUFTRAG 20XX' +Suchfund
								If MsgBox(262144, $Inf, $LukAA, 0.3) = 1 Then
								Else
									Local $SuchAngAlt3 = _FO_FolderSearch($OrdAufJa & "20" & $IAngA + 1, $AngAltGanzNum, True, 2, 0, 0) ; Suche nach Ordner '01-XXXX-14' im AUFTRAG 2015
									If $SuchAngAlt3 = "" Then ; alte Aufträge Suche 'AUFTRAG 20XX'+1
										MsgBox(262208, 'Such-Info', 'Ordner Leider Nicht da!' & @LF & @LF & _
												'Such-Ordner = ' & $OrdAufJa & "20" & $IAngA + 1 & @LF & @LF & _
												'Such-Nummer = ' & $AngAltGanzNum, 11)
									Else
										ShellExecute($SuchAngAlt3, "", $OrdAufJa & "20" & $IAngA + 1, "open") ; öffnet alte Aufträge Suche 'AUFTRAG 20XX' + 1 +Suchfund +'01-XXXX-XX'
										Sleep(600)
										MsgBox(262144, 'Info', '' & @LF & _
												$OrdAufJa & "20" & $IAngA + 1 & @LF & @LF & _
												$SuchAngAlt3, 11)
									EndIf
								EndIf
							Else
								ShellExecute($SuchAngAlt2, "", $OrdAufJa & "20" & $IAngA, "open") ; öffnet alte Aufträge Suche 'AUFTRAG 20XX' +Suchfund +'01-XXXX-XX'
								Sleep(600)
								MsgBox(262144, 'Info', '' & @LF & _
										$OrdAufJa & "20" & $IAngA & @LF & @LF & _
										$SuchAngAlt2, 11)
							EndIf
						EndIf
					Else
						ShellExecute($SuchOrdAngAlt, "", $OrdAngAlt2, "open") ; öffnet alte Aufträge Suche 'ANGEBOT 200X' + 'AN-01-XXXX-XX'
						Sleep(600)
						MsgBox(262144, 'Info', '' & @LF & _
								$OrdAngAlt2 & @LF & @LF & _
								$SuchOrdAngAlt, 11)
					EndIf
				EndIf
			Else
				ShellExecute($AngAltGanzNum, "", $OrdAngAlt2, "open") ; öffnet alte Aufträge 'ANGEBOT 20XX' + '01-XXXX-XX'
			EndIf
		EndIf
	Else
		ShellExecute($AngAltGanzNum, "", $OrdAngAlt, "open") ; öffnet normale 'ANGEBOT 20XX' + '01-XXXX-XX'
	EndIf
EndFunc   ;==>_goAngAlt

Alles anzeigen

**Kanashius**

Habs jetzt so gekürzt:

AutoIt

Func _goAngAlt()
	Local $IAngA = GUICtrlRead($InpAngAlt3) ; Jahr auslesen '8' oder '11'
	Local $AngAltGanzNum = GUICtrlRead($InpAngAlt1) & '-' & GUICtrlRead($InpAngAlt2) & '-' & $IAngA ; = AngebotsNummer 'XX-XXXX-X' oder 'XX-XXXX-XX'
	Local $OrdAngAlt = $OrdAngJa & "20" & $IAngA & "\" ; Pfad zusammen setzen "G:\Dateien\Kunden\ANGEBOT " +'20'+'8' oder '11'
	If (StringLen($IAngA) < 2) Then $OrdAngAlt = $OrdAngJa & "20" & "0" & $IAngA & "\" ; wenn nur '8' dann '20'+'0'+'8'
	Local $OrdAngAlt2 = $OrdJahrAA & "20" & $IAngA & "\" ; Pfad zusammen setzen "G:\Dateien\alte Aufträge\Kunden\ANGEBOT " +'20'+'8' oder '11'
	If (StringLen($IAngA) < 2) Then $OrdAngAlt2 = $OrdJahrAA & "20" & "0" & $IAngA & "\" ;  ; wenn nur '8' dann '20'+'0'+'8'
	If Not FileExists($OrdAngAlt) Or Not FileExists($OrdAngAlt & $AngAltGanzNum) Then ; normale 'ANGEBOT 20XX' oder 'ANGEBOT 20XX' + '12-XXXX-XX'
		If MsgBox(262144, $Inf, $LukAA, 0.3) = 1 Then return -1
		If Not FileExists($OrdAngAlt2 & $AngAltGanzNum) Then ; alte Aufträge 12-2222-8
			If MsgBox(262144, $Inf, $LukAA, 0.3) = 1 Then return -1
			Local $SuchOrdAngAlt = _FO_FolderSearch($OrdAngAlt2, '*' & $AngAltGanzNum, True, 0, 0, 0) ; Suche nach Ordner 'AN-12-XXXX-XX'
			If Not (StringLen($SuchOrdAngAlt) > 10) Then ; alte Aufträge Suche: AN-12-2222-8
				If MsgBox(262144, $Inf, $LukAA, 0.3) = 1 Then return -1
				Local $SuchAngAlt2 = _FO_FolderSearch($OrdAufJa & "20" & $IAngA, $AngAltGanzNum, True, 2, 0, 0) ; Suche nach Ordner '12-XXXX-14' im AUFTRAG 2014
				If $SuchAngAlt2 = "" Then ; alte Aufträge Suche 'AUFTRAG 20XX' +Suchfund
					If MsgBox(262144, $Inf, $LukAA, 0.3) = 1 Then return -1
					Local $SuchAngAlt3 = _FO_FolderSearch($OrdAufJa & "20" & $IAngA + 1, $AngAltGanzNum, True, 2, 0, 0) ; Suche nach Ordner '12-XXXX-14' im AUFTRAG 2015
					If $SuchAngAlt3 = "" Then ; alte Aufträge Suche 'AUFTRAG 20XX'+1
						MsgBox(262208, 'Such-Info', 'Ordner Leider Nicht da!' & @LF & @LF & _
								'Such-Ordner = ' & $OrdAufJa & "20" & $IAngA + 1 & @LF & @LF & _
								'Such-Nummer = ' & $AngAltGanzNum, 11)
					Else
						_execute($SuchAngAlt3,$OrdAufJa & "20" & $IAngA + 1,@LF & $OrdAufJa & "20" & $IAngA + 1 & @LF & @LF & $SuchAngAlt3)
					EndIf
				Else
					_execute($SuchAngAlt2,$OrdAufJa & "20" & $IAngA,@LF & $OrdAufJa & "20" & $IAngA & @LF & @LF & $SuchAngAlt2)
				EndIf
			Else
				_execute($SuchOrdAngAlt,$OrdAngAlt2,@LF & $OrdAngAlt2 & @LF & @LF & $SuchOrdAngAlt)
			EndIf
		Else
			_execute($AngAltGanzNum,$OrdAngAlt2) ; öffnet alte Aufträge 'ANGEBOT 20XX' + '12-XXXX-XX'
		EndIf
	Else
		_execute($AngAltGanzNum,$OrdAngAlt) ; öffnet normale 'ANGEBOT 20XX' + '12-XXXX-XX'
	EndIf
EndFunc   ;==>_goAngAlt


Func _execute($execute,$workDir,$msg=-1)
	ShellExecute($execute, "", $workDir, "open")
	if $msg<>-1 then
		Sleep(600)
		MsgBox(262144, 'Info', $msg, 11)
	endif
EndFunc

Alles anzeigen

Mehr kann man schlecht kürzen, ohne zu wissen, wie genau das Funktionieren soll.
Man muss zum vereinfachen regelmäßigkeiten suchen, die immer gleich sind. Oft helfen bei so etwas auch arrays, z.B. wenn man mehrere Ordner auf genau die gleiche Weise durchsuchen will,...
Mit nem return -1 springt man übrigens aus einer Funktion heraus und gibt -1 zurück, dort kann auch eine andere Rückgabe erfolgen, auf die dann reagiert werden kann. Dadurch spart man sich z.B. riesige If/Else Blöcke, bzw. die wo nichts passieren soll.

MfG Kanashius

Fintan

Interessante Möglichkeit, mich würde aber lieber die zuvor gefragte Select..case Variante interessieren..
Ich bräuchte halt ein konkretes beispiel mit einer meinen If--then Schleifen, damit ich verstehe wie sowas geht.

Wie man vielleicht erkennen kann, will ich mit verschiedenen Eingaben mehrere Ordner durchsuchen.

- mit '01-1111-8' soll 'Angebot 2008' + 'alte Angebot 2008' oder 'alte Angebot 2008' mit 'AN-01-1111-8' -Ordnern durchsucht werden.
- mit '01-1111-12' soll 'Angebot 2012' + 'alte Angebot 2012' oder 'Auftrag 2012' oder 'Auftrag 2013' durchsucht werden.

Das sind schon 5 Ordnersuchvarianten...

**autoBert**

wenn du ein lauffähiges DemosKript (consolewrite für evtl. Aktionen) machst, mache ich mir die Mühe es auf select ... endselecet umzusetzen, es wird aber mit Sicherheit auch verschachtelt sein => können wir uns also die Mühe sparen, ist keine laufzeit kritische Anwendung! (Und funktioniert bereits)

**Kanashius**

Aus der Hilfe:

AutoIt

#include <MsgBoxConstants.au3>


Example()


Func Example()
    Local $iValue = 0
    Local $sBlank = "Test"


    Select
        Case $iValue = 1
            MsgBox($MB_SYSTEMMODAL, "", "The first expression was True.")
        Case $sBlank = "Test"
            MsgBox($MB_SYSTEMMODAL, "", "The second expression was True")
        Case Else ; If nothing matches then execute the following.
            MsgBox($MB_SYSTEMMODAL, "", "No preceding case was True.")
    EndSelect
EndFunc   ;==>Example

Alles anzeigen

Dazugehörig die If-Bedingung:

AutoIt

#include <MsgBoxConstants.au3>


Example()


Func Example()
    Local $iValue = 0
    Local $sBlank = "Test"
    if $iValue=1 then
        MsgBox($MB_SYSTEMMODAL, "", "The first expression was True.")
    elseif $sBlank = "Test" then
        MsgBox($MB_SYSTEMMODAL, "", "The second expression was True")
    else
        MsgBox($MB_SYSTEMMODAL, "", "No preceding case was True.")
    endif
EndFunc   ;==>Example

Alles anzeigen

Ist also eigentlich fast nur eine andere Schreibweise (intern sind dort noch nen paar unterschiede)
Die Bedingungen musst du also immernoch mehrfach aufzählen. Deshalb hatte ich nichts damit eingebaut. Es macht hier nicht wirklich Sinn.

Habs jetzt mal so umgeschrieben, wie es zu dem passt, wie dus beschrieben hast. Das mit der Suche könnte man noch ändern, jenachdem, was für Bedingungen es dort gibt.
Hoffe, ich habs richtig verstanden:

AutoIt

;Ordner mit | getrennt, Wenn was vor den Dateinamen soll mit & an den Ordner anhängen
$arSearchFolders=[ _
					[""], _;2000
					[""], _;2001
					[""], _;2002
					[""], _;2003
					[""], _;2004
					[""], _;2005
					[""], _;2006
					[""], _;2007
					["Angebot 2008|alte Angebot 2008|alte Angebot 2008&AN-"], _;2008
					[""], _;2009
					[""], _;2010
					[""], _;2011
					["Angebot 2012|alte Angebot 2012|Auftrag 2012|Auftrag 2013"], _;2012
				 ]

_search("01-1111-8")


Func _search($sEingabe)
	$tmpIndex=StringInStr($sEingabe,"-",0,-1)
	$iYear=Int(StringRight($sEingabe,StringLen($sEingabe)-$tmpIndex))
	$arFolders=_searchFor("C:\Ordner",$iYear,$sEingabe)
	for $i=0 to UBound($arFolders)-1 step 1
		MsgBox(48,"Info","Found: "&@crlf&$arFolders[$i]);@LF ist unter Linux/iOS verbreitet, Windows nutzt @crlf, sonst keine Zeilenumbrüche im Notepad, z.b.
	next
EndFunc


Func _searchFor($sFolder,$sYear,$sFile)
	local $arFoundFiles[0]
	$sFolders=$arSearchFolders[$sYear]
	$arFolders=StringSplit($sFolders,"|",1+2)
	For $i=0 to UBound($arFolders)-1 step 1
		$arInfos=StringSplit($arFolders[$i],"&",1+2)
		$tmpFile=$sFile
		if UBound($arInfos)>0 then $tmpFile=$arInfos[1]&$sFile
		If FileExists($sFolder&"\"&$arInfos[0]&"\"&$tmpFile) Then
			ReDim $arFoundFiles[UBound($arFoundFiles)+1]
			$arFoundFiles[UBound($arFoundFiles)-1]=$sFolder&"\"&$arInfos[0]&"\"&$tmpFile
		EndIf
	next
	return $arFoundFiles
EndFunc

Alles anzeigen

Fintan

Kanashius, ah du hast dir so eine Mühe gemacht, danke.
Hilfe lesen habe ich kein Problem, eher mit der Umsetzung, bin also wirklich noch Anfänger.

Also mich würde nur die _goAngAlt Funktion in Zeile 232 im Script interessieren, alle anderen kann man lassen.Suchfunktion habe ich ja schon mit _FO_FolderSearch, hängt am Ende vom Script, mir ging es wirlich nur um die Umformulierung.
Habe gedacht, das sieht man im Script-fetzen von Oben.

Und die 01-1111-12 wird mit 3 Inputs ausgelesen, worauf dann die einzelnen Suchen begründen ...

Fintan

@ Kanashius
Hm, ich weiß nicht wie/wo ich meine Pfade in dein Script schreiben soll, weil es 2 verschiede sind.
G:\Dateien\Kunden\ANGEBOT \ AUFTRAG
G:\Dateien\alte daten\Kunden\ANGEBOT \ AUFTRAG

Ich brauche schon die _FO_FolderSearch Suchfunktion, damit kann ich dann Ordner suchen die einen Unbekannten Ordner enthalten kann.
G:\Dateien\Kunden\AUFTRAG 2014\02-XXXX-14\01-8888-14

Meine konstruierten Pfade sind etwas verwirrend, aber die brauche ich so konstruiert, damit das Script funktioniert...