GUI größer machen

ExoBiTe

Hi.
Ich habe ein Script erstellt wo man in einer GUI neue Elemente per Knopfdruck erstellen kann.
Nun möchte ich dass die GUI sich nach unten erweitert, sobald das Element nichtmehr in die GUI passen würde.
Zurzeit versuche ich es über WinMove(), aber das funktioniert irgendwie nicht.
Hier mal der Code:

AutoIt

Global $GuiHeight = 500
Global $MoveHeight = 70
Global $MoveCount = 0
func _Gui2()
	Opt("GUIOnEventMode", 1)
	Global $Gui2 = GUICreate("Creator Kit Attack Assigner", 510, $GuiHeight)
	GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
	Global $BtnAdd = GUICtrlCreateButton("Add Move", 20, $MoveHeight, 90, 20)
	GUICtrlSetOnEvent(-1, "_addMoveLine")
	GUISetState()
	While 1
	sleep(5000)
	wEnd
endFunc
func _addMoveLine()
	GUICtrlDelete($BtnAdd)
	$MoveCount = $MoveCount +1 
	GUICtrlCreateLabel($MoveCount & ".", 20, $MoveHeight +2.5)
	$MoveID[$MoveCount] = GUICtrlCreateCombo("Moves", 40, $MoveHeight, 120, 20)
	GuiCtrlSetData(-1, "|" & _ArrayToString($Names))
	$MoveLvs[$MoveCount] = GUICtrlCreateInput("Level", 170, $MoveHeight, 50, 20)
	$MoveHeight = $MoveHeight + 30
	if $MoveHeight > $GuiHeight Then
		WinMove($Gui2, "", 0, 0, 510, $MoveHeight + 20)
	EndIf
	Global $BtnAdd = GUICtrlCreateButton("Add Move", 20, $MoveHeight, 90, 20)
	GUICtrlSetOnEvent(-1, "_addMoveLine")
	;_ArrayDisplay($IDs)
endFunc

Alles anzeigen

Das Problem ist halt der Part (Zeile 25 - 27).

AutoIt

if $MoveHeight > $GuiHeight Then
		WinMove($Gui2, "", 0, 0, 510, $MoveHeight + 20)
	EndIf

Ich hoffe ihr könnt das Problem verstehen und mir helfen. Dankeschön

Zeitriss

Hi,

Das Script funktioniert nicht, es fehlen includes usw...
Aber so vom drüber gucken schätze ich das folgendes geändert werden musss:

1.) Hinzufügen:

AutoIt

Opt("GUIResizeMode",768 + 32); $GUI_DOCKSIZE + $GUI_DOCKTOP

Damit sich die Elemente nicht verschieben/Zerren.

2.) und die folgdenden Zeilen änderen (Zeile 23 - 25)?.:

AutoIt

if $MoveHeight > $GuiHeight - 30 Then
    WinMove($Gui2, "", Default, Default, 510, $MoveHeight + 60)
EndIf

Zudem solltest du den Button $BtnAdd nicht immerwieder neu erstellen.

mfg

Zeitriss

ExoBiTe

Ich habe hier nur nicht das ganze Script gepostet, an sich funktioniert alles top (ausser dass das Fenster Größer wird).

Ich frage mich gerade nur woher du die 782 + 32 nimmst ( Opt("GUIResizeMode",768 + 32) ).
Habe es zwar trozdem eingefügt, sowie den 2ten Codeschnipsel aber das Fenster bleibt einfach unverändert

Wo genau muss ich das erste einfügen? (Habe es nun direkt nach dem erstellen der GUI eingebaut, das funktioniert aber nicht

Zeitriss

AutoIt

#include<GUIConstants.au3>
#include<Array.au3>
Opt("GUIResizeMode", $GUI_DOCKSIZE + $GUI_DOCKTOP)
Opt("GUIOnEventMode", 1)
Global $GuiHeight = 200
Global $MoveHeight = 70
Global $MoveCount = 0
Global $MoveID[42]
Global $MoveLvs[42]
Global $Names[3] = ["Heinz", "Hugo", "Herbert"]
_Gui2()
func _Gui2()
   Global $Gui2 = GUICreate("Creator Kit Attack Assigner", 510, $GuiHeight)
   GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
   Global $BtnAdd = GUICtrlCreateButton("Add Move", 20, $MoveHeight, 90, 20)
   GUICtrlSetOnEvent(-1, "_addMoveLine")
   GUISetState()
   While 1
	  sleep(5000)
   wEnd
endFunc
func _addMoveLine()
   $MoveCount = $MoveCount +1
   GUICtrlCreateLabel($MoveCount & ".", 20, $MoveHeight +2.5)
   $MoveID[$MoveCount] = GUICtrlCreateCombo("Moves", 40, $MoveHeight, 120, 20)
   GuiCtrlSetData(-1, "|" & _ArrayToString($Names))
   $MoveLvs[$MoveCount] = GUICtrlCreateInput("Level", 170, $MoveHeight, 50, 20)
   $MoveHeight = $MoveHeight + 30
   if $MoveHeight > $GuiHeight - 30 Then
	  WinMove($Gui2, "", Default, Default, 510, $MoveHeight + 60)
   EndIf
   GUICtrlSetPos($BtnAdd, 20, $MoveHeight, 90, 20)
   ;_ArrayDisplay($IDs)
endFunc

Alles anzeigen

Versuch es mal so, Script habe ich behilfsmäßig zum laufen bekommen

mfg

Zeitriss

ExoBiTe

Vielen Dank, war aber garnichtmehr benötigt.
Habe es mit deinem vorherigen Post gerade doch noch zum laufen bekommen, vielen Dank