SoundPlay Ausgabegerät wählen

fausti96

Hallo,

ich suche eine Möglichkeit bei der Soundplay Funktion einen Parameter mitzugeben, um auszuwählen über welches Ausgabegerät der Sound dann ausgegeben werden soll.
Ich nutze eine Interne Soundkarte und ein USB Headset und möchte den Ton meines Skrips immer auf meinem Headset wiedergeben.
Das Headset bildet eine eigene Soundkarte ab und ist als Windowskommunikationsgerät eingestellt.
Gibt es also eine Möglichkeit den SoundPlay auf dieses Gerät einzustellen, sodass nicht das Windows Standartgerät genzut wird?

Ich hoffe ihr könnt mir weiterhelfen

Liebe Grüße

**Kanashius**

Dafür musst du dir die BASS-UDF ansehen.
Ansonsten das Sound-Objekt bei MSDN. Es gibt ein Objekt, um die Lautsprecher zu abzurufen und zu setzen (zumindest bei TTS).

fausti96

Okay vielen Dank...

Schade dass es da keine möglichkeit gibt das wäre schön einfach gewesen...
Leider blicke ich bei der BASS-UDF kein bisschen durch und kann leider auch keine gescheite Einführung finden
Hätte jemand einen Ansatz für mich wie ich das ganze Aufbauen muss.

Ziel ist es mein Sript zu starten und so eine Audiodatei über die dann festegelegte Soundkarte wiederzugeben. Mehr Funktionen benötige ich nicht.

Schon mal DANKE

**Kanashius**

Hab hier mal die entsprechenden Stellen aus nem Script von mir rausgesucht:

AutoIt

;Create Combo
$hGUIDeviceCombo=_GUICtrlComboBoxEx_Create($StreamWindow, "", 5,80, $width-40)


;Get Devices
_GUICtrlComboBoxEx_ResetContent($hGUIDeviceCombo)
$i = 0
While 1
	$device = _BASS_GetDeviceInfo($i)
	If $device = 0 Then
		ExitLoop
	EndIf
	If $device[0] <> "No Sound" Then
		_GUICtrlComboBoxEx_AddString($hGUIDeviceCombo, $device[0])
	EndIf
	$i += 1
WEnd


GUICtrlSetOnEvent(_GUICtrlComboBoxEx_GetComboControl($hGUIDeviceCombo), "_setDevice")


;SetDevice
Local $sText
$nr = _GUICtrlComboBoxEx_GetCurSel($hGUIDeviceCombo)
;_GUICtrlComboBoxEx_GetItemText($hGUIDeviceCombo, $nr, $sText)
$device = _BASS_GetDeviceInfo($nr + 1)
If $device[2] < 4 Then
	_BASS_Init(0, $nr + 1, 100000, 0, "")
EndIf
_BASS_ChannelSetDevice($MusicHandle, $nr + 1)


;Create Stream, _BASS_Init must be called before (SetDevice)
$MusicHandle = _BASS_StreamCreateFile(False, $sFile, 0, 0, 0)
If $aktDevice[0] <> -1 Then
	_BASS_ChannelSetDevice($MusicHandle, $aktDevice[0] + 1);aktDevice ist Number of selected device in combobox
EndIf
_BASS_ChannelPlay($MusicHandle, 1)
local $vol=100
_BASS_ChannelSetAttribute($MusicHandle, $BASS_ATTRIB_VOL, $vol / 100)

Alles anzeigen

Musst dir das dann zusammenbasteln

Falls du noch Ideen/Anregungen brauchst, aus dem Script hab ich das:
MusikPlayer mit Equalizer,Playlist, etc.

Ist nen Musicplayer, den ich mal geschrieben habe.

MfG Kanashius

**eukalyptus**

Mit DirectSound geht das auch ohne externe DLL:

AutoIt

#include "DirectSound.au3"
#include <Array.au3>






Global $aDevice = _DSnd_Enumerate()
_ArrayDisplay($aDevice)




Global $aSND1 = _SND_Play("Test.wav", 2)
Global $aSND2 = _SND_Play("Test.mp3", 3)




