Per Tastenkombination vordefinierte Chatnachrichten senden ?

Lanius

Hallo.

Ich würde gerne über eine Tastenkombination eine vordefinierte Nachricht in einem Spielechat senden. Idealerweise hätte ich gern 3 Nachrichten zum Senden zur Verfügung die abhängig wie oft ich diese Tastenkombination innerhalb von sagen wir mal 1 Sekunde drücke gesendet werden.

Um es etwas ausführlicher zu beschreiben hier mal meine aktuelle Situation...
Ich fahre nicht gut, aber gerne ProjectCars mit einem Lenkrad. Mit dem Tool JoytoKey erleichter ich mir gerade schon ein wenig das Leben im Spiel, zumal die Tasten an meinem Lenkrad begrenzt sind. Ich möchte eine Taste am Lenkrad über JoytoKey einer Tastenkombination zuweisen. Von mir aus STRG + T...
AutoIt soll jetzt also auf "STRG+T" reagieren und abhängig davon wie oft es in einer Sekunde gesendet habe eine vordefinierte Nachricht senden. Denke 3 wären genial, wobei mir erstmal nur 2 einfallen würden. Um eine Nachricht im Spiel zu senden muß das "T" für den Chat gedrückt werden, dann die Nachricht und mit "ENTER" bestätigen.

Ich weiß von AutoIt, Programmieren oder Skripten so gut wie gar nichts... Ist so etwas durchführbar ? Kann mir jemand vielleicht etwas unter die Arme greifen wonach ich suchen muß, oder idealerweise mir schon ein paar Codeschnipsel hinwerfen ?
Bin für jede Idee und Tip dankbar...

M.f.G.
Markus

**Kanashius**

Das Script sollte Chat schreiben können. Um die Tastenkombi zu ändern sieh dir Zeile 6 und 12 an. Mit durck von F1 auf _IsPressed kommst du in die Hilfe, da findest du die KeyCodes.
Um Nachrichten hinzuzufügen musst du nur den Switch in Zeile 23 erweitern. Mit ALT+ESC schließt man das Programm.

AutoIt

#include <Misc.au3>
#include <MsgBoxConstants.au3>
Global $TimeDifference=300
Local $hDLL = DllOpen("user32.dll")
While sleep(10)
	;Senden mit T+STRG
	If _IsPressed("11", $hDLL) and _IsPressed("54", $hDLL) Then
        $timerStart=TimerInit()
		;Herausfinden, wann losgelassen wird
        While _IsPressed("11", $hDLL) and _IsPressed("54", $hDLL)
            Sleep(10)
        WEnd
		;senden
		_sendChatTime(TimerDiff($timerStart))
	;Schließen mit ESC+ALT
    ElseIf _IsPressed("1B", $hDLL) and _IsPressed("12", $hDLL) Then
        ExitLoop
    EndIf
WEnd
DllClose($hDLL)
exit


Func _sendChatTime($time)
	_sendChatNr(int($time/$TimeDifference))
EndFunc


Func _sendChatNr($number)
	Switch $number
		Case 0
			_sendChat("Message1")
		Case 1
			_sendChat("Message2")
		Case 2
			_sendChat("Message3")
		Case Else
			;do nothing
	EndSwitch
EndFunc


Func _sendChat($message)
	;Actives Fenster ermitteln
	$handle=WinGetHandle("[active]")
	;Senden
	ControlSend($handle,"",0,"{t}")
	ControlSend($handle,"",0,$message)
	ControlSend($handle,"",0,"{ENTER}")
EndFunc

Alles anzeigen

Kann aber gut sein, dass dein Programm das schreiben nicht nimmt. Oft wird sowas verhindert.

MfG Kanashius

Lanius

WOW, das ging ja schnell... Das das Spiel die Eingaben annimmt bin ich mir ziemlich sicher. Ich danke dir recht herzlich und will nicht undankbar klingen, allerdings habe ich mich vielleicht etwas falsch ausgedrückt.
Das Skript sendet jetzt ja abhängig von der Länge des Tastendrucks eine Nachricht, ich würde es allerdings abhängig von der Anzahl eines bestimmten Zeitraums bevorzugen...
Also 1x Drücken innerhalb einer Sekunde=Text1, 2x Drücken in einer Sekunde=Text2, usw. Ob jetzt genau 1 Sekunde ein guter Zeitraum ist weiß ich noch nicht, aber so in etwa... Ich halte es für einfacher im Renngeschehen mal eben 1-3x zu drücken, als mich auf die Länge des Drückens zu konzentrieren.
Aber so muß ich mich ja nur noch um eine "Funktion" kümmern und Google befragen.
Wie gesagt, vielen Dank dafür...
M.f.G.
Markus

Runa

Angepasste Version von Kanashius' Script:

AutoIt

#include <Misc.au3>
#include <MsgBoxConstants.au3>


Global $iPressTime = 1000 ;Zeitspanne bis zum Senden der Nachricht in Millisekunden (1s = 1000 ms)


Local $hDLL = DllOpen("user32.dll")
While sleep(10)
	;Senden mit T+STRG
	If _IsPressed("11", $hDLL) and _IsPressed("54", $hDLL) Then
		Local $iCount = 1
        $timerStart=TimerInit()
		Do
			; Auf weitere Tastendrücke warten
			If _IsPressed("11", $hDLL) and _IsPressed("54", $hDLL) Then
				;Warten bis Taste losgelassen wird
				While _IsPressed("11", $hDLL) and _IsPressed("54", $hDLL)
					Sleep(10)
				WEnd
				;Zähler für Anzahl der Tastendrücke erhöhen, sobald Taste losgelassen wird
				$iCount += 1
			EndIf
		; Bis eine Sekunde vergangen ist
		Until TimerDiff($timerStart) > $iPressTime
		;senden
		_sendChatNr(TimerDiff($timerStart))
	;Schließen mit ESC+ALT
    ElseIf _IsPressed("1B", $hDLL) and _IsPressed("12", $hDLL) Then
        ExitLoop
    EndIf
WEnd


DllClose($hDLL)
exit


Func _sendChatNr($number)
	Switch $number
		Case 0
			_sendChat("Message1")
		Case 1
			_sendChat("Message2")
		Case 2
			_sendChat("Message3")
		Case Else
			_sendChat("Message3")
	EndSwitch
EndFunc


Func _sendChat($message)
	;Actives Fenster ermitteln
	$handle=WinGetHandle("[active]")
	;Senden
	ControlSend($handle,"",0,"{t}")
	ControlSend($handle,"",0,$message)
	ControlSend($handle,"",0,"{ENTER}")
EndFunc

Alles anzeigen

Lanius

Das angepasste Skript funktionierte irgendwie nicht...
Ich habe da jetzt mal eben schnell drin rumgepfuscht und auf den ersten Blick scheint es jetzt so zu funktionieren. Das habe ich allerdings gemacht ohne wirklich zu wissen was ich hier tue, wäre nett wenn vielleicht jemand nochmal drauf schauen könnte...

AutoIt

#include <Misc.au3>
#include <MsgBoxConstants.au3>


Global $iPressTime = 1000 ;Zeitspanne bis zum Senden der Nachricht in Millisekunden (1s = 1000 ms)


Local $hDLL = DllOpen("user32.dll")
While sleep(10)
	;Senden mit T+STRG
	If _IsPressed("11", $hDLL) and _IsPressed("54", $hDLL) Then
		Local $iCount = 0
        $timerStart=TimerInit()
		Do
			; Auf weitere Tastendrücke warten
			If _IsPressed("11", $hDLL) and _IsPressed("54", $hDLL) Then
				;Warten bis Taste losgelassen wird
				While _IsPressed("11", $hDLL) and _IsPressed("54", $hDLL)
					Sleep(10)
				WEnd
				;Zähler für Anzahl der Tastendrücke erhöhen, sobald Taste losgelassen wird
				$iCount = $iCount + 1
			EndIf
		; Bis eine Sekunde vergangen ist
		Until TimerDiff($timerStart) > $iPressTime
		;senden
		_sendChatNr($iCount)
	;Schließen mit ESC+ALT
    ElseIf _IsPressed("1B", $hDLL) and _IsPressed("12", $hDLL) Then
        ExitLoop
    EndIf
WEnd


DllClose($hDLL)
exit


Func _sendChatNr($number)
	Switch $number
		Case 1
			_sendChat("Message1")
		Case 2
			_sendChat("Message2")
		Case 3
			_sendChat("Message3")
		Case Else
			_sendChat("Message4")
	EndSwitch
EndFunc


Func _sendChat($message)
	;Actives Fenster ermitteln
	$handle=WinGetHandle("[active]")
	;Senden
	ControlSend($handle,"",0,"{t}")
	ControlSend($handle,"",0,$message)
	ControlSend($handle,"",0,"{ENTER}")
EndFunc

Alles anzeigen

Runa

Jup, gerade gesehen, Zeile 25 hatte ich nicht angepasst. Das wäre die einzige Stelle gewesen, die du hättest anpassen müssen, aber dein angepasstes Script stimmt dann natürlich auch.

**autoBert**

als Beigeordneter der International GamePlaying DriverAssociation mache ich auf Artikel 14.3 Satz 2 aufmerksam:

Zitat von Regelwerk der VGpWM

Die Untersagung jeglichen Funkverkehrs zwischen den Fahren gilt ausdrücklich auch für Textnachrichten jeglicher Art.

es gab in der letzten Saison zuviele Unfälle durch Fahrer die durch das Lesen einer Nachricht abgelenkt waren, deshalb hat die VGpWM auch diese für alle Veranstaltungen untersagt.

Edit: die Ausnahmen nach 14.8 für den Funkverkehr gelten natürlich auch für Textnachrichten:

Zitat

Ausgenommen sind:

Warnmeldungen bezüglich Trümmerteilen und gefährlichen Flüßigkeiten auf der Strecke bis zum 2. Passieren der Stelle.

jegliche Meldung, z.B.: Gratulation nach Ablauf einer Trainingssession, Rennens.

Lanius

Danke euch allen...
Ich werde nochmal eine Rückmeldung geben ob es im Spiel auch so gut funktioniert, weiß nur noch nicht ob ich es gleich heute schaffe.
Grundsätzlich hoffe ich ja das ich hiervon im Spiel kein/kaum Gebrauch machen muß... Mir geht es hier nämlich darum mal für mich entspannt ein "Sorry" absetzen zu können falls ich nicht aufgepasst habe. Vielleicht noch einen 2. Text um sich mal zu beschweren...
Wünsche allen ein schönes Wochenende!
M.f.G.
Markus

Kawooshe

@Lanius Ich würde dieses script jedoch bevorzugen:

C

#include <Misc.au3>
#include <MsgBoxConstants.au3>
Global $iPressTime = 1000 ;Zeitspanne bis zum Senden der Nachricht in Millisekunden (1s = 1000 ms)
Local $hDLL = DllOpen("user32.dll")
While sleep(10)
	;Senden mit T+STRG
	If _IsPressed("11", $hDLL) and _IsPressed("54", $hDLL) Then
		Local $iCount = 0
        $timerStart=TimerInit()
		Do
			; Auf weitere Tastendrücke warten
			If _IsPressed("11", $hDLL) and _IsPressed("54", $hDLL) Then
				;Warten bis Taste losgelassen wird
				While _IsPressed("11", $hDLL) and _IsPressed("54", $hDLL)
					Sleep(10)
				WEnd
				;Zähler für Anzahl der Tastendrücke erhöhen, sobald Taste losgelassen wird
				$iCount = $iCount + 1
			EndIf
		; Bis eine Sekunde vergangen ist
		Until TimerDiff($timerStart) > $iPressTime
		;senden
		_sendChatNr($iCount)
	;Schließen mit ESC+ALT
    ElseIf _IsPressed("1B", $hDLL) and _IsPressed("12", $hDLL) Then
        ExitLoop
    EndIf
WEnd
DllClose($hDLL)
exit
Func _sendChatNr($number)
	Switch $number
		Case 1
			_sendChat("Message1")
		Case 2
			_sendChat("Message2")
		Case 3
			_sendChat("Message3")
		Case Else
			_sendChat("Message4")
	EndSwitch
EndFunc
Func _sendChat($message)
	;Actives Fenster ermitteln
	$handle=WinGetHandle("[active]")
	;Senden
	ControlSend($handle,"",0,"{t}")
	ControlSend($handle,"",1,$message)
	ControlSend($handle,"",0,"{ENTER}")
EndFunc

Alles anzeigen

Das einzige was ich geändert habe ist, das du in deine nachrichten auch ausrufezeichen einbauen kannst, was bei der anderen version nicht geklappt hätte.