StringRegExp richtig verwenden

mirko2002

Hallo Community,

ich scheiter mal wieder an einer wahrscheinlich sehr simplen Sache.

In der Zwischenablage habe ich einen String der wie folgt aussieht:

Code

Account no.: 123456789
Company: Test GmbH
Your Name: Herr Test
Address: Teststrasse 1
City: Testort
Postal code: 12345
Telephone: 0123456789
E-Mail Address: bla@test.de
Country: DE

Ich möchte nun, dass er Strings wie "Account no." sucht und mir den Wert dahinter ausgibt. Also ich brauche sozusagen die Daten hinter dem Doppelpunkt.

Folgenden Code habe ich bereits:

AutoIt

ConsoleWrite("Ausgabe 1: " & @CRLF)
	ConsoleWrite($Zwischenablage_MediaTrix& @CRLF)
	$dataArray = StringRegExp($Zwischenablage_MediaTrix, "(?m)^(.+?)\h*:\h*(.*?)\h*$", 4)


	Local $dic_Variables = ObjCreate("Scripting.Dictionary")
	For $Match In $dataArray
		$dic_Variables($Match[1]) = $Match[2]
	Next


	ConsoleWrite("Ausgabe 2: " & @CRLF)
	ConsoleWrite($Match[1]& " " & $Match[2] & @CRLF & @CRLF)

Alles anzeigen

In der Console haut er mir die komplette Zwischenablage rein (Ausgabe 1)... wie es oben bereits steht, so stehts auch in der Zwischenablage.

Die Ausgabe 2 gibt mir dann nur noch "Country DE" aus - also sozusagen den letzten "Match" den er gefunden hat.

Wie bekomme ich eine genaue Auflistung aller Matches und das ich dann nach bestimmten Dingen (wie Company oder so) gezielt suchen kann? Ich muss letzendlich nämlich die gesuchte Werte in Variablen speichern und dies gelint mir nicht

LG
Mirko

**BugFix**

zu kompliziert

So bekommst du alles in ein Array, abwechselnd Schlüssel und Wert:

AutoIt

$sText = _
'Account no.: 123456789' & @CRLF & _
'Company: Test GmbH' & @CRLF & _
'Your Name: Herr Test' & @CRLF & _
'Address: Teststrasse 1' & @CRLF & _
'City: Testort' & @CRLF & _
'Postal code: 12345' & @CRLF & _
'Telephone: 0123456789' & @CRLF & _
'E-Mail Address: bla@test.de' & @CRLF & _
'Country: DE '


$aMatch = StringRegExp($sText, '(?m)([^:]+)', 3)


For $x In $aMatch
	ConsoleWrite(StringStripWS($x, 1) & @CRLF)
Next

Alles anzeigen

mirko2002

Hm ok und genau da steh ich auf dem Schlauch:

Wie kann ich jetzt in einer Variable (nennen wir sie mal $Kundennummer) nun genau die Kundennummer speichern?

in die Console ballert er mir ja nun alle Werte rein die er in der For-Schleife findet aber wie kann ich diese gezielt abfangen?

So das ich halt einmal die Variable $Firma habe und einmal die Variable $Kundennummer und so weiter und in jeder Variable ist der Wert aus dem String...

Das kapier ich nicht

**BugFix**

In meinem vorigen Pattern hatte ich vergessen, die Umbrüche auszufiltern.
So gehts z.B.

AutoIt

$aMatch = StringRegExp($sText, '(?m)([^:\r\n]+)', 3)
Local $oDict = ObjCreate('Scripting.Dictionary')


For $i = 0 To UBound($aMatch) -2 Step 2
;~ 	ConsoleWrite($aMatch[$i] & ':' & StringStripWS($aMatch[$i+1], 1) & @CRLF)
	$oDict($aMatch[$i]) = StringStripWS($aMatch[$i+1], 1)
Next


ConsoleWrite($oDict('Account no.') & @LF)
ConsoleWrite($oDict('Company') & @LF)
ConsoleWrite($oDict('Your Name') & @LF)
ConsoleWrite($oDict('Address') & @LF)
ConsoleWrite($oDict('City') & @LF)
ConsoleWrite($oDict('Postal code') & @LF)
ConsoleWrite($oDict('Telephone') & @LF)
ConsoleWrite($oDict('E-Mail Address') & @LF)
ConsoleWrite($oDict('Country') & @LF)

Alles anzeigen

mirko2002

Allllles klar damit kann ich was anfangen/arbeiten

Perfekt - den Rest bastel ich mir schon hin, dass alles läuft

Super, danke Dir für die Unterstützung. Sofern ich weitere Hilfe brauche melde ich mich in diesem Thread nochmal!