Problem bei zufälliger Zeilenausgabe

hajoh25

Hallo.
Ich habe ein Problem, ich möchte aus 6 verschiedenen TXT- Dateien eine zufällige Zeile auslesen und diese Anzeigen. Bei mir funktieroniert dies aber nicht. Kann mir jemand weiterhelfen?

Danke im vorraus.

C: Random.au3

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>


$Form1 = GUICreate("Was, Wie, Wo?", 392, 108, 192, 124)
GUISetFont(12, 400, 0, "MS Sans Serif")
$Label1 = GUICtrlCreateLabel("", 8, 8, 52, 24)
$Label2 = GUICtrlCreateLabel("", 72, 8, 52, 24)
$Label3 = GUICtrlCreateLabel("", 136, 8, 52, 24)
$Label4 = GUICtrlCreateLabel("", 200, 8, 52, 24)
$Label5 = GUICtrlCreateLabel("", 264, 8, 52, 24)
$Label6 = GUICtrlCreateLabel("", 328, 8, 52, 24)
$Button1 = GUICtrlCreateButton("Los", 160, 56, 75, 25)
GUICtrlSetOnEvent($Button1, "Los")
GUISetState(@SW_SHOW)


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit


	EndSwitch
WEnd


$Liste1 = "Aktivität1.txt"
$Liste2 = "Aktivität2.txt"
$Liste3 = "Art1.txt"
$Liste4 = "Art2.txt"
$Liste5 = "Ort.txt"
$Liste6 = "Zusatz.txt"


Func Los()
   $Random = Random(1, 10)


   $Datei1 = FileReadLine($Liste1, $Random)
   $Datei2 = FileReadLine($Liste2, $Random)
   $Datei3 = FileReadLine($Liste3, $Random)
   $Datei4 = FileReadLine($Liste4, $Random)
   $Datei5 = FileReadLine($Liste5, $Random)
   $Datei6 = FileReadLine($Liste6, $Random)


   GUICtrlSetData($Label, $Datei1)
   GUICtrlSetData($Labe2, $Datei2)
   GUICtrlSetData($Labe3, $Datei3)
   GUICtrlSetData($Labe4, $Datei4)
   GUICtrlSetData($Labe5, $Datei5)
   GUICtrlSetData($Labe6, $Datei6)


EndFunc

Alles anzeigen

**autoBert**

Und die Dateien zum testen soll man selber schreiben? Auf Anhieb sehe ich allerdings, daß die Func Los nie aufgerufen werden kann, da Opt("guioneventmode", 1) fehlt. In diesem würde sich die Gui nicht schliessen lassen da auch GUISetOnEvent($GUI_EVENT_CLOSE, 'DeineExitFunc') fehlt. Falls GuiOnEventModekannst du Zeilen 19-24 mit einer einzigen Zeile Sleep(1000) ersetzen. Falls nicht GuiOnEventMode (also GuiGetMsg-Modus) kannst du Zeile 15 löschen, mußt dann aber noch den ButtonClick im Switch-Block abhandeln (einfach mal das Beispiel zu GUICtrlCreateButton) anschauen.

Egal welcher Modus Zeilen 27 bis 32 (Dateipfade) müssen vor die While Schleife verschoben werden. Lies dir in der Hilfe auf jedenfall den Abschnitt GUI Reference komplett durch, ist wichtig zu wissen. Den sonst passiert das was du gemacht hast 2 Konzepte durcheinander geworfen.

Spoiler anzeigen

Code

$Liste1 = "Aktivität1.txt"
$Liste2 = "Aktivität2.txt"
$Liste3 = "Art1.txt"
$Liste4 = "Art2.txt"
$Liste5 = "Ort.txt"
$Liste6 = "Zusatz.txt"

**Kanashius**

Bei diesem Script sollte passieren, was du willst. Es ist recht flexibel, wenn du die Gui ändern willst und kann auch sehr schnell um Dateien erweitert werden.
Erklärungen stehen als Kommentare dabei.

AutoIt