While _SND_IsPlaying($aSND1) Or _SND_IsPlaying($aSND2)
	ToolTip("Sound1:  " & StringFormat("%.1f", _SND_GetPosition($aSND1) * 100) & "%" & @CRLF & "Sound2:  " & StringFormat("%.1f", _SND_GetPosition($aSND2) * 100) & "%")
	Sleep(100)
WEnd


_SND_Stop($aSND1)
_SND_Stop($aSND2)












Func _SND_Play($sFile, $iDevice = 1, $fVolume = 1)
	Local $aWav = _DSnd_WaveLoadFromFile($sFile)
	If @error Then
		Local $hFile = FileOpen($sFile, 16)
		Local $bFile = FileRead($sFile)
		FileClose($hFile)
		$aWav = _DSnd_MP3Decode($bFile)
	EndIf


	If Not IsArray($aWav) Then Return SetError(1, 0, False)


	Switch $aWav[1].FormatTag
		Case $WAVE_FORMAT_MPEG, $WAVE_FORMAT_MPEGLAYER3
			$aWav = _DSnd_MP3Decode($aWav[0])
			If @error Then Return SetError(1, 1, False)
	EndSwitch


	Local $aDevice = _DSnd_Enumerate()
	If @error Or Not IsArray($aDevice) Then Return SetError(1, 2, False)
	If $iDevice < 1 Then
		$iDevice = 1
	ElseIf $iDevice > $aDevice[0][0] Then
		$iDevice = $aDevice[0][0]
	EndIf


	Local $aSND[3]
	$aSND[0] = _DSnd_Create($aDevice[$iDevice][2])
	$aSND[1] = _DSnd_CreateSoundBuffer($aSND[0], BitOR($DSBCAPS_GLOBALFOCUS, $DSBCAPS_CTRLVOLUME), BinaryLen($aWav[0]), $aWav[1].Channels, $aWav[1].SamplesPerSec, $aWav[1].BitsPerSample, $aWav[1].FormatTag)
	$aSND[2] = BinaryLen($aWav[0])


	Local $aLock = _DSnd_BufferLock($aSND[1])
	Local $tBuffer = DllStructCreate("byte[" & $aLock[1] & "];", $aLock[0])
	DllStructSetData($tBuffer, 1, $aWav[0])
	_DSnd_BufferUnLock($aSND[1], $aLock)


	_SND_SetVolume($aSND, $fVolume)
	_DSnd_BufferPlay($aSND[1])


	Return $aSND
EndFunc   ;==>_SND_Play




Func _SND_Stop(ByRef $aSND)
	If Not IsArray($aSND) Or UBound($aSND) <> 3 Then Return SetError(1, 0, False)
	$aSND[1].Stop()
	$aSND[1] = 0
	$aSND[0] = 0
	$aSND = 0
EndFunc   ;==>_SND_Stop




Func _SND_SetVolume($aSND, $fVolume)
	If Not IsArray($aSND) Or UBound($aSND) <> 3 Then Return SetError(1, 0, False)


	If $fVolume < 0.00001 Then
		$fVolume = 0.00001
	ElseIf $fVolume > 1 Then
		$fVolume = 1
	EndIf


	Local $fDB = 20 * Log($fVolume) / Log(10)
	$aSND[1].SetVolume($fDB * 100)
EndFunc   ;==>_SND_SetVolume




Func _SND_IsPlaying($aSND)
	If Not IsArray($aSND) Or UBound($aSND) <> 3 Then Return SetError(1, 0, False)
	Local $iStatus
	$aSND[1].GetStatus($iStatus)
	Return BitAND($iStatus, $DSBSTATUS_PLAYING)
EndFunc   ;==>_SND_IsPlaying




Func _SND_GetPosition($aSND)
	If Not IsArray($aSND) Or UBound($aSND) <> 3 Then Return SetError(1, 0, False)
	Local $iPos
	$aSND[1].GetCurrentPosition($iPos, Null)
	Return $iPos / $aSND[2]
EndFunc   ;==>_SND_GetPosition

Alles anzeigen

Die benötigte DirectSound-UDF findest du in meinem Anhang