Fokus bei Mausklick WM_CHILD

**eukalyptus**

Hi

Ich habe folgendes Problem:
In einem Hauptfenster hab ich mehrere Child-Fenster.
Wenn ich nun mit der Maus auf das Child-Fenster klicke, welches hinter dem anderen Child liegt, dann kommt es nicht in den Vordergrund.

In den Vordergrund kommt es nur, wenn man auf die Titelleiste klickt.
Und auch nur dann, wenn man kurz klickt! - Wenn man die Maustaste gedrückt hält und dann erst loslässt, bleibt das Fenster im Hintergrund.

Was mach ich falsch?
Oder kenn jemand einen Workaround?

Hier der Code:

AutoIt

#include <WindowsConstants.au3>


$hGui = GUICreate("Main", 800, 600)


$hChild1 = GUICreate("Child 1", 300, 200, 10, 10, BitOR($WS_CHILD, $WS_CAPTION), 0, $hGui)
$hChild2 = GUICreate("Child 2", 300, 200, 200, 210, BitOR($WS_CHILD, $WS_CAPTION), 0, $hGui)


GUISetState(@SW_SHOW, $hGui)
GUISetState(@SW_SHOW, $hChild1)
GUISetState(@SW_SHOW, $hChild2)


While GUIGetMsg() <> -3
WEnd

Alles anzeigen

Vielen Dank!

**Kanashius**

Ich seh so keinen Fehler...
Als Workaround:
Wenn WinActivate funktioniert -> mit GuiRegisterMsg auf Mausklicks reagieren und das Fenster einblenden, wenn es im Hintergrund ist, und ein anderes Childfenster im Vordergrund.

EDIT:
grad mal getestet:

AutoIt

#include <WindowsConstants.au3>
$hGui = GUICreate("Main", 800, 600)
$hChild1 = GUICreate("Child 1", 300, 200, 10, 10, BitOR($WS_CHILD, $WS_CAPTION), 0, $hGui)
$hChild2 = GUICreate("Child 2", 300, 200, 200, 210, BitOR($WS_CHILD, $WS_CAPTION), 0, $hGui)
GUISetState(@SW_SHOW, $hGui)
GUISetState(@SW_SHOW, $hChild1)
GUISetState(@SW_SHOW, $hChild2)


GUIRegisterMsg($WM_LBUTTONDOWN,"WM_LBUTTONDOWN")


While GUIGetMsg() <> -3
WEnd


Func WM_LBUTTONDOWN($hWnd, $iMsg, $wParam, $lParam)
	ConsoleWrite($hWnd&":"&$iMsg&":"&$wParam&":"&$lParam&@crlf)
	if $hWnd=WinGetHandle($hChild1) then
		WinActivate($hChild1)
	else
		WinActivate($hChild2)
	endif
EndFunc

Alles anzeigen

IWie funktioniert das mit WinActivate nicht. Hab auch probiert mit SW_HIDE,... Geht alles nicht. wird wohl doch schwieriger

**Raupi**

Probier es einfach so:

AutoIt

#include <WindowsConstants.au3>


$hGui = GUICreate("Main", 800, 600)


$hChild1 = GUICreate("Child 1", 300, 200, 10, 10, BitOR($WS_CHILD, $WS_CAPTION), $WS_EX_CONTROLPARENT , $hGui)
$hChild2 = GUICreate("Child 2", 300, 200, 200, 210, BitOR($WS_CHILD, $WS_CAPTION), $WS_EX_CONTROLPARENT , $hGui)


GUISetState(@SW_SHOW, $hGui)
GUISetState(@SW_SHOW, $hChild1)
GUISetState(@SW_SHOW, $hChild2)


While GUIGetMsg() <> -3
WEnd

Alles anzeigen

Bei klick auf das Child, kommt es in den Vordergrund.
Edit: Leider hat es aber auch den selben Fehler wie mit der Titelzeile, langes klicken holt es nicht in den Vordergrund.

**eukalyptus**

DANKE!
Das hilft schonmal.

Ich helf mir noch zusätzlich mit diesem Workaround:

AutoIt

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>


$hGui = GUICreate("Main", 800, 600)


$hChild1 = GUICreate("Child 1", 300, 200, 10, 10, BitOR($WS_CHILD, $WS_CAPTION), 0, $hGui)
$hChild2 = GUICreate("Child 2", 300, 200, 200, 210, BitOR($WS_CHILD, $WS_CAPTION), 0, $hGui)


GUISetState(@SW_SHOW, $hGui)
GUISetState(@SW_SHOW, $hChild1)
GUISetState(@SW_SHOW, $hChild2)


GUIRegisterMsg($WM_MOUSEACTIVATE, "WM_MOUSEACTIVATE")


While GUIGetMsg() <> -3
WEnd




Func WM_MOUSEACTIVATE($hWnd, $iMsg, $wParam, $lParam)
	Switch $hWnd
		Case $hChild1, $hChild2
			_SendMessage($hWnd, $WM_NCLBUTTONDOWN, $HTCAPTION, Null)


	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_MOUSEACTIVATE

Alles anzeigen