Unterschiedliche Textfarben innerhalb einer ListView

TheUnkowingDude

Hallo AutoIt Community.

Ich möchte, wie im Titel beschrieben, einzelne ListViewElemente erstellen/einfärben, deren Spalten (in horizontaler Sicht) unterschiedliche Farben aufweisen. Ich brauch dies um bestimmte Inhalte von Anderen abzusetzen (aus grauen würde auch genügen).
Die Tabelle/Liste erstelle ich über den Befehl GUICtrlCreateListView. Zwar kann man mit GUICtrlSetColor den Text einfärben, dies wirkt dann aber großflächig auf das ganze Objekt.
Konnte auf den Foren und in der AutoIT Help nichts brauchbares finden, hoffe ihr könnt mir weiter helfen.

**autoBert**

Hallo TheUnkowingDude,

herzlich willkommen im Forum und viel Spass mit AutoIt.

Schau dir dazu Listview Subitem BKColor anpassen - je Subitem eine Farbe. Zeilen 60 bis 71 sind für das Färben der Zeilen und Spalten zuständig.
60_Listview Farbig.jpg
Das ganze basiert auf http://www.autoit.de/index.php?page=Thread&threadID=10104

mfg (auto)Bert

TheUnkowingDude

Hi Bert,

vielen Dank für die schnelle Antwort.
Leider ist das Beschriebene nicht ganz das, was ich suche. So wie ich das sehe, kann man mit deinem Skript nur die Hintergrundfarbe ändern, oder irre ich mich da?
Mit geht es darum, wie zb. mit dem Befehl GUICtrlSetColor, die Textfarbe zu ändern und das für einzelne Elemente der ViewList.

Mfg TheUnkowingDude

**BugFix**

Zitat von TheUnkowingDude

Mit geht es darum, wie zb. mit dem Befehl GUICtrlSetColor, die Textfarbe zu ändern und das für einzelne Elemente der ViewList.

DllStructSetData($tCustDraw, 'clrText', <BGR-COLOR>)

**autoBert**

Zitat von TheUnkowingDude

Hi Bert,

vielen Dank für die schnelle Antwort.
Leider ist das Beschriebene nicht ganz das, was ich suche. So wie ich das sehe, kann man mit deinem Skript nur die Hintergrundfarbe ändern, oder irre ich mich da?

mit Erweiterung des Skriptes ist auch das ändern der Textfarbe möglich:
62_Listview Farbig.jpg

Spoiler anzeigen

AutoIt

;https://autoit.de/index.php/Thread/84279-Unterschiedliche-Textfarben-innerhalb-einer-ListView/?postID=674195#post674195
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <array.au3>
#include <ListViewConstants.au3>
#include <StructureConstants.au3>
#include <WindowsConstants.au3>
$aColBK = IniReadSection(@ScriptDir & "\lv_format.ini", "ColBKColor")
_ArrayDelete($aColBK, 0)
;_ArrayDisplay($aColBK)
$aRowBK = IniReadSection(@ScriptDir & "\lv_format.ini", "RowBKColor")
_ArrayDelete($aRowBK, 0)
;_ArrayDisplay($aColBK)
$aColText = IniReadSection(@ScriptDir & "\lv_format.ini", "ColTextColor")
_ArrayDelete($aColText, 0)
;_ArrayDisplay($aColBK)
$aRowText = IniReadSection(@ScriptDir & "\lv_format.ini", "RowTextColor")
_ArrayDelete($aRowText, 0)
;_ArrayDisplay($aRowText)
$GUI = GUICreate("Listview Farbig", 1024, 300, 0, 0) ;<==== Breite geändert
$cListView = GUICtrlCreateListView("", 2, 2, 1020, 294, -1, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT)) ;<==== Breite geändert
$hListView = GUICtrlGetHandle($cListView)
For $i = 1 To 31
	_GUICtrlListView_InsertColumn($hListView, $i - 1, $i, 25)
	_GUICtrlListView_SetColumnWidth($hListView, $i - 1, 32) ;<==== eingefügt für Spaltenbreite
Next
For $i = 0 To 21 ; alle Item/SubItem erstellen
	_GUICtrlListView_AddItem($hListView, "Item: " &$i, $i)
	For $j = 1 To 30
		_GUICtrlListView_AddSubItem($hListView, $i, "Sub: "&$j, $j)
	Next
Next
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUISetState()
While True
	$msg = GUIGetMsg()
	Switch $msg
		Case -3
			ExitLoop
	EndSwitch
WEnd
Exit
Func WM_NOTIFY($hWnd, $msg, $wParam, $lParam)
	Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR
	$tNMHDR = DllStructCreate($tagNMHDR, $lParam)
	$hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
	$iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
	$iCode = DllStructGetData($tNMHDR, "Code")
	Switch $hWndFrom
		Case $hListView
			Switch $iCode
				Case $NM_CUSTOMDRAW
					Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
					Local $iDrawStage, $iItem, $iSubitem, $hDC, $tRect
					$iDrawStage = DllStructGetData($tCustDraw, 'dwDrawStage')
					Switch $iDrawStage
						Case $CDDS_ITEMPREPAINT
							Return $CDRF_NOTIFYSUBITEMDRAW
						Case BitOR($CDDS_ITEMPREPAINT, $CDDS_SUBITEM)
							; Item/SubItem das aktuell gezeichnet werden soll ermitteln
							$iItem = DllStructGetData($tCustDraw, 'dwItemSpec')
							$iSubitem = DllStructGetData($tCustDraw, 'iSubItem')
							Switch $iItem ; Zeilenwahl
								Case -1 ;kommt nicht vor ist aber notwendig, damit case else verwendet werden kann
								Case Else
									$iIndex = _ArraySearch($aRowBK, $iItem, 0, 0, 0, 0, 1, 0)
									If $iIndex = -1 Then ;nicht im Array für spezielle Zeilen also weiß
										DllStructSetData($tCustDraw, 'clrTextBk', RGB2BGR(0xFFFFFF))
									Else
										DllStructSetData($tCustDraw, 'clrTextBk', RGB2BGR($aRowBK[$iIndex][1]))
										;ConsoleWrite('Item '&$iItem&' BK: '&$aRowBK[$iIndex][1] & @CRLF)
									EndIf
									$iIndex = _ArraySearch($aRowText, $iItem, 0, 0, 0, 0, 1, 0)
									If $iIndex = -1 Then ;nicht im Array für spezielle Zeilen also schwarz
										DllStructSetData($tCustDraw, 'clrText', RGB2BGR(0x000000))
									Else
										DllStructSetData($tCustDraw, 'clrText', RGB2BGR($aRowText[$iIndex][1]))
										;ConsoleWrite('Item '&$iItem&' Text: '&$aRowText[$iIndex][1] & @CRLF)
									EndIf
							EndSwitch
							Switch $iSubitem
								Case -1 ;kommt nicht vor ist aber notwendig, damit case else verwendet werden kann
								Case Else
									$iIndex = _ArraySearch($aColBK, $iSubitem, 0, 0, 0, 0, 1, 0)
									If $iIndex <> -1 Then
										DllStructSetData($tCustDraw, 'clrTextBk', RGB2BGR($aColBK[$iIndex][1]))
										;ConsoleWrite('SubItem '&$iSubitem&' BK: '&$aColBK[$iIndex][1] & @CRLF)
									EndIf
									$iIndex = _ArraySearch($aColText, $iSubitem, 0, 0, 0, 0, 1, 0)
									If $iIndex <> -1 Then
										DllStructSetData($tCustDraw, 'clrText', RGB2BGR($aColText[$iIndex][1]))
										;ConsoleWrite('SubItem '&$iSubitem&' Text: '&$aColText[$iIndex][1] & @CRLF)
									EndIf
							EndSwitch
							Return $CDRF_NEWFONT
					EndSwitch
			EndSwitch
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY
Func RGB2BGR($iColor)
	Local $sH = Hex($iColor, 6)
	Return '0x' & StringRight($sH, 2) & StringMid($sH, 3, 2) & StringLeft($sH, 2)
EndFunc   ;==>RGB2BGR

Alles anzeigen

und die dazugehörige Ini:

Code: LV_Format.ini

[ColBKColor]
4=0x0000FF
22=0x0000FF
23=0x0000FF
24=0x0000FF
[ColTextColor]
4=0xf23456
22=0x234567
23=0xFF0000
24=0x456789
[RowBKColor]
4=0xFF0000
11=0xFFf000
[RowTextColor]
4=0x00FF00
11=0x0000FF

Alles anzeigen

die Spalteneinfärbung überschreibt die Zeileneinfärbung. Die Items kannst du auch mit GuiCtrlCreateListviewItem anlegen,

Wenn du es noch individueller benötigst solltest du dir ListView - SubItem einzeln färben/formatieren, Finale Version! (v1.3) anschauen. Aus dieser UDF habe ich die für obigen Zweck benötigten Funktionen kopiert. Im Original ist natürlich noch viel mehr machbar.

mfg (auto)Bert

TheUnkowingDude

Genau solch eine Funktion habe ich gesucht!
Vielen Dank Bert

**autoBert**

Zitat von TheUnkowingDude

Genau solch eine Funktion habe ich gesucht!
Vielen Dank Bert

Bedank dich bei BugFix, ist seine Vorlag in einer etwas anderen Form. Wenn dir dies so reicht ist es i.O. ansonsten weißt du ja jetzt wo du nachschauen kannst.

mfg (auto)Bert

**autoBert**

Ich habe das Skript mit Hilfe von Melba23 & Co. weiterentwickelt:

Spoiler anzeigen

C

;https://autoit.de/index.php/Thread/84279-Unterschiedliche-Textfarben-innerhalb-einer-ListView/?postID=674295#post674295
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <array.au3>
#include <ListViewConstants.au3>
#include <StructureConstants.au3>
#include <WindowsConstants.au3>
#include <FontConstants.au3>


Global $iDllGDI = DllOpen("gdi32.dll")


$aColBK = IniReadSection(@ScriptDir & "\lv_format.ini", "ColBKColor")
_ArrayDelete($aColBK, 0)
;_ArrayDisplay($aColBK)
$aRowBK = IniReadSection(@ScriptDir & "\lv_format.ini", "RowBKColor")
_ArrayDelete($aRowBK, 0)
;_ArrayDisplay($aColBK)
$aColText = IniReadSection(@ScriptDir & "\lv_format.ini", "ColTextColor")
_ArrayDelete($aColText, 0)
;_ArrayDisplay($aColBK)
$aRowText = IniReadSection(@ScriptDir & "\lv_format.ini", "RowTextColor")
_ArrayDelete($aRowText, 0)
;_ArrayDisplay($aRowText)


Global $bColorHeader = True ;wenn true werden auch die Spaltenüberschriften mit eingefärbt.




$GUI = GUICreate("Listview Farbig", 1024, 300, 0, 0) ;<==== Breite geändert
$cListView = GUICtrlCreateListView("", 2, 2, 1020, 294, -1, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT)) ;<==== Breite geändert
;_GUICtrlListView_SetExtendedListViewStyle($cListView, $LVS_EX_FULLROWSELECT) ; BitOR($LVS_EX_DOUBLEBUFFER, $LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
$hListView = GUICtrlGetHandle($cListView)
For $i = 1 To 31
	_GUICtrlListView_InsertColumn($hListView, $i - 1, $i, 25)
	_GUICtrlListView_SetColumnWidth($hListView, $i - 1, 32) ;<==== eingefügt für Spaltenbreite
Next
;get handle to child SysHeader32 control of ListView
Global $hHeader = HWnd(GUICtrlSendMsg($cListView, $LVM_GETHEADER, 0, 0))
;Turn off theme for header
DllCall("uxtheme.dll", "int", "SetWindowTheme", "hwnd", $hHeader, "wstr", "", "wstr", "")
;subclass ListView to get at NM_CUSTOMDRAW notification sent to ListView
;Global $wProcNew = DllCallbackRegister("_LVWndProc", "ptr", "hwnd;uint;wparam;lparam")
;Global $wProcOld = _WinAPI_SetWindowLong($hListView, $GWL_WNDPROC, DllCallbackGetPtr($wProcNew))


;Optional: Flat Header - remove header 3D button effect
Global $iStyle = _WinAPI_GetWindowLong($hHeader, $GWL_STYLE)
_WinAPI_SetWindowLong($hHeader, $GWL_STYLE, BitOR($iStyle, $HDS_FLAT))


; Get the font of the Header control (credit KaFu)
Local $hDC = _WinAPI_GetDC($hHeader)
Local $hFont = _SendMessage($hHeader, $WM_GETFONT)
Local $hObject = _WinAPI_SelectObject($hDC, $hFont)
Local $tLogFont = DllStructCreate($tagLOGFONT)


_WinAPI_GetObject($hFont, DllStructGetSize($tLogFont), DllStructGetPtr($tLogFont))
_WinAPI_SelectObject($hDC, $hObject)
_WinAPI_ReleaseDC($hHeader, $hDC)


Local $iWeight = DllStructGetData($tLogFont, "Weight") ; Bold
DllStructSetData($tLogFont, "Weight", BitOR($iWeight, $FW_BOLD))
$hHdrFont = _WinAPI_CreateFontIndirect($tLogFont)




For $i = 0 To 21 ; alle Item/SubItem erstellen
	_GUICtrlListView_AddItem($hListView, "Item: " & $i, $i)
	For $j = 1 To 30
		_GUICtrlListView_AddSubItem($hListView, $i, "Sub: " & $j, $j)
	Next
Next
If $bColorHeader Then
	$iCols = _GUICtrlListView_GetColumnCount($hListView)
	Global Const $tagNMCUSTOMDRAW = "struct;" & $tagNMHDR & ";dword dwDrawStage;handle hdc;" & $tagRECT & _
			";dword_ptr dwItemSpec;uint uItemState;lparam lItemlParam;endstruct"


	Global $aHdrData[$iCols][3] ;Headerdata erstellen wird beim einfärben benötigt
	For $i = 0 To $iCols - 1
		$aHdrData[$i][0] = _GUICtrlListView_GetColumn($hListView, $i)[5]
		$iIndex = _ArraySearch($aColText, $i, 0, 0, 0, 0, 1, 0)
		If $iIndex <> -1 Then
			$aHdrData[$i][1] = RGB2BGR($aColText[$iIndex][1])
		Else
			$aHdrData[$i][1] = 0x000000
		EndIf
		$iIndex = _ArraySearch($aColBK, $i, 0, 0, 0, 0, 1, 0)
		If $iIndex <> -1 Then
			$aHdrData[$i][2] = RGB2BGR($aColBK[$iIndex][1])
		Else
			$aHdrData[$i][2] = 0xFFFFFF
		EndIf
	Next
EndIf


GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUISetState()


While True
	$msg = GUIGetMsg()
	Switch $msg
		Case -3
			ExitLoop
	EndSwitch
WEnd


Func WM_NOTIFY($hWnd, $msg, $wParam, $lParam)
	Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR
	$tNMHDR = DllStructCreate($tagNMHDR, $lParam)
	$hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
	$iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
	$iCode = DllStructGetData($tNMHDR, "Code")
	Switch $hWndFrom
		Case $hHeader
			If $bColorHeader Then
				;ConsoleWrite('Header: ' & $iCode & @CRLF)
				Switch $iCode
					Case $NM_CUSTOMDRAW
						Local $tNMCustomDraw = DllStructCreate($tagNMCUSTOMDRAW, $lParam)
						Local $dwDrawStage = DllStructGetData($tNMCustomDraw, "dwDrawStage")
						Switch $dwDrawStage ; Holds a value that specifies the drawing stage
							Case $CDDS_PREPAINT ; Before the paint cycle begins
								Return $CDRF_NOTIFYITEMDRAW ; Notify parent window of any item related drawing operations


							Case $CDDS_ITEMPREPAINT ; Before an item is drawn: Default painting (frames and background)
								Return $CDRF_NOTIFYPOSTPAINT ; Notify parent window of any post item related drawing operations


							Case $CDDS_ITEMPOSTPAINT ; After an item is drawn: Custom painting (item texts)
								Local $tRECT = DllStructCreate($tagRECT)
								Local $iIndex = DllStructGetData($tNMCustomDraw, "dwItemSpec") ; Item index
								Local $hDC = DllStructGetData($tNMCustomDraw, "hdc") ; Device context
								_WinAPI_SelectObject($hDC, $hHdrFont) ; Set text font
								_WinAPI_SetBkMode($hDC, $TRANSPARENT) ; Transparent background
								_WinAPI_SetTextColor($hDC, $aHdrData[$iIndex][1]) ; Set text colour
								; Get header section size
								DllStructSetData($tRECT, 1, DllStructGetData($tNMCustomDraw, 6) + 1)
								DllStructSetData($tRECT, 2, DllStructGetData($tNMCustomDraw, 7) + 1)
								DllStructSetData($tRECT, 3, DllStructGetData($tNMCustomDraw, 8) - 2)
								DllStructSetData($tRECT, 4, DllStructGetData($tNMCustomDraw, 9) - 2)
								; Set and draw back colour
								Local $hBrush = _WinAPI_CreateSolidBrush($aHdrData[$iIndex][2])
								_WinAPI_FillRect($hDC, $tRECT, $hBrush)
								; Write text
								If $iIndex < _GUICtrlListView_GetColumnCount($cListView) Then
									_WinAPI_DrawText($hDC, $aHdrData[$iIndex][0], $tRECT, $DT_CENTER + $DT_VCENTER)
								EndIf
								Return $CDRF_NEWFONT ; $CDRF_NEWFONT must be returned after changing font or colors
						EndSwitch
				EndSwitch
			EndIf
		Case $hListView
			;ConsoleWrite('Listview' & @CRLF)
			Switch $iCode
				Case $NM_CUSTOMDRAW
					Local $tNMCustomDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
					Local $iDrawStage, $iItem, $iSubitem, $hDC, $tRECT
					$iDrawStage = DllStructGetData($tNMCustomDraw, 'dwDrawStage')
					Switch $iDrawStage
						Case $CDDS_ITEMPREPAINT
							Return $CDRF_NOTIFYSUBITEMDRAW
						Case BitOR($CDDS_ITEMPREPAINT, $CDDS_SUBITEM)
							; Item/SubItem das aktuell gezeichnet werden soll ermitteln
							$iItem = DllStructGetData($tNMCustomDraw, 'dwItemSpec')
							$iSubitem = DllStructGetData($tNMCustomDraw, 'iSubItem')
							Switch $iItem ; Zeilenwahl
								Case -1 ;kommt nicht vor ist aber notwendig, damit case else verwendet werden kann
								Case Else
									$iIndex = _ArraySearch($aRowBK, $iItem, 0, 0, 0, 0, 1, 0)
									If $iIndex = -1 Then ;nicht im Array für spezielle Zeilen also weiß
										DllStructSetData($tNMCustomDraw, 'clrTextBk', RGB2BGR(0xFFFFFF))
									Else
										DllStructSetData($tNMCustomDraw, 'clrTextBk', RGB2BGR($aRowBK[$iIndex][1]))
										;ConsoleWrite('Item '&$iItem&' BK: '&$aRowBK[$iIndex][1] & @CRLF)
									EndIf
									$iIndex = _ArraySearch($aRowText, $iItem, 0, 0, 0, 0, 1, 0)
									If $iIndex = -1 Then ;nicht im Array für spezielle Zeilen also schwarz
										DllStructSetData($tNMCustomDraw, 'clrText', RGB2BGR(0x000000))
									Else
										DllStructSetData($tNMCustomDraw, 'clrText', RGB2BGR($aRowText[$iIndex][1]))
										;ConsoleWrite('Item '&$iItem&' Text: '&$aRowText[$iIndex][1] & @CRLF)
									EndIf
							EndSwitch
							Switch $iSubitem
								Case -1 ;kommt nicht vor ist aber notwendig, damit case else verwendet werden kann
								Case Else
									$iIndex = _ArraySearch($aColBK, $iSubitem, 0, 0, 0, 0, 1, 0)
									If $iIndex <> -1 Then
										DllStructSetData($tNMCustomDraw, 'clrTextBk', RGB2BGR($aColBK[$iIndex][1]))
										;ConsoleWrite('SubItem '&$iSubitem&' BK: '&$aColBK[$iIndex][1] & @CRLF)
									EndIf
									$iIndex = _ArraySearch($aColText, $iSubitem, 0, 0, 0, 0, 1, 0)
									If $iIndex <> -1 Then
										DllStructSetData($tNMCustomDraw, 'clrText', RGB2BGR($aColText[$iIndex][1]))
										;ConsoleWrite('SubItem '&$iSubitem&' Text: '&$aColText[$iIndex][1] & @CRLF)
									EndIf
							EndSwitch
							Return $CDRF_NEWFONT
					EndSwitch
			EndSwitch
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY


Func RGB2BGR($iColor)
	Local $sH = Hex($iColor, 6)
	Return '0x' & StringRight($sH, 2) & StringMid($sH, 3, 2) & StringLeft($sH, 2)
EndFunc   ;==>RGB2BGR

Alles anzeigen

66_Listview Farbig.jpg
es lohnt sich im Entwicklerforum vorbeizuschauen, im dortigen Thema sind einige gute Lösungen im Zusammenhang mit LV-Headern verlinkt bzw. direkt gepostet, die Lösung von @UEZ verdient hier besondere Erwähnung