#include <File.au3>
#include <GUIConstantsEx.au3>
;OnEventMode einschalten. GuiGetMsg funktioniert dann nicht mehr!
Opt("GuiOnEventMode",1)


;FensterBreite, Höhe der Labels und des Buttons, Platz zwischen den Labels/Buttons
global $GuiWidth=400, $LineHeight=25, $LineSpace=5
;2 Dimensionales Array. In der 1ten Spalte wird der Dateiname gespeichert, in der 2ten Spalte die Label Control-ID, um später den Text dort zu setzen.
; (das " _" am Ende der Zeile ist nur, damit man es schöner einrücken kann, da normal alles in eine Zeile muss.
; Aufbau (visuell als Tabelle vorstellen):
;   |0             |1
;   +--------------+-----------
;  0|Aktivität1.txt|0
;  1|Aktivität2.txt|0
;  2|Art1.txt      |0
;  3|Art2.txt      |0
;  4|Ort.txt       |0
;  5|Zusatz.txt    |0
;Die 0en in der 2 Spalte (Eitrag 1, da bei Arrays bei 0 angefangen wird) werden später durch die Label-Control-IDs ersetzt.
global $arFiles= _
		[ _
			["Aktivität1.txt",0], _
			["Aktivität2.txt",0], _
			["Art1.txt",0], _
			["Art2.txt",0], _
			["Ort.txt",0], _
			["Zusatz.txt",0] _
		]


;Fenster mit der GuiWidth erzeugen. Die Höhe wird berechnet aus der Arraygröße (+1 wegen dem Button). Jedes Element braucht LineHeight+LineSpace als Platz
$Form1 = GUICreate("Was, Wie, Wo?", $GuiWidth,(UBound($arFiles)+1)*($LineHeight+$LineSpace))
GUISetFont(12, 400, 0, "MS Sans Serif")
;Schleife, um für jeden Array-Eintrag ein Label zu erstellen
for $i=0 to UBound($arFiles)-1 step 1
	;Label erstellen. left wird mit 5 gesetzt, top wird aus der Nummer des aktuellen Elementes berechnet.
	$arFiles[$i][1]=GUICtrlCreateLabel(" - ",5,$LineSpace+$i*($LineHeight+$LineSpace),$GuiWidth-10,$LineHeight)
next
;Button wird mit dem Space vom unteren Rand der Gui erzeugt
$ButtonGo = GUICtrlCreateButton("Los",5,((UBound($arFiles)+1)*($LineHeight+$LineSpace))-$LineHeight-$LineSpace,$GuiWidth-10, $LineHeight)
;Event auf den Button setzen, damit die genannte Funktion beim Klick ausgeführt wird
GUICtrlSetOnEvent($ButtonGo, "Los")
;Event fürs Schließen auf die Gui setzen
GUISetOnEvent($GUI_EVENT_CLOSE, "_close")
;Fenster anzeigen
GUISetState(@SW_SHOW)


;Schleife, damit das Programm läuft. Sleep(10) verringert dabei die Programmaktivität, sodass nicht unnötig viele Ressourcen verbraucht werden
While Sleep(10)
WEnd


Func Los()
	;Wieder das Array mit den Dateinamen durchlaufen
	for $i=0 to UBound($arFiles)-1 step 1
		;Zufallszahl zwischen 1 und der maximalen Anzahl an Zeilen in der Datei
		$randomLine=Random(1,_FileCountLines($arFiles[$i][0]),1)
		;Wenn die Datei z.B. nicht existiert kommt hier ein Fehler, deshalb wird das dann angezeigt, sonst wird die zufällige Zeile angezeigt.
		if @error then
			GUICtrlSetData($arFiles[$i][1],"Error! File: "&'"'&$arFiles[$i][0]&'"'&" not found!")
		else
			;Zeile auslesen
			$sLine=FileReadLine($arFiles[$i][0],$randomLine)
			;Zeile in das Control packen
			GUICtrlSetData($arFiles[$i][1],$sLine)
		endif
	next
EndFunc


Func _close()
	;Schließen
	exit
EndFunc

Alles anzeigen

MfG Kanashius