Hilfe beim Ordner durchsuchen und löschen der Dateien

F-L-O-88

Servus zusammen,

eines vor weg, ich fange gerade an mit AutoIt zu programmieren und würde Hilfe bei folgendem Tool benötigen:

Ich möchte ein Verzeichnis (in diesem Fall ein Netzlaufwerk) auf alle Dateien mit der Endung .txt durchsuchen (inkl. allen Unterordnern). Und diese anschließen löschen lassen.

Wäre nett wenn mir hierbei jemand helfen könnte.

Danke,
lg

**chip**

Schau dir diese Befehle an, damit kannst es machen:

FileFindFirstFile
FileFindNextFile
FileDelete

**autoBert**

_FileListToArrayRec wäre imho besser geeignet, als Anfänger gleich eine Rekursion zu programmieren kommt mir doch etwas zu schwer vor.

GerhardSchr

ungetestet hätte ich es so gemacht..

AutoIt

Func tree ($file)
	If StringInStr (FileGetAttrib ($file), "D") Then
		$files = _FileListToArray ($file, "*", 0)
		If IsArray ($files) Then
			For $folder = 1 To UBound ($files) -1
				tree ($file & "\" & $files[$folder])
			Next
		EndIf
	Else
		If StringInStr ($file, ".txt") > 0 Then
			FileDelete ($file)
		EndIf
	EndIf
EndFunc

Alles anzeigen

Code-Jack

Vielleicht überhaupt der Hinweis auf den Befehl _FileListToArrayRec.
In der AutoIt Help findet sich zu diesem Befehl ein leicht verständliches, kompaktes und direkt lauffähiges Example, wo die jeweiligen Resultate ratzfatz in einer Tabelle dargestellt werden, mittels _ArrayDisplay().

Keine Angst, da wird nichts gelöscht, sondern nur die Liste angezeigt, entsprechend der jeweiligen Parameter.

Etwas damit herumspielen, bis alle Einstellungen stimmen, so dass die Ergebnisliste korrekt das zeigt, was man löschen möchte. Dann erst den Befehl zum Löschen einbauen, wie GerhardSchr es demonstriert.
So kann nichts in die Hose gehen, durch eventuell falsch gesetzte Parameter.

Edit: Oh, autoBert hat weiter oben ja bereits darauf hingewiesen ...

GerhardSchr

wenn man es noch etwas "sicherer" machen will, könnte man statt StringinStr StringRegExp benutzen:

AutoIt

tree ("C:\test")




Func tree ($file)
	If StringInStr (FileGetAttrib ($file), "D") Then
		$files = _FileListToArray ($file, "*", 0)
		If IsArray ($files) Then
			For $folder = 1 To UBound ($files) -1
				tree ($file & "\" & $files[$folder])
			Next
		EndIf
	Else
		If StringRegExp ($file, "\.txt$", 0) Then
			FileDelete ($file)
		EndIf
	EndIf
EndFunc

Alles anzeigen

F-L-O-88

Danke GerhardSchr funktioniert wunderbar dein Code.

Eine Frage hätte ich nur noch.. Wenn ich vor dem Löschen eine Abfrage mit JA/NEIN einbaue, kommt diese Frage 5-6 Mal bis er es wirklich löscht.

Hier der Code:

Code

Func tree ($file)
	If StringInStr (FileGetAttrib ($file), "D") Then
		$files = _FileListToArray ($file, "*", 0)
		If IsArray ($files) Then
			For $folder = 1 To UBound ($files) -1
				tree ($file & "\" & $files[$folder])
			Next
		 EndIf


	  Else

		 Switch MsgBox(3, 'Wählen Sie!', "Wollen Sie alle .TXT Dateien löschen?" & @LF & ""  & @LF & "JA = .TXT Dateien werden gelöscht" & @LF & "" & @LF &"NEIN = Tool wird nicht weiter fortgesetzt!")
			Case 6	; JA
				  If StringRegExp ($file, "\.txt$", 0) Then
					 FileDelete ($file)
				  EndIf




			Case 7	; NEIN
			  Exit




			Case 2	; CANCEL
			   EndSwitch


	EndIf
EndFunc

Alles anzeigen

GerhardSchr

deine abfrage muss innerhalb von

AutoIt

If StringRegExp ($file, "\.txt$", 0) Then
			FileDelete ($file)
		EndIf

vorgenommen werden, sonst fragt er auch bei NICHT txt dateien, ob er löschen soll (obwohl er da nicht löscht)

z.B. so:

AutoIt

tree ("C:\test")






Func tree ($file)
	If StringInStr (FileGetAttrib ($file), "D") Then
		$files = _FileListToArray ($file, "*", 0)
		If IsArray ($files) Then
			For $folder = 1 To UBound ($files) -1
				tree ($file & "\" & $files[$folder])
			Next
		EndIf
	Else
		If StringRegExp ($file, "\.txt$", 0) Then
			$frage = MsgBox (3, "Frage", "Wirklich " & $file & " löschen?")
			If $frage = 6 Then
				FileDelete ($file)
			EndIf
		EndIf
	EndIf
EndFunc

Alles anzeigen

//edit: beim löschen bietet es sich an auch fehler abzufangen, da z.B. eine geöffnete Datei sich bei windows nicht einach löschen läst:

AutoIt

Func tree ($file)
	If StringInStr (FileGetAttrib ($file), "D") Then
		$files = _FileListToArray ($file, "*", 0)
		If IsArray ($files) Then
			For $folder = 1 To UBound ($files) -1
				tree ($file & "\" & $files[$folder])
			Next
		EndIf
	Else
		If StringRegExp ($file, "\.txt$", 0) Then
			$frage = MsgBox (3, "Frage", "Wirklich " & $file & " löschen?")
			If $frage = 6 Then
				$fehler = FileDelete ($file)
				If $fehler = 0 Then
					MsgBox (0, "", "Konnte " & $file & " nicht löschen!")
				EndIf
			EndIf
		EndIf
	EndIf
EndFunc

Alles anzeigen

oh ich sehe gerade, dass du nur einmal fragen willst, dachte es soll bei jeder datei gefragt werden...
hier die version wo er nur am anfang einmal fragt:

AutoIt

$frage = MsgBox (3, "Frage", "Wirklich alle .txt Dateien löschen?")
If Not ($frage = 6) Then
	MsgBox (0, "Hinweis", "Tool wird nicht weiter fortgesetzt!")
	Exit
EndIf


tree ("C:\test")




Func tree ($file)
	If StringInStr (FileGetAttrib ($file), "D") Then
		$files = _FileListToArray ($file, "*", 0)
		If IsArray ($files) Then
			For $folder = 1 To UBound ($files) -1
				tree ($file & "\" & $files[$folder])
			Next
		EndIf
	Else
		If StringRegExp ($file, "\.txt$", 0) Then
			$fehler = FileDelete ($file)
			If $fehler = 0 Then
				MsgBox (0, "", "Konnte " & $file & " nicht löschen!")
			EndIf
		EndIf
	EndIf
EndFunc

Alles anzeigen

F-L-O-88

Oh herzlichen Dank!!!

Wenn ich noch einmal lästig sein darf - wenn jetzt keine .txt gefunden wird, wo baue ich dann eine Fehlermeldung ein?

thx

**Kanashius**

bevor du das erste mal $file benutzt ne abfrage nach FileExists($file).

GerhardSchr

hmm das konnte man mit einen counter lösen:

AutoIt

$counter = 0


$frage = MsgBox (3, "Frage", "Wirklich alle .txt Dateien löschen?")
If Not ($frage = 6) Then
	MsgBox (0, "Hinweis", "Tool wird nicht weiter fortgesetzt!")
	Exit
EndIf




tree ("C:\test")




If $counter > 0 Then
	MsgBox (0, "Fertig", "Es wurde(n) " & $counter & " txt-Dateien bearbeiten")
Else
	MsgBox (0, "Fertig", "Es wurden keine txt-Dateien gefunden")
EndIf






Func tree ($file)
	If StringInStr (FileGetAttrib ($file), "D") Then
		$files = _FileListToArray ($file, "*", 0)
		If IsArray ($files) Then
			For $folder = 1 To UBound ($files) -1
				tree ($file & "\" & $files[$folder])
			Next
		EndIf
	Else
		If StringRegExp ($file, "\.txt$", 0) Then
			$counter += 1
			$fehler = FileDelete ($file)
			If $fehler = 0 Then
				MsgBox (0, "", "Konnte " & $file & " nicht löschen!")
			EndIf
		EndIf
	EndIf
EndFunc

Alles anzeigen

wobei ich das nicht elegant finde, daher meine frage:
wie kann ich $counter in der funktion declarieren, ohne mir den wert jedesmal wieder zu resetten?
ich dachte da an IsDeclared....allerdings hat dies nicht so geklappt wie ich wollte...

Zeitriss

GerhardSchr: hier nehme ich die Anzahl immer als Rückgabe mit:

AutoIt

Func tree ($file)
   Local $iCounter = 0
	If StringInStr (FileGetAttrib ($file), "D") Then
		$files = _FileListToArray ($file, "*", 0)
		If IsArray ($files) Then
			For $folder = 1 To UBound ($files) -1
				$iCounter += tree ($file & "\" & $files[$folder])
			Next
		EndIf
	Else
		If StringRegExp ($file, "\.txt$", 0) Then
			$iCounter += 1
			$fehler = FileDelete ($file)
			If $fehler = 0 Then
				MsgBox (0, "", "Konnte " & $file & " nicht löschen!")
			EndIf
		EndIf
	 EndIf
	 Return $iCounter
EndFunc

Alles anzeigen

€Edit:

GerhardSchr: Du solltest bei deinem StringRegExp() nicht das "(?i)" vergessen sonst findet er nicht alles

Man kann es übrigens auch so lösen:

AutoIt

Func MyFileDelete($sSearchPath, $sFileSuffix = "txt", $iMaxDepth = 200)
   If Not IsInt($iMaxDepth) or $iMaxDepth < 0 and $iMaxDepth >= 256 Then Return SetError(2, 0, False)
   Local $aFile[$iMaxDepth +1], $iDepth = 0, $sPath = StringRegExpReplace($sSearchPath,"\\*\Z",""), $sFile = "", $iCounter = 0
   If Not FileExists($sPath) Then Return SetError(1, 0, False)
   $aFile[0] = FileFindFirstFile($sPath & "\*")
   While $iDepth >= 0
	  $sFile = FileFindNextFile($aFile[$iDepth])
	  If @extended = 1 and $iDepth < $iMaxDepth Then
		 $iDepth +=1
		 $sPath &= "\" & $sFile
		 $aFile[$iDepth] = FileFindFirstFile( $sPath & "\*" )
	  ElseIf @error = 1 Then
		 FileClose( $aFile[$iDepth] )
		 $iDepth -= 1
		 $sPath = StringRegExpReplace($sPath,"\\[^\\]*\Z","")
	  ElseIf StringRegExpReplace($sFile,"\A[^\.]*|.*\.","") = $sFileSuffix Then
		 ;FileDelete($sPath & "\" & $sFile)
		 $iCounter +=1
		 ConsoleWrite($sPath & "\" & $sFile &@crlf)
	  EndIf
   Wend
   Return SetError(0, $iCounter, True)
EndFunc

Alles anzeigen

FileDelete auskommentiert, da nicht hinreichend getestet

mfg Zeitriss

GerhardSchr

moin,
jo mit dem retrun wert ist ne gute idee...

aber warum soll er ohne (?i) nicht alles finden?

FileFindNextFile hatte ich auch schonmal benutzt.....bei mir ist dann der code unübersichtlich gewurden
auch war es damals für mich eine kleine übung, funktionen mehrfach selbst aufzurufen

Zeitriss

Hi,

(?i) macht den Pattern "Case-insensitivity" so dass auch Bezeichnungen wie File.TXT gefunden werden.

mfg

Zeitriss

GerhardSchr

ah ok dann habe ich dich falsch verstanden, ich dachte dass in manchen fällen auch .txt nicht gefunden wird...
klar (?i) macht dann sinn

also dann so:

AutoIt

StringRegExp ($file, "(?i)\.txt$", 0